how to plot 3d

[cyborg]

Hi!

I have the coordinates for a box and i want to plot it in 3d.

If the camera is still and just a bit over the box so i can see the front and top, how do i calculate the positions of the coordinates?

I just want to use some simple methods for plotting, like setpixel or line, not directx.

[dafhi]

zip now contains 2 graphics dma 'bare-bones' projects

[cyborg]

wow....good work! this was both fast and easy! but it wasnt the answer to this question



in a 3d box when you look at the corners in the back of it....they seem to be closer to each other than they really are...the further back they are, the closer and smaller they appear to be! how do i calculate this?

[Fox]

Truly simple:

ScreenX = (X / Z) and
ScreenY = (Y / Z)

Example:

'This is your point
private Type tPoint3D
    x as single
    y as single
    z as single
end Type
 
'This line type connects 2 points
private Type tLine
    p1 as Long
    p2 as Long
end Type
 
'This will become a cube
dim p(7) as tPoint3D
dim l(11) as tLine
 
Private Sub Form_Load()
    'Define the edge points
 
    'Top rect
    with p(0): .x = -1: .y = -1: .z = 1: end with
    with p(1): .x = 1: .y = -1: .z = 1: end with
    with p(2): .x = 1: .y = 1: .z = 1: end with
    with p(3): .x = -1: .y = 1: .z = 1: end with
    'Bottom rect
    with p(4): .x = -1: .y = -1: .z = -1: end with
    with p(5): .x = 1: .y = -1: .z = -1: end with
    with p(6): .x = 1: .y = 1: .z = -1: end with
    with p(7): .x = -1: .y = 1: .z = -1: end with
 
    'Define the lines
 
    'Top rect
    with l(0): .p1 = 0: .p2 = 1: end With
    with l(1): .p1 = 1: .p2 = 2: end With
    with l(2): .p1 = 2: .p2 = 3: end With
    with l(3): .p1 = 3: .p2 = 0: end With
    'Bottom rect
    with l(4): .p1 = 4: .p2 = 5: end With
    with l(5): .p1 = 5: .p2 = 6: end With
    with l(6): .p1 = 6: .p2 = 7: end With
    with l(7): .p1 = 7: .p2 = 4: end With
    'Connectors
    with l(8): .p1 = 0: .p2 = 4: end With
    with l(9): .p1 = 1: .p2 = 5: end With
    with l(10): .p1 = 2: .p2 = 6: end With
    with l(11): .p1 = 3: .p2 = 7: end With
 
    'Setup the form for drawing
    scaleMode = vbPixels
End Sub
 
Public Sub Form_MouseDown(b As integer, s As integer, x As single, y As single)
    'Draw the lines
    dim A as Long
 
    'This will be screen coordinates
    dim x1 as long
    dim x2 as long
 
    dim y1 as long
    dim y2 as long
 
    'This is the screen middle
    dim tX as long
    dim tY as long
 
    'Get screen middle
    tX = (scaleWidth / 2)
    tX = (scaleHeight / 2)
 
    'Since 3d positions are relative we need a size
    Dim size As Single
    size = 100
 
    'The camera says where to draw the cube
    dim cam As tPoint3D
 
    'Move camera with mouse
    cam.x = (x - tX) / size
    cam.y = (y - tY) / size
    cam.z = 5
 
    'FOV (field-of-view) corrects the stretching
    dim fov as single
    fov = 3
 
    me.Cls
    for a = 0 to uBound(l)
        'Get screen coordinates of both points
        with p(l(a).p1)
            x1 = (.x + cam.x) / (.z + cam.z) * size * fov
            y1 = (.y + cam.y) / (.z + cam.z) * size * fov
        end with
        with p(l(a).p2)
            x2 = (.x + cam.x) / (.z + cam.z) * size * fov
            y2 = (.y + cam.y) / (.z + cam.z) * size * fov
        end with
 
        'Draw line (origin at screen center)
        Line (x1+tX, y1+tY)-(x2+tX, y2+tY)
    next
End Sub

[cyborg]

thanks alot!
that was great!

do you also know how to rotate the camera/box around different axis?

[petrus]

Originally posted by cyborg
thanks alot!
that was great!

do you also know how to rotate the camera/box around different axis?

Snart vill du ha texturer också!

[cyborg]

hehe...nej då =)
i just want to be able to draw some objects (stored in maps files(i can do the loading function by myself)) and then move around them how i want to....turn the mouse to look around and press the arrow keys to move around......no light, no textures or anything special...

[Fox]

Sure.. this is the formula for a z-rotation:

newX = (x * Sin( angle )) + (y * Cos( angle ))
newY = (x * Cos( angle )) - (y * Sin( angle ))

And here's the modified draw function (get rest from first example) - changed parts are red:

Public Sub Form_MouseMove(b As Integer, s As Integer, x As Single, y As Single)
    'Draw the lines
    Dim A As Long

    'This will be screen coordinates
    Dim x1 As Long
    Dim x2 As Long

    Dim y1 As Long
    Dim y2 As Long
    
    'Temporary rotated points
    Dim p1 As tPoint3D
    Dim p2 As tPoint3D
    
    Dim r1 As tPoint3D
    Dim r2 As tPoint3D
    
    'This is the screen middle
    Dim tX As Long
    Dim tY As Long

    'Get screen middle
    tX = (ScaleWidth / 2)
    tX = (ScaleHeight / 2)

    'Since 3d positions are relative we need a size
    Dim size As Single
    size = 100

    'The camera says where to draw the cube
    Dim cam As tPoint3D

    'Move camera with mouse
    cam.x = (200 - tX) / size
    cam.y = (150 - tY) / size
    cam.z = 5
        
    'We also want a rotation
    Dim rot As Single
    
    'Rotate by mouse
    rot = x / 100
    
    'FOV (field-of-view) corrects the stretching
    Dim fov As Single
    fov = 3

    Me.Cls
    For A = 0 To UBound(l)
    
        'Get points
        p1 = p(l(A).p1)
        p2 = p(l(A).p2)
        
        'Rotate the points
        With p1
            r1.x = (.x * Sin(rot)) + (.y * Cos(rot))
            r1.y = (.x * Cos(rot)) - (.y * Sin(rot))
            r1.z = p1.z
        End With
        
        With p2
            r2.x = (.x * Sin(rot)) + (.y * Cos(rot))
            r2.y = (.x * Cos(rot)) - (.y * Sin(rot))
            r2.z = p2.z
        End With
         
        'Get screen coordinates of both points
        With r1 
            x1 = (.x + cam.x) / (.z + cam.z) * size * fov
            y1 = (.y + cam.y) / (.z + cam.z) * size * fov
        End With
        With r2 
            x2 = (.x + cam.x) / (.z + cam.z) * size * fov
            y2 = (.y + cam.y) / (.z + cam.z) * size * fov
        End With
           
        'Draw line (origin at screen center)
        Line (x1 + tX, y1 + tY)-(x2 + tX, y2 + tY)
    Next
End Sub

[Fox]

*reads question again* umm for different axes? Don't know this by hard, let my find a older project..


here we are, i'm sure you can work out this snippet:

'Types
    Public Type tPosition
        'Position info
        x As Double
        y As Double
        z As Double
    End Type
    
    Public Type tRotation
        'Rotation info
        rX As Double
        rY As Double
        rZ As Double
        
        'Lookup values
        SinX As Double
        CosX As Double
        
        SinY As Double
        CosY As Double
        
        SinZ As Double
        CosZ As Double
    End Type
 
Public Function RotatePosition(iPosition As tPosition, iRotation As tRotation) As tPosition
    Dim TempX As Double
    Dim TempY As Double
    Dim TempZ As Double
    
    With iRotation
        'Calculate coordinates
        TempX = .CosZ * iPosition.x
        TempY = .SinZ * iPosition.y
        TempZ = .CosY * iPosition.z
        
        Dim Temp As Double
        Temp = iPosition.y * .CosZ + iPosition.x * .SinZ
        
        'Get position
        RotatePosition.x = (.CosY * (TempX - TempY) + .SinY * iPosition.z)
        RotatePosition.y = (.SinX * (.SinY * TempX - .SinY * TempY - TempZ) + .CosX * Temp)
        RotatePosition.z = (.CosX * (-.SinY * TempX + .SinY * TempY + TempZ) + .SinX * Temp)
    End With
End Function

[alkatran]

You have to rotate around each axis one after the other. The order is VERY important for this!!

I use 'pitch' and 'rotation' when I do mine. I rotate by pitch, then by rotation. (Look up/down then turn around)

[damasterjo]

this thread was asked in 2003

[alkatran]

this thread was asked in 2003

Bah, I hate it when I forget I'm inside a search box! There needs to be a warning for stupid people like me.