Winsock problem

[SparkT]

Hi.

I'm developing a school project which consists in a Instant Messenger using the Microsoft Winsock control.

The IM project consists in a Server and a Client, but in this case only clients are allowed to talk, the server is there to put 2 clients in communication with each other.

The problem I'm having occurs when i try to send a message from a client to another.
The clients are registering their requestID in a database, and when a client try to communicate, the server searches in a database for the ID of the other client, and then places the communication.

id is the variable who carries the id in the database

sock(id).sendData ("example")

but this won't work... it gives me an error (i know that vb6 is getting the ID right off the database because it printed it right after performing the .seek function)

But if I instead of id(variable) place directly the id(integer), it works!!!

ex.

sock(2).sendData ("example")

this way things will work perfectly...!

I hope and can get some help here :S, the only thing left to this to work is this problem... i need to get it to work with the id it gets from the database...

Thanks in advance!

[the182guy]

I've done this type of app before.

Its easier to maintain an array of connected clients in the server, instead of going into the db everytime a message is sent. In my opinion, the sock(this number) should not be related to anything in the database. This index is always going to be different for each client, each time they connect, because its based on who connects first. I dont think there is any need to base it on the ID of the clients info in the database.

Its easier to keep an array of users connected. So it would go like this:

Client1 sends "hello" to Client2
Server receives "hello,Client2" from Client1, it parses the message and can see that its destined for Client2
Server searchs the array of connectes clients looking for "Client2" in the list
Server finds "Client2" at array #X, it then sends the message to Winsock(X).

You see? If you keep the socket index matching the index of the client in the array, you can make this very easy for yourself

[SparkT]

Yeah, your right.... I'm going to try that and see if it solves my problem...

[SparkT]

Geez.... i can't get this right... :S

[evan29]

EDIT: First things first, make sure you set up the server so that the clients is set up in an array, otherwise, things won't work properly :P

I've got this working one of my server/client programs. This is how it works; once you have gotten the clients to connect (which you probably have done) then when data is received, it sends that data to everybody in that socket array but the person who sent it. Try this for the server side:

Private Sub sck_DataArrival(Index As Integer, ByVal bytesTotal As Long)
 
Dim LowerBound As Integer
Dim UpperBound As Integer
Dim Loops As Integer
Dim strData As String
 
LowerBound = 1 'The lowest index number of your sockets
UpperBound = 2 'The highest index number of your sockets
 
sck(Index).GetData strData 'get the data that is recieved
 
For Loops = LowerBound To UpperBound 'Loop through each socket
    If sck(Loops).State = sckConnected And Loops <> Index Then 'Checks if the socket is connected and is not the sender
        DoEvents 'Makes sure the socket has finished with everything else first
        sck(Loops).SendData strData 'Send the data to the client
    End If
Next Loops
 
End Sub

This was not yet tested but it should work

[DigiRev]

I do what 182guy said.

I usually create a UDT structure to store all clients' info. Here's an example. Might make it easier to read/understand if you paste it into a VB project.

Option Explicit
 
'Structure to store information about a chat client.
Private Type CHAT_CLIENT
    strUsername As String
    strIP As String
    'Other info...
End Type
 
'Variable to store all chat client's info.
Private udtClient() As CHAT_CLIENT
 
'Maximum number of clients that can connect.
'Change to whatever you want.
Private Const MAX_CLIENTS As Integer = 32767
 
'Simple function to return the UBound of udtClient array without an error.
Private Function UBClient() As Long
    On Error GoTo ErrorHandler
    
    UBClient = UBound(udtClient())
    
    Exit Function
    
ErrorHandler:
    Exit Function
    
End Function
 
'Finds the next available socket to use to accept the connection on.
Private Function NextSocket() As Integer
    Dim intLoop As Integer, intFound As Integer
    
    'First check if we even have any other winsock controls loaded.
    'If not, then just load #1.
    If sckServer.ubound = 0 Then
        'Load next socket.
        Load sckServer(1)
        sckServer(1).Close
        NextSocket = 1
    Else
        'There are other winsock controls loaded.
        'Loop through all of them.
        'If one of them isn't being used (State = sckClosed) then we can use that one.
        
        'If we can't find one already loaded then we need to load a new one
        'unless we've already reached MAX_CLIENTS.
        For intLoop = 1 To sckServer.ubound
            
            If sckServer(intLoop).State = sckClosed Then
                intFound = intLoop 'Found one.
                Exit For
            End If
        
        Next intLoop
        
        If intFound > 0 Then 'Check if we found one already loaded.
            NextSocket = intFound
        Else
            'Didn't find one. Check if we can load a new one.
            If sckServer.ubound < MAX_CLIENTS Then
                intFound = sckServer.ubound + 1
                Load sckServer(intFound)
                sckServer(intFound).Close
                NextSocket = intFound
            Else
                'We reached MAX_CLIENTS.
                Debug.Print "CONNECTION REFUSED: MAX_CLIENTS REACHED"
            End If
        
        End If
    
    End If
    
End Function
 
Private Sub sckServer_Close(Index As Integer)
    'A client has disconnected.
    'To acccess this client's info we can just use the Index property of the winsock.
    
    Debug.Print udtClient(Index).strIP & " disconnected."
End Sub
 
Private Sub sckServer_ConnectionRequest(Index As Integer, ByVal requestID As Long)
    'Find the next available socket to use.
    Dim intNext As Integer
    
    intNext = NextSocket
    
    If intNext > 0 Then 'Found one.
        sckServer(intNext).Accept requestID 'Accept connection.
        
        'Now associate a client in udtClient() with this winsock control.
        
        'We may need to ReDim the array in case this one hasn't been loaded yet.
        If intNext > UBClient() Then
            ReDim Preserve udtClient(0 To intNext) As CHAT_CLIENT
        End If
        
        With udtClient(intNext)
            .strUsername = ""
            .strIP = sckServer(intNext).RemoteHostIP
        End With
        
    End If
    
End Sub