[FAQ's: OD] How do I automate an Office App using VB.NET?

[RobDog888]

VB.NET 2003 Late Binding Automation Code Example:

Option Explicit On 
'Option Strict Off is needed to allow the late binding
Option Strict Off

'Late Binding Automation FAQ Example
Public Class Form1

    Inherits System.Windows.Forms.Form

    "Windows Form Designer generated code"

    'Declare our Application Object as an unknown generic Object
    Public moApp As Object

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        'Declare and create a Workbook object
        Dim oWB As Object = moApp.Workbooks.Add()
        'Make it Visible to the user now that we are going to use it
        moApp.Visible = True
        'Write some text into Cell A1 on Sheet1
        oWB.Sheets("Sheet1").Cells(1, 1).Value = "Meow!"
        'Make sure our object variable is destroyed and released since its going out of scope
        oWB = Nothing
    End Sub

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Create our generic unknown object variable and trap for Excel not installed
        Try
            moApp = CreateObject("Excel.Application")
            'Keep it hidden from the user until we need to use it
            moApp.Visible = False
        Catch ex As Exception
            MessageBox.Show(ex.Message, "VB/Office Guru™ Excel Late Binding VB.NET Automation FAQ", _
            MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
        End Try
    End Sub

    Private Sub Form1_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) _
    Handles MyBase.Closing
        'Check if Excel Application is still instanciated
        If IsNothing(moApp) = False Then
            'Check if our Excel instance has any opened workbooks in it
            If moApp.Workbooks.Count > 0 Then
                'Close all open workbooks not saving them
                'Loop backwards so the index information will be relevant as they close
                For i As Integer = moApp.Workbooks.Count To 1 Step -1
                    moApp.Workbooks.Item(i).Close(SaveChanges:=False)
                Next
            End If
            'Close our Excel Application object
            moApp.Quit()
        End If
        'Make sure its destroyed
        moApp = Nothing
        'Absolutely none of our Excel instances will be left running!
    End Sub

End Class