Generalitites

[Seeker870]

For all of the documentation there is very little to do with specific statements.
And I'm new to API's.
So, can someone state, simply, the general rules of using API's.
Or perhaps more specifically DrawFocusRect. Of course, that will be the first of many.

From the API-Guide:

Function name: DrawFocusRect
Library: User32
Min. required OS: Windows NT 3.1 or later; Windows 95 or later
Description: The DrawFocusRect function draws a rectangle in the style used to indicate that the rectangle has the focus.


Example:

Const DC_ACTIVE = &H1
Const DC_ICON = &H4
Const DC_TEXT = &H8
Const BDR_SUNKENOUTER = &H2
Const BDR_RAISEDINNER = &H4
Const EDGE_ETCHED = (BDR_SUNKENOUTER Or BDR_RAISEDINNER)
Const BF_BOTTOM = &H8
Const BF_LEFT = &H1
Const BF_RIGHT = &H4
Const BF_TOP = &H2
Const BF_RECT = (BF_LEFT Or BF_TOP Or BF_RIGHT Or BF_BOTTOM)
Const DFC_BUTTON = 4
Const DFC_POPUPMENU = 5            'Only Win98/2000 !!
Const DFCS_BUTTON3STATE = &H10
Const DT_CENTER = &H1
Const DC_GRADIENT = &H20          'Only Win98/2000 !!
Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
Private Declare Function DrawCaption Lib "user32" (ByVal hWnd As Long, ByVal hdc As Long, pcRect As RECT, ByVal un As Long) As Long
Private Declare Function DrawEdge Lib "user32" (ByVal hdc As Long, qrc As RECT, ByVal edge As Long, ByVal grfFlags As Long) As Long
Private Declare Function DrawFocusRect Lib "user32" (ByVal hdc As Long, lpRect As RECT) As Long
Private Declare Function DrawFrameControl Lib "user32" (ByVal hdc As Long, lpRect As RECT, ByVal un1 As Long, ByVal un2 As Long) As Long
Private Declare Function DrawText Lib "user32" Alias "DrawTextA" (ByVal hdc As Long, ByVal lpStr As String, ByVal nCount As Long, lpRect As RECT, ByVal wFormat As Long) As Long
Private Declare Function SetRect Lib "user32" (lpRect As RECT, ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
Private Declare Function OffsetRect Lib "user32" (lpRect As RECT, ByVal x As Long, ByVal y As Long) As Long
Private Sub Form_Paint()
    'KPD-Team 1999
    'URL: http://www.allapi.net/
    'E-Mail: [email protected]
    Dim R As RECT
    'Clear the form
    Me.Cls
    'API uses pixels
    Me.ScaleMode = vbPixels
    'Set the rectangle's values
    SetRect R, 0, 0, Me.ScaleWidth, 20
    'Draw a caption on the form
    DrawCaption Me.hWnd, Me.hdc, R, DC_ACTIVE Or DC_ICON Or DC_TEXT Or DC_GRADIENT
    'Move the recatangle
    OffsetRect R, 0, 22
    'Draw an edge on our window
    DrawEdge Me.hdc, R, EDGE_ETCHED, BF_RECT
    OffsetRect R, 0, 22
    'Draw a focus rectangle on our window
    DrawFocusRect Me.hdc, R
    OffsetRect R, 0, 22
    'Draw a frame control on our window
    DrawFrameControl Me.hdc, R, DFC_BUTTON, DFCS_BUTTON3STATE
    OffsetRect R, 0, 22
    'draw some text on our form
    DrawText Me.hdc, "Hello World !", Len("Hello World !"), R, DT_CENTER
End Sub

Hope that helps.

Basically, all it does is draw the focus rectangle on a specified control.

This example will draw the focus rectangle on a PictureBox.

Private Type RECT
    Left As Long
    Top As Long
    Right As Long
    Bottom As Long
End Type
Private Declare Function DrawFocusRect Lib "user32" (ByVal hdc As Long, lpRect As RECT) As Long
Private Declare Function GetClientRect Lib "user32" (ByVal hwnd As Long, lpRect As RECT) As Long

Private Sub Command1_Click()
    Dim RC As RECT
    GetClientRect Picture1.hwnd, RC
    DrawFocusRect Picture1.hdc, RC
    Picture1.Refresh
End Sub

Private Sub Form_Load()
    Picture1.AutoRedraw = True
End Sub