Runtime Error 3021

[khanjan_a2k]

Hey all,
I am testing a http link search robot I created. I am getting a Runtime Error 3021 which I don't know a lot about. I was hoping some of you could help.

The message I get is:

Run-time error '3021':

Either BOF or EOF is True, or the current record has been deleted. Requested operation requires a current record.

When I click on the Debug button, it gives me the following statement to fix:

buf = rsURL!URL & " (" & rsURL!relevance & ")"

Thank you for your help in advance.

Khanjan

[Joacim Andersson]

Well, there is nothing wrong with that line of code by itself. However if you want to get the value of a recordset field it must contain something. According to the error message the recordset is either empty or not currently pointing to any record. Normally before you read from a recordset you would first check that the EOF (End Of File) property isn't true. Can you show a little bit more of your code?

[khanjan_a2k]

Here is my program.
Anyways sorry its time for me to go to bed. I will reply again tomorrow.

Khanjan

[Al42]

Post it as a .zip file. Many people have no way of opening a .rar file. It would also help you to get an answer if you indicated which form the error occurred in (and which sub or function).

[Joacim Andersson]

Actually it would be enough if you posted the code in the procedure the error line is in.

[khanjan_a2k]

Hi,
Here is the code.

Private Sub Form_Load()
 
Dim strConnect As String
Dim buf As String
Dim SQLString As String
 
strConnect = "Provider=Microsoft.Jet.OLEDB.3.51;"
strConnect = strConnect & "Persist Security Info=False;"
strConnect = strConnect & "Data Source = " & gDataFileName
 
Set cnLinks = New ADODB.Connection
Set rsURL = New ADODB.Recordset
 
cnLinks.ConnectionString = strConnect
cnLinks.ConnectionTimeout = 10
cnLinks.CursorLocation = adUseNone
cnLinks.Open
 
SQLString = "Select * from links where relevance > 0 "
SQLString = SQLString & "order by relevance"
 
rsURL.Open SQLString, cnLinks, adOpenDynamic, adLockOptimistic, adCmdText
 
Do
 
    buf = rsURL!URL & " (" & rsURL!relevance & ")"
    lstReport.AddItem buf
    rsURL.MoveNext
    
Loop While Not rsURL.EOF
 
End Sub

And I have also attached the program in .zip format.

Khanjan

[si_the_geek]

Your loop keeps going until you reach the end of the recordset (after all the records).. but it seems that you are already at the end of the recordset before the loop starts - which is why there is no data to be retrieved by that line (and hence the error).

You need to basically not let the loop run if there is no data, which can be done by:
a) Putting an IF block around the loop. eg:

If Not rsURL.EOF Then
  Do
    ...
  Loop While Not rsURL.EOF
End If

or b) Changing the structure of the loop slightly (so it is never entered if there is no data - but still exits at the end of the data), eg:

Do While Not rsURL.EOF
  ...
Loop