Drawing other controls

[agent]

I'm trying to code a designer for controls for my app (not an IDE designer). I'm going to be able to move the control around and size it using the mouse. I want to prevent mouse events on the control without disabling the control. The best way I can think of this is to hijack the drawing code and draw the control into my own control.

I got it to work with the Button control: I call the OnPaint method. How? (Considering that it's protected...) I used reflection to find the "OnPaint" method signature and called it using the invoke method providing it the graphics object attached to a label control. The code to invoke the Button's paint event was in the Label's paint event.

This worked surprisingly well for the button. Unfortunately, it didn't work so well for other controls, such as the Listbox.

Using Lutz Roeder's .NET Reflector* (to decompile the listboxes drawing methods) I discovered that the Listbox does it's drawing from a method called by WndProc instead of OnPaint (like a rational control...)

Is there a way anybody knows of to cause a control, in most sane circumstances, to paint to a Graphics object that is not its own?

Do you know of a better way to obtain my long-term goal of preventing mouse events from reaching a visible and enabled control?

I'm designing this with the intention that it work with anything that inherits Control.

---
*Using Lutz Roeder's .NET Reflector decompiles .Net assemblies through reflection. Available free at http://www.aisto.com/roeder/dotnet/

[sparrow1]

Hi,

Here's a link how to draw your own controls using GDI+.

http://msdn.microsoft.com/library/de...cntrlsamp4.asp

Hope it helps,

sparrow1

[agent]

Hi,

Here's a link how to draw your own controls using GDI+.

http://msdn.microsoft.com/library/de...cntrlsamp4.asp

Hope it helps,

sparrow1

I'm actually interested in getting another control to draw itself into a graphics object I provide... in other words, I want to draw a control other than mine into mine.

If I attach my control to a button, my control will appear exactly as the attached button does.

[agent]

The following is the incomplete but somewhat usable control that I'm working on. Copy/paste this into a new file (there are two classes).

To use it, drop ControlSizer onto a form. Drag another control, (tested with Button, Label, Groupbox) onto the form. Set the property Control of ControlSizer to the control you just dropped.

The controls listed above (Button, etc) work properly. It's other controls, such as ProgressBar, ScrollBars, TextBox, Listbox, etc, that don't work.

Basically, anything that does the painting in OnPaint and OnBackgroundPaint properly paints in my control. Controls, such as Listbox which do their painting from WndProc don't paint in my control.

Anybody know of a better way to do this?

Public Class ControlSizer
    Private Const SizeGripSize = 8I
 
    'These hold the protected methods 'OnPaint' and 'OnBackgroundPaint' of _Control
    Private _PaintMethod As System.Reflection.MethodInfo
    Private _PaintBackgroundMethod As System.Reflection.MethodInfo
 
    'This is where the protected methods 'OnPaint' and 'OnBackgroundPaint' of _Control are called
    Protected Overrides Sub OnPaint(ByVal pe As System.Windows.Forms.PaintEventArgs)
        'everything is doublebuffered for speed now
        Dim MyRect = New Rectangle(Point.Empty, Me.Size)
 
        'Paint _Control into a buffer
        Dim ControlBuffer As New Bitmap(Me.Width - (SizeGripSize * 2), Me.Height - (SizeGripSize * 2), Imaging.PixelFormat.Format32bppArgb)
        If _Control IsNot Nothing Then
            Using ControlBufferGraphics As Graphics = Graphics.FromImage(ControlBuffer)
                Dim args As Object() = {New PaintEventArgs(ControlBufferGraphics, New Rectangle(Point.Empty, _Control.Size))}
                _PaintBackgroundMethod.Invoke(_Control, args)
                _PaintMethod.Invoke(_Control, args)
            End Using 'ControlGraphics
        End If
 
        'Paint the size grips, selection, and border into a buffer
        Dim SizeGripBuffer As New Bitmap(Me.Width, Me.Height, Imaging.PixelFormat.Format32bppArgb)
        Using SizeGripBufferGraphics As Graphics = Graphics.FromImage(SizeGripBuffer)
            'todo: draw size grips
 
            'right now, we'll just draw a transparent selection box
            Using SelectionBrush As New SolidBrush(Color.FromArgb(128, SystemColors.Highlight))
                SizeGripBufferGraphics.FillRectangle(SelectionBrush, MyRect)
            End Using
 
            ControlPaint.DrawSelectionFrame(SizeGripBufferGraphics, True, MyRect, Rectangle.Inflate(MyRect, -2, -2), SystemColors.Highlight)
 
        End Using
 
        'Paint any owner draw stuff into a buffer
        Dim OwnerDrawBuffer As New Bitmap(Me.Width, Me.Height, Imaging.PixelFormat.Format32bppArgb)
        Using OwnerDrawBufferGraphics As Graphics = Graphics.FromImage(OwnerDrawBuffer)
            MyBase.OnPaint(New PaintEventArgs(OwnerDrawBufferGraphics, MyRect))
        End Using
 
        'Paint all the buffers to the control
        pe.Graphics.DrawImage(ControlBuffer, New Point(SizeGripSize, SizeGripSize))
        pe.Graphics.DrawImage(SizeGripBuffer, Point.Empty)
        pe.Graphics.DrawImage(OwnerDrawBuffer, Point.Empty)
 
        'Dispose all the buffers
        ControlBuffer.Dispose()
        SizeGripBuffer.Dispose()
        OwnerDrawBuffer.Dispose()
    End Sub
 
    'This is where _PaintMethod and _PaintBackgroundMethod are set
    Public Property Control() As Control
        Get
            Return _Control
        End Get
        Set(ByVal value As Control)
            If value Is Me Then
                Throw New CircularReferenceException
            Else
                _Control = value
 
                RefreshSize(True)
 
                If _Control IsNot Nothing Then
                    _PaintBackgroundMethod = _Control.GetType.GetMethod("OnPaintBackground", Reflection.BindingFlags.Instance Or Reflection.BindingFlags.NonPublic Or Reflection.BindingFlags.Public Or Reflection.BindingFlags.FlattenHierarchy)
                    _PaintMethod = _Control.GetType.GetMethod("OnPaint", Reflection.BindingFlags.Instance Or Reflection.BindingFlags.NonPublic Or Reflection.BindingFlags.Public Or Reflection.BindingFlags.FlattenHierarchy)
                End If
            End If
        End Set
    End Property
    Private _Control As Control
 
    'Adjusts the size of this control or _Control as needed. Also forces redraw
    Public Sub RefreshSize(ByVal SizeToControl As Boolean)
        If _Control IsNot Nothing Then
            If SizeToControl Then
                Me.Bounds = Rectangle.Inflate(_Control.Bounds, SizeGripSize, SizeGripSize)
                Me.BringToFront()
            Else
                _Control.Bounds = Rectangle.Inflate(Me.Bounds, -(SizeGripSize), -(SizeGripSize))
            End If
 
            Me.Invalidate()
        End If
    End Sub
 
    Protected Overrides Sub OnSizeChanged(ByVal e As System.EventArgs)
        MyBase.OnSizeChanged(e)
 
        RefreshSize(False)
    End Sub
 
    Protected Overrides Sub OnLocationChanged(ByVal e As System.EventArgs)
        MyBase.OnLocationChanged(e)
 
        RefreshSize(False)
    End Sub
End Class
 
Public NotInheritable Class CircularReferenceException
    Inherits ApplicationException
 
    Sub New()
        MyBase.New("An attempt has been made to create a reference that is circular (for example, attaching a Resizer control to itself).")
    End Sub
End Class

[agent]

I think what I'll do in the interim is add a 'special drawing' handler or something. If I notice something doesn't draw correctly, the host app can draw a generic control (a white box with some text or something)