[2005] MemoryStream TextWriter

[GottaGetITDone]

Hi Guys,

Just having a small issue with a MemoryStream, I think my only real issue is lack of education.

I am wanting to dump a MemoryStream to a text file (.csv). Now I have some code here that does this but I'm left thinking there is a better or more elegant way to do this.

Private Sub StreamToFile(ByVal sFilePath As String, ByVal objStream As System.IO.MemoryStream)
 
        Dim objTxtWriter As System.IO.TextWriter = Nothing
        Dim objReader As System.IO.StreamReader = Nothing
 
        Try
            objTxtWriter = New System.IO.StreamWriter(sFilePath)
 
            objReader = New System.IO.StreamReader(objStream)
 
            objTxtWriter.Write(objReader.ReadToEnd())
 
            objReader.Close()
            objTxtWriter.Close()
 
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        Finally
            If objTxtWriter IsNot Nothing Then
                objTxtWriter.Dispose()
                objTxtWriter = Nothing
            End If
 
            objReader.Dispose()
        End Try

As you can see I am using a StreamReader to get the contents of the stream as a string and dump it. My gut feeling is that I should be able to dump this stream without using a reader?

Is the above method using a reader the only way? Can I feed a raw MemoryStream into a file??

I have done many searches but found only unlcear or incomplete answers.

Thanks PPL,
Matt.

[Mr.No]

Try the WriteTo method of the MemoryStream. The help says:

Writes the entire contents of this memory stream to another stream.

[jmcilhinney]

Using Mr.No's suggestion:

Private Sub StreamToFile1(ByVal sFilePath As String, ByVal objStream As System.IO.MemoryStream)
    Using sr As New IO.StreamWriter(sFilePath)
        objStream.WriteTo(sr.BaseStream)
    End Using
End Sub

or another way:

Private Sub StreamToFile2(ByVal sFilePath As String, ByVal objStream As System.IO.MemoryStream)
    Dim count As Integer = Convert.ToInt32(objStream.Length)
    Dim buffer(count - 1) As Byte
 
    objStream.Read(buffer, 0, count)
    IO.File.WriteAllBytes(sFilePath, buffer)
End Sub

[GottaGetITDone]

PEEEERRRRRRFECT!!!!!

That's exactly the sort of answer I was chasing. I knew there had to be a more elegant solution!

Thanks to the both of you, I had seen the WriteTo method but hadn't made the metal 'skip'.

Love your work JM!!!!! Love it!

Again thank you to you both...

[jmcilhinney]

You could just use a FileStream and forget the StreamWriter too. In that case:

Using sr As New IO.StreamWriter(sFilePath)
        objStream.WriteTo(sr.BaseStream)
    End Using

would become:

Using fs As New IO.FileStream(sFilePath, IO.FileMode.Create)
        objStream.WriteTo(fs)
    End Using