write XML file

[Navarone]

I have been reading thru some threads and looked trhu the tutorials bank and I really couldn't find what I was looking for. Can I use FSO to write an XML file or is there a better way. I have a directory list box that I use to find a FLV file, I need to pass the file name into the xml file in this format.

I am sure this is something that has been asked and answered 1000 times, but I couldn't find a simple example. I searched under "write XML and create XML"

Thanks for any help.

<videos>
    <video>
        <videoName>video</videoName>
    </video>    
</videos>

[Navarone]

ok, I did some searching on the MSDN site but I am having trouble getting the format to look correct. I need to add another node called videoName, any help appreciated.

Private Sub Form_Load()
    'play shockwav movie
    ShockwaveFlash1.Movie = App.Path & "\XML_FLV_player.swf"
    
    Dim dom, node, attr
    On Error GoTo ErrorHandler
    Set dom = CreateDOM
    
    ' Create a processing instruction targeted for xml.
    Set node = dom.createProcessingInstruction("xml", "version='1.0' encoding='UTF-8'")
    dom.appendChild node
    Set node = Nothing
    
    ' Create a comment for the document.
    Set node = dom.createComment("sample xml file created using XML DOM object.")
    dom.appendChild node
    Set node = Nothing
    
    ' Create the root element.
    Dim root
    Set root = dom.createElement("videos")
    
'    ' Create a "created" attribute for the root element and
'    ' assign the "using dom" character data as the attribute value.
'    Set attr = dom.createAttribute("created")
'    attr.Value = "using dom"
'    root.setAttributeNode attr
'    Set attr = Nothing
    
    ' Add the root element to the DOM instance.
    dom.appendChild root
    ' Insert a newline + tab.
    root.appendChild dom.createTextNode(vbNewLine + vbTab)
    ' Create and add more nodes to the root element just created.
    ' Create a text element.
    Set node = dom.createElement("video")
    node.Text = "some character data"
    ' Add text node to the root element.
    root.appendChild node
    Set node = Nothing
      ' Add a newline plus tab.
    root.appendChild dom.createTextNode(vbNewLine + vbTab)
    
    ' Save the XML document to a file.
    dom.save App.Path + "\dynamDom.xml"
    Set root = Nothing
    Set dom = Nothing
    Exit Sub
    
ErrorHandler:
    MsgBox Err.Description
End Sub

[cssriraman]

Sub Create_XML(oXMLfile As String)
'This procedure is used to create XML document
' <Family>
'    <Member Relationship="Father">
'       <Name>Some Guy</Name>
'    </Member>
' </Family>
' Requires msxml.dll (Go to Project --> References and and choose Microsoft XML version 2.0, or whatever the
' current version you have installed)
    Dim objDom As DOMDocument
    Dim objRootElem As IXMLDOMElement
    Dim objSubRootElem As IXMLDOMElement
    Dim objMemberElem As IXMLDOMElement
 
    Set objDom = New DOMDocument
 
    ' Creates root element
    Set objRootElem = objDom.createElement("ErrorLog")
    objDom.appendChild objRootElem
 
    ' Creates sub root element
    Set objSubRootElem = objDom.createElement("Error")
    objRootElem.appendChild objSubRootElem
 
    ' Creates Error Date & Time element
    Set objMemberElem = objDom.createElement("ErrorDateTime")
    objSubRootElem.appendChild objMemberElem
    objMemberElem.Text = Format(Now, "DD-MMM-YYYY hh:mm:ss")
 
    ' Creates User Name element
    Set objMemberElem = objDom.createElement("UserName")
    objSubRootElem.appendChild objMemberElem
    objMemberElem.Text = "TestUser"
 
    ' Creates Machine Name element
    Set objMemberElem = objDom.createElement("MachineName")
    objSubRootElem.appendChild objMemberElem
    objMemberElem.Text = "YourMachineName"
 
    ' Creates Procedure Name element
    Set objMemberElem = objDom.createElement("ProcName")
    objSubRootElem.appendChild objMemberElem
    objMemberElem.Text = "Test Procedure"
 
    ' Creates Error Number element
    Set objMemberElem = objDom.createElement("ErrNo")
    objSubRootElem.appendChild objMemberElem
    objMemberElem.Text = "Err_Number"
 
    ' Creates Error Description element
    Set objMemberElem = objDom.createElement("ErrDesc")
    objSubRootElem.appendChild objMemberElem
    objMemberElem.Text = "Test Error. Access Denied. Please retry after sometime."
 
    ' Saves XML data to disk.
    objDom.save oXMLfile
ExitHere:
    Err.Clear
    Set objDom = Nothing
End Sub