[RESOLVED] listbox to popup ...how?

[om-yousif]

could you please help me with this ?

form1... contains a richtext box with some words
form2... contains two lists with some group of words saperated by an empty field
for example

list1
ocean
The Deep
Marine

choose
decide on
Pick


list2
22
66
87

57
93
11




how can i assign apopup menu for wach word in form 1 with the valus of these lists

as folows


the first word in text is (sea)
popup menu will be
ocean <22>
The Deep <66>
Marine <87>
then if the user select one of these options (sea) will be replased by that option

the second word in text is (select)
popup menu sholud be
choose <57>
decide on < 93>
Pick < 11>



if the user picked ocean <22> in the first case and decide on < 93> in the second case

the text will be shown as
ocean<22> decide on< 93>


and thats it pleeeease help me

[Static]

why are u using listboxes for these word?
how many "choices" will there be? (is it going to be more than sea and select)??
why have a second listbox that has the numbers in it?

[shakti5385]

do u want multi line popup... then

http://vbforums.com/showthread.php?&...&is_resolved=1

check out this link

[Static]

I think they want a popup menu... so user can select a word and it replaces it

[om-yousif]

STATIC....

if you remeber this thread

[URL=http://www.vb-forums.com/showthread.php?t=418760[/URL]

these two words and the numbers are just to simplyfy the idea
because the actual project deals with arabic text

as u see in the URL

....from the beging i choose to extract the options of each word as you told me and put them in a list box then i did the same thing to get the english translation for each option and put them in another list

.... i don't know the number of words in the text, it is different text in each run

my questions now :

is it possible to divide the list box and convert it to a popup for each word?
can i merg the two lists each row togather ?
how can i replace the choosen option with the original woed in the text?


i hope that i explaind well

[om-yousif]

SHAKTI 5385
thanks i well check this

[Static]

oh yeah, that thread.

I would suggest dropping the idea of the listbox. or, do u really need to see these words? or only on right click?

I would create text file, or store in a variable.. split up...
somthing like this:

sea;ocean <22>;The Deep <66>;Marine <87>
select;choose <57>;decide on <93>;Pick <11>

then you can loop thru and check the first word if its the selected word, you can build the popup with the rest of the line

is the INPUT the "word"? or is Lookup the Word?

[Static]

here is a sample project. .it is using the Lookup word as the possible match from the rich textbox... let me know if u want it to use the input string...

this will build a menu for the highlighted word... then replaced if clicked.

[om-yousif]

it is the INPUT

.. no i don't need to see the words

[om-yousif]

i run the project STATIC thanks
this is what i mean
but can popup menu appear whith right click the word without selecting it

[Static]

sure, heres another question...
should the "lookup word" be ignored?

[Static]

ok replace the code in the sample project with the code below..

a few notes....
1 (sorry the sample had a listbox and command button... leftover from testing)
2 I cannot test since the "INPUT string" is in arabic, I cant check it, only shows ????? in my test files.. so hopefull it will work for you
3 either select the word, or click in it then right click, menu should appear

any questions on the code, just yell

Dim WORDLIST() As String
 
Private Sub GetData()
    Dim tW As String
    Dim tmp() As String
    Dim Words() As String
    Open App.Path & "\arabic.txt" For Input As #1
        tmp = Split(Input(LOF(1), 1), vbCrLf)
    Close #1
    Dim sLine As String
    For x = 0 To UBound(tmp)
        
        If UCase(Left(tmp(x), 8)) = "SOLUTION" Then
            Words = Split(tmp(x), "(")
            sLine = sLine & Left(Words(1), InStr(Words(1), ")") - 1) & ";"
        ElseIf UCase(Left(tmp(x), 7)) = "COMMENT" Then
            Words = Split(tmp(x), ":")
            sLine = sLine & Words(1)
        ElseIf UCase(Left(tmp(x), 5)) = "INPUT" Then
            If sLine <> "" Then
                If Right(sLine, 1) = ";" Then
                    sLine = Left(sLine, Len(sLine) - 1)
                End If
                sLine = sLine & vbCrLf
            End If
            Words = Split(tmp(x), ":")
            sLine = sLine & Trim(Words(1)) & ":"
        ElseIf UCase(Left(tmp(x), 7)) = "LOOK-UP" Then
            'nothing
        End If
    Next
    Debug.Print sLine
    WORDLIST = Split(sLine, vbCrLf)
    
 
End Sub
 
 
Private Sub Form_Load()
   GetData
   RichTextBox1.Text = "not sure what to put here...."
End Sub
 
 
 
Private Sub mnuWord_Click(Index As Integer)
    If InStr(mnuWord(Index).Caption, "NOT FOUND") = 0 Then
        RichTextBox1.SelText = mnuWord(Index).Caption
    End If
End Sub
 
Private Sub RichTextBox1_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
    If Button = 2 Then
        Dim sLoc As Integer, eLoc As Integer
        Dim wrds() As String
        Dim tmp() As String
        If Trim(RichTextBox1.SelText) = "" Then
            If RichTextBox1.SelStart = 0 Then Exit Sub
            sLoc = InStrRev(RichTextBox1.Text, " ", RichTextBox1.SelStart)
            eLoc = InStr(RichTextBox1.SelStart, RichTextBox1.Text, " ") - 1
            RichTextBox1.SelStart = sLoc
            RichTextBox1.SelLength = eLoc - sLoc
        End If
        If Trim(RichTextBox1.SelText) <> "" Then
            For x = mnuWord.UBound To 1 Step -1
                Unload mnuWord(x)
            Next
            mnuWord(0).Caption = "NOT FOUND"
            For x = 0 To UBound(WORDLIST)
                tmp = Split(WORDLIST(x), ":")
                If tmp(0) = Trim(RichTextBox1.SelText) Then
                    wrds = Split(tmp(1), ";")
                    For I = 0 To UBound(wrds)
                        If I = 0 Then
                            mnuWord(0).Caption = wrds(I)
                        Else
                            Load mnuWord(I)
                            mnuWord(I).Visible = True
                            mnuWord(I).Caption = wrds(I)
                        End If
                    Next
                End If
            Next
            PopupMenu mnuPop
        End If
    End If
    
End Sub

[om-yousif]

yes "lookup word" should be ignored

thnks i will check this and tell you
thank u again

[om-yousif]

thanks STATIC
it works nicely

can i add the english translation to the popup for each option
the translations are between two plus signs +

[om-yousif]

oh there is an error said
(run time error '380' invalid property value'
points to this code

RichTextBox1.SelLength = eLoc - sLoc

specially when i click the last word in the text

what is the problem??

[Static]

sure...
this will add it...

but, u will need To change the "replace" Option so it does Not insert the translation As well

Private Sub GetData() 
    Dim tW As String 
    Dim tmp() As String 
    Dim Words() As String 
    Dim gloss() As String 
    Open App.Path & "\arabic.txt" For Input As #1 
        tmp = Split(Input(LOF(1), 1), vbCrLf) 
    Close #1 
    Dim sLine As String 
    For x = 0 To UBound(tmp) 
         
        If UCase(Left(tmp(x), 8)) = "SOLUTION" Then 
            Words = Split(tmp(x), "(") 
            If UCase(Left(tmp(x + 1), 7)) = "(GLOSS)" Then 
                sLine = sLine & Left(Words(1), InStr(Words(1), ")") - 1) 
                gloss = Split(tmp(x + 1), "+") 
                sLine = sLine & " (" & Trim(gloss(1)) & ");" 
            Else 
                sLine = sLine & Left(Words(1), InStr(Words(1), ")") - 1) & ";" 
            End If 
        ElseIf UCase(Left(tmp(x), 7)) = "COMMENT" Then 
            Words = Split(tmp(x), ":") 
            sLine = sLine & Words(1) 
        ElseIf UCase(Left(tmp(x), 5)) = "INPUT" Then 
            If sLine <> "" Then 
                If Right(sLine, 1) = ";" Then 
                    sLine = Left(sLine, Len(sLine) - 1) 
                End If 
                sLine = sLine & vbCrLf 
            End If 
            Words = Split(tmp(x), ":") 
            sLine = sLine & Trim(Words(1)) & ":" 
        ElseIf UCase(Left(tmp(x), 7)) = "LOOK-UP" Then 
            'nothing 
        End If 
    Next 
    Debug.Print sLine 
    WORDLIST = Split(sLine, vbCrLf) 
     
 
End Sub

[om-yousif]

thanks

very good

[om-yousif]

Static
i know that u r so busy
but could u please explain each line of code

because i need to undrstand every line

[bodoora]

Hi Static...
I used you code in replay #12, because I have in my program PopUp menu that appear by right click with some words (translation words), when we select the word from menu it is show next to the word in RichTextBox and if i select another word it show also next to it.
But I want to delete the first word i selected and print the second word i select it from menu.
How can I do that?