Outlook task event

[charmer]

I am using outlook 2003 you can assign a task and send it to another person and it stays in the other person email until he accepts it, i want to automatically accept the task for the user, i can't find an event which gets triggered
can anyone there help me please
thanks heaps

[charmer]

Hi, i found this

This Microsoft Visual Basic/Visual Basic for Applications (VBA) example accepts a TaskRequestItem, sending the response without displaying the inspector.

Sub AcceptTask()
Dim myOlApp As New Outlook.Application
Dim myNameSpace As Outlook.NameSpace
Dim myTasks As Outlook.MAPIFolder
Dim myNewTaskItem As Outlook.TaskItem
Dim mytaskreqItem As Outlook.TaskRequestItem
Dim myItem As Outlook.TaskItem
Set myNameSpace = myOlApp.GetNamespace("MAPI")
Set myTasks = myNameSpace.GetDefaultFolder(olFolderInbox)
Set mytaskreqItem = myTasks.Items.Find("[Subject] = ""Meeting w/ Nate Sun""")
If Not TypeName(mytaskreqItem) = "Nothing" Then
Set myNewTaskItem = mytaskreqItem.GetAssociatedTask(True)
Set myItem = myNewTaskItem.Respond(olTaskAccept, True, True)
myItem.Send
End If
End Sub

however i think this one assumes that we know the subject name of the email that has the taskrequestitem is there's a way to go around that?
or even another totally different way @@?

[Comintern]

Can't you just catch them in the inbox when new mail arrives? Here's a bit of sample code, you'll have to add something to screen the ones that you want to autorespond to, but this should give you a start. Drop this "ThisOutlookSession".

Private Sub Application_NewMail()
 
    Dim oInBox As MAPIFolder, oItem As Object, oResponse As TaskItem
    
    Set oInBox = Application.GetNamespace("MAPI").GetDefaultFolder(olFolderInbox)
    
    For Each oItem In oInBox.Items
        If TypeName(oItem) = "TaskItem" Then
            Set oResponse = oItem.Respond(olTaskAccept, True, False)
            oResponse.Send
        End If
    Next oItem
 
    Set oResponse = Nothing
    Set oInBox = Nothing
 
End Sub

[RobDog888]

Since your using Outlook 2003 you can use the Application_NewMailEx event as it passes in a parameter of the newmailitem. Then instead of looping through the items you can just use the referenced Item and test for its type and/or its subject like you were doing.