[RESOLVED] Class Events?

[Fedhax]

I've coded myself into a corner, and I don't even know which terms/words to use to search for a solution to solve my problem. My original goal was that I noticed I was using the same kinds of controls and control names for multiple forms: lblTitleBar, lblCmd1, lblCmd2, cmdTmr, etc. I figured that I could consolidate this duplicated code into a class and create an instance on each form. At that point, my basic controls would be setup, formatted, and ready to use for each form. As it stands now, the visible GUI part is working as planned, but I can't figure out how to now capture the events for these objects. Am I not setting them up properly? Is there a way I can pass basic VB events (Click, DblClick, MouseMove, etc) to the class or reference these events on the parent form?

Now, I've seen that I can create the variables on each form and then, they will work as planned, but it would kinda defeat the purpose of trying to centralize the code if I still need to have multiple variable declarations, etc per form, no?

Option Explicit
 
'clsForm
Public lblTitleBar          As Label
Public lblCmd1              As Label
Public lblCmd2              As Label
 
Private foForm              As Form
 
Private cmdTmr              As Timer
 
Private shpTitleBar         As Shape
Private shpForm             As Shape
 
Public Sub NewObject(ByRef roForm As Form)
    
    Dim li          As Integer
 
    Set foForm = roForm
 
    Set lblTitleBar = foForm.Controls.Add("VB.Label", "lblTitleBar")
    
    Set lblCmd1 = foForm.Controls.Add("VB.Label", "lblCmd1")
    Set lblCmd2 = foForm.Controls.Add("VB.Label", "lblCmd2")
    
    Set cmdTmr = foForm.Controls.Add("VB.Timer", "cmdTmr")
    
    Set shpTitleBar = foForm.Controls.Add("VB.Shape", "shpTitleBar")
    Set shpForm = foForm.Controls.Add("VB.Shape", "shpForm")
    
    ' Label Objects
    With lblTitleBar
    
        ' Dimensions
        .Top = 2
        .Left = 2
        .Width = roForm.ScaleWidth - 4
        .Height = 19
        
        ' Visibility
        .Visible = True
        .BorderStyle = 0
        
        ' Color
        .BackColor = &H808080
        .ForeColor = &H80000009
        
        ' Text
        .Caption = "Test_Form"
        .Font.Bold = True
        .Font.Name = "MS Sans Serif"
        
    End With
    
    With lblCmd1
                
        ' Dimensions
        .Width = 16
        .Height = 16
        .Top = lblTitleBar.Top + 1
        .Left = roForm.ScaleWidth - 3 - .Width
        
        ' Visibility
        .Visible = True
        .BackStyle = 0      ' Transparent
        .BorderStyle = 1    ' Fixed Single
        .Appearance = 0     ' Flat
        .Alignment = 2      ' Centered
                    
        ' Text
        .Caption = "X"
        .Font.Bold = True
        .Font.Name = "Verdana"
        
        .ZOrder
        
    End With
                
 
    With lblCmd2
    
        ' Dimensions
        .Width = 16
        .Height = 16
        .Top = lblTitleBar.Top + 1
        .Left = roForm.ScaleWidth - 4 - (.Width * 2)
        
        ' Visibility
        .Visible = True
        .BackStyle = 0      ' Transparent
        .BorderStyle = 1    ' Fixed Single
        .Appearance = 0     ' Flat
        .Alignment = 2      ' Centered
                    
        ' Text
        .Caption = "_"
        .Font.Bold = True
        .Font.Name = "Verdana"
        
        .ZOrder
                
    End With
 
    ' Shape Objects
    With shpTitleBar
        .Left = 1
        .Top = 1
        .Width = roForm.ScaleWidth - 2
        .Height = lblTitleBar.Height + 2
        .Visible = True
    End With
 
    With shpForm
        .Left = 1
        .Top = shpTitleBar.Height + shpTitleBar.Top + 1
        .Width = shpTitleBar.Width
        .Height = roForm.ScaleHeight - lblTitleBar.Height - 4
        .Visible = True
    End With
 
End Sub

Now, all I want to do is know when someone clicks or when the mouse is over one of these newly created labels...

Option Explicit
' Main Form
Private foFormCls       As clsForm
 
Private Sub Form_Load()
    
    Set foFormCls = New clsForm
    
    Call foFormCls.NewObject(Me)
 
End Sub
 
Private Sub lblTitleBar_Click()
   Msgbox "Doesn't Work"
End Sub

( I've attached a sample screenshot to show how the GUI appears. If you don't click on one of the labels, Form_Click(), etc will fire. )

[Fedhax]

I know that this solution works, but surely there is a better way?

Option Explicit
' Main Form
Dim WithEvents foFormCls       As clsForm
Dim WithEvents lblTitleBar     As Label
 
Private Sub Form_Load()
    
    Set foFormCls = New clsForm
    Call foFormCls.NewObject(Me)
    
    Set lblTitleBar = foFormCls.lblTitleBar
 
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
 
    Set foFormCls = Nothing
 
End Sub
 
Private Sub lbltitlebar_Click()
 
    MsgBox "Here2"
 
End Sub

[bushmobile]

make a basic form with your GUI and all the setup code already in place - then save it as a template and you won't have to recode it everytime (or mess around with a class)

[Fedhax]

make a basic form with your GUI and all the setup code already in place - then save it as a template and you won't have to recode it everytime (or mess around with a class)

It may accomplish the same feat as what I want, but I'm confused as to how you transfer the "setup code" between the template and the instances. Also, the form properties will be different between each form, but the controls follow basic formulas to fit onto the form. Could you provide me with an example?

It isn't something along of the line of:

Private WithEvents foForm     as Form
 
Private Sub Form_Load()
 
   Set foForm = frmTemplate
 
End Sub

[bushmobile]

what i meant is that when you go to Project | Add Form you have a number of templates that you can choose from

create your own and stick it in the Template folder:
C:\Program Files\Microsoft Visual Studio\VB98\Template\Forms
in my case.

that's just one option.

[Fedhax]

what i meant is that when you go to Project | Add Form you have a number of templates that you can choose from

create your own and stick it in the Template folder:
C:\Program Files\Microsoft Visual Studio\VB98\Template\Forms
in my case.

that's just one option.

Oh, I see. Interesting thought. I guess as long as I didn't want to make changes to the code it would work. However, my "template" form includes some kinds of form validation code, form/window docking, mouseover functionality too. If push comes to shove, you're right that I can make a template and have this basic functionality ready to be enhanced. If I went the route of using classes & events, how would it work that way?

[Fedhax]

If I went the route of using classes & events, how would it work that way?

Bump?

[penagate]

I am confused whats the problem in simple form?

[Fedhax]

I am confused whats the problem in simple form?

Using code that I've found on this forum and other forums, I have added enhancements: Windows/Border Docking, MouseOver functionality, etc that I would like to carry across all of my forms for this application. After developing 3 forms, I found myself doing a copy/paste on each new form to carry forward this enhanced functionality. Then, it dawned on me if I needed to fix/correct/enhance this functionality, I'd have to make the changes on each form individually. This line of thought led me to ask how I could write the code for this functionality once and use it multiple times which made me think of Global functions (kludgy?) or a Class.

The problems with a class is capturing the form's events and passing it on to the class which led me to writing code like:

Public WithEvents foFormCls             As clsForm
 
Private WithEvents lblTitleBar          As Label
Private WithEvents lblCmdEnd            As Label
Private WithEvents lblCmdMinimize       As Label
 
Private WithEvents cmdTmr               As Timer
 
'*************************************************
'***    Form
'*************************************************
 
Private Sub Form_Load()
    
    Set foFormCls = New clsForm
        Call foFormCls.NewObject(Me)
        Call foFormCls.Set_WindowState(geDisplayType.Frame)
    
        Set lblTitleBar = foFormCls.lblTitleBar
        Set lblCmdEnd = foFormCls.lblCmdEnd
        Set lblCmdMinimize = foFormCls.lblCmdMinimize
    
        Set cmdTmr = foFormCls.cmdTmr
    ' Finished with Class
 
End Sub
 
Private Sub Form_GotFocus()
 
    Call foFormCls.Form_GotFocus
 
End Sub
 
Private Sub Form_LostFocus()
 
    Call foFormCls.Form_LostFocus
 
End Sub
 
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
 
    Call foFormCls.Form_MouseMove(Button, Shift, X, Y)
 
End Sub

Ultimately, is this implementation the best way to do it or should I be looking into other avenues to use my form class and pass on events from the main form to the class?

[chemicalNova]

The main solution I can see is to create a window completely through the API in each class. That way, you have complete control over how its drawn.

I still have this example I gave to someone on these forums over a year ago. Check it out..

chem

[penagate]

The problems with a class is capturing the form's events and passing it on to the class which led me to writing code like:

[snip]

Ultimately, is this implementation the best way to do it or should I be looking into other avenues to use my form class and pass on events from the main form to the class?

I see now. You're halfway there as you have declared the class WithEvents on the form. You need to do the same in reverse as well so that the class receives and can handle the events of the form. You already have a variable reference in the class pointing to the form, it is just a matter of adding the WithEvents modifier. Then, you can code any form event handlers using the notation foForm_eventname.

[Fedhax]

I see now. You're halfway there as you have declared the class WithEvents on the form. You need to do the same in reverse as well so that the class receives and can handle the events of the form. You already have a variable reference in the class pointing to the form, it is just a matter of adding the WithEvents modifier. Then, you can code any form event handlers using the notation foForm_eventname.

Wow. Just wow... Now, my spaghetti code is in one class and the forms now use only 20-25 lines of code--with white spaces--to provide that functionality. It's tighter; it's cleaner; it works. I'm impressed. I'm sure that I'll see how else I can push the boundry, but for now, this issue is resolved.

Thanks for the API code and assistance.

[penagate]

I'm glad you solved it.

Remember, if code ever feels messy, that means it is.