Access FTP Server

[khanjan_a2k]

Hello people,
Instead of creating resource files, what I want to do is that while my program is loading, I want my program to access a ftp server account and copy certain files on the ftp server account.

I have been told that the proper way to do this is by using the INet control. I tried searching on the forums, but it was hard to find anything useful. I haven't found anything so far and I haven't used an INet control before neither heard of it. So I someone can find me a tutorial or atleast tell me how to access a certain ftp and copy the files, I would really appreciate it.

Thank You all in advance

Khanjan

[dglienna]

I would have your program write a batch file that sends the files using the ftp command built into windows. After it's written, your app could just shell it to send the files.

Figure out how to send the files from a command prompt using the FTP command, and then write those commands into a file.

[oh1mie]

Try this:

Option Explicit
 
Public Const INTERNET_OPEN_TYPE_DIRECT = 1                         ' direct to net
Public Const INTERNET_OPEN_TYPE_PROXY = 3                          ' via named proxy
Public Const INTERNET_OPEN_TYPE_PRECONFIG_WITH_NO_AUTOPROXY = 4    ' prevent using java/script/INS
Public Const INTERNET_FLAG_PASSIVE = &H8000000             ' used for FTP connections
Public Const INTERNET_FLAG_RELOAD = &H80000000
 
' additional cache flags
Public Const INTERNET_FLAG_NO_CACHE_WRITE = &H4000000      ' don't write this item to the cache
 
' additional flags
Public Const INTERNET_DEFAULT_FTP_PORT = 21                ' default for FTP servers
Public Const INTERNET_FLAG_EXISTING_CONNECT = &H20000000   ' FTP: use existing InternetConnect handle for server if possible
Public Const INTERNET_SERVICE_FTP = 1
 
 
Public Declare Function InternetOpen Lib "Wininet.dll" _
   Alias "InternetOpenA" _
  (ByVal lpszAgent As String, _
   ByVal dwAccessType As Long, _
   ByVal lpszProxyName As String, _
   ByVal lpszProxyBypass As String, _
   ByVal dwFlags As Long) As Long
 
Public Declare Function InternetCloseHandle Lib "Wininet.dll" _
   (ByVal hEnumHandle As Long) As Long
 
Public Declare Function InternetConnect Lib "Wininet.dll" _
   Alias "InternetConnectA" _
  (ByVal hInternet As Long, _
   ByVal lpszServerName As String, _
   ByVal nServerPort As Long, _
   ByVal lpszUserName As String, _
   ByVal lpszPassword As String, _
   ByVal dwService As Long, _
   ByVal dwFlags As Long, _
   ByVal dwContext As Long) As Long
 
Public Declare Function FtpGetFile Lib "Wininet.dll" _
   Alias "FtpGetFileA" _
  (ByVal hConnect As Long, _
   ByVal lpszRemoteFile As String, _
   ByVal lpszNewFile As String, _
   ByVal fFailIfExists As Long, _
   ByVal dwFlagsAndAttributes As Long, _
   ByVal dwFlags As Long, _
   ByVal dwContext As Long) As Long
 
Private hInternet As Long
Private hConnect  As Long
Public Function LoadFromInternetWithFTP(ftpServerName As String, ftpUserName As String, ftpPassword As String _
, strSourceFile As String, strTargetFile As String, strErrorMsg As String) As Boolean
  
   Screen.MousePointer = vbHourglass
  
   hInternet = InternetOpen("Vb FTP Transfer", INTERNET_OPEN_TYPE_DIRECT, _
                             vbNullString, vbNullString, INTERNET_FLAG_NO_CACHE_WRITE)
   
      If hInternet Then
         ' Try first passive
         hConnect = InternetConnect(hInternet, ftpServerName, INTERNET_DEFAULT_FTP_PORT, ftpUserName, _
                                 ftpPassword, INTERNET_SERVICE_FTP, INTERNET_FLAG_EXISTING_CONNECT Or _
                                 INTERNET_FLAG_PASSIVE, &H0)
         If hConnect = 0 Then
            ' Then active connection
            hConnect = InternetConnect(hInternet, ftpServerName, INTERNET_DEFAULT_FTP_PORT, ftpUserName, _
                                 ftpPassword, INTERNET_SERVICE_FTP, INTERNET_FLAG_EXISTING_CONNECT Or _
                                 INTERNET_FLAG_RELOAD, &H0)
         End If
 
         If hConnect <> 0 Then
            If FtpGetFile(hConnect, strSourceFile, strTargetFile, False, &H20, &H0, 0&) Then
               LoadFromInternetWithFTP = True
            End If
         End If
      
      End If
   
   'Close FTP
   Call InternetCloseHandle(hConnect)
   Call InternetCloseHandle(hInternet)
   
   hInternet = 0
   hConnect = 0
  
  Screen.MousePointer = vbDefault
 
End Function

[anup_vb2]

Try this:

First select Internet Transfer Control from Project->Components
Drag the control onto your form. Place a command button on your form. Then simply enter this code. Please enter your username & password correctly as given by the network administrator. Execute the code and check if your file has been uploaded to the server. You can then make necessary changes as you like.

Private Sub Form_Load()
Inet1.AccessType = icUseDefault
Inet1.Protocol = icFTP
End Sub

Private Sub Command2_Click()

With Inet1
.URL = "ftp://yourwebsite.com"
.UserName = "username"
.Password = "password"
.Execute , "PUT D:\yourfile_on_disk.txt /yourfile_on_server.txt"

End With

[Hack]

As others have supplied you with good working code, I'll give you a little tutorial.

Using The INET Control

[Joacim Andersson]

Attached is another tutorial I wrote a few years back and that used to be published at VB2theMax.com. It explains the API functions showed by oh1mie above together with a bunch of others FTP functions.

[mecracked]

Well I would suggest to use the very good cFTP class (by Andersson ?). Look for cFTP or FileCourier in the forum. Makes adding FTP function very easy. All you need to do is :

OpenConnection
GetFile or PutFile
CloseConnection

So Easy ! No need to go through the nitty grity of Inet.

I have one problem though. How can I add a 'cancel' facility ? I want to let the user cancel a download and I think this class does not support cancel method. Any suggestion will be appreciated.

[Joacim Andersson]

Well I would suggest to use the very good cFTP class (by Andersson ?). Look for cFTP or FileCourier in the forum. Makes adding FTP function very easy. All you need to do is :

OpenConnection
GetFile or PutFile
CloseConnection

So Easy ! No need to go through the nitty grity of Inet.

I have one problem though. How can I add a 'cancel' facility ? I want to let the user cancel a download and I think this class does not support cancel method. Any suggestion will be appreciated.

Glad you like the class . If you've found the FileCourier which I did publish as a reply to a thread here some time ago, you'll notice that it has an improved version of this class which indeed allows you to cancel the operation.

[mecracked]

Thanks Joacim !

I'd been wishing that cancel operation for a long time. Seems I didn't look through the FileCourier code properly.

[Joacim Andersson]

Well if you run FileCourier you'll notice that it shows a progress bar on upload/download with an estimated time it will take to finish the operation. This dialog also has a Cancel button.

[Joacim Andersson]

BTW, Here is the thread in which I posted the source code for my File Courier program, if anyone is interested.