Code copied from VB to Notepad

[Jacob Roman]

Seems VBForums has issues when I copy and paste code straight from VB, especially with missing tabs or newlines.:

Option Explicit
 
Public Function Calculate_Angle(X1 As Single, Y1 As Single, X2 As Single, Y2 As Single) As Single
    
    Const PI As Single = 3.141592654
    
    Dim DX As Single, DY As Single
    Dim Angle As Single
 
        DX = X2 - X1
        DY = Y2 - Y1
        
        Angle = 0
 
        If DX = 0 Then
        
            If DY = 0 Then
            
                Angle = 0
                
            ElseIf DY > 0 Then
            
                Angle = PI / 2
            
            Else
                
                Angle = PI * 3 / 2
                
            End If
        
        ElseIf DY = 0 Then
 
            If DX > 0 Then
            
                Angle = 0
                
            Else
            
                Angle = PI
            
            End If
        
        Else
        
            If DX < 0 Then
            
                Angle = Atn(DY / DX) + PI
                
            ElseIf DY < 0 Then
            
                Angle = Atn(DY / DX) + (2 * PI)
                
            Else
            
                Angle = Atn(DY / DX)
                
            End If
            
            
        End If
 
        Angle = Angle * 180 / PI
 
        Calculate_Angle = Angle
 
End Function
 
Private Sub Form_Activate()
 
    AutoRedraw = True
    ScaleMode = 3
    BackColor = RGB(0, 0, 0)
    
    Circle (Me.ScaleWidth / 2, Me.ScaleHeight / 2), 50, RGB(0, 255, 0)
    
End Sub
 
Private Sub Form_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
    
    Dim Angle As Single
    
    Angle = Calculate_Angle(Me.ScaleWidth / 2, Me.ScaleHeight / 2, X, Y)
    
    Me.Caption = Angle
 
End Sub

[Jacob Roman]

Well that didn't work. Might as well upload this then: