[RESOLVED] always on top

[croto]

Hi,

How can I for a form to always stay on top of the other windows ? I tried some code I found on the net such as this link from MSDN .

But I always have the problem that VBA don't recognize the .hwnd properties of the form... Where is my problem ?

Thanks!

[RobDog888]

Use the FindWindow API to get the UserForms handle.

Option Explicit
'Written By VB/Office Guru™
Private Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" (ByVal lpClassName As String, _
ByVal lpWindowName As String) As Long
 
Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
  
Private Const HWND_TOPMOST = -1
Private Const HWND_NOTOPMOST = -2
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOSIZE = &H1
 
Private Sub UserForm_Initialize()
    Dim lHwnd As Long
    lHwnd = FindWindow("ThunderDFrame", "UserForm1") 'Change to match your userforms caption
    Do While lHwnd = 0
        lHwnd = FindWindow("ThunderDFrame", "UserForm1") 'Change to match your userforms caption
        DoEvents
    Loop
    SetWindowPos lHwnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOMOVE Or SWP_NOSIZE
End Sub

[croto]

I've changed "userform1" with the name (is it right ? Or I need the caption ?) of my form, but what is "ThunderDFrame" ?

[RobDog888]

"ThunderDFrame" is the class name of the userform. That doesnt change.

UserForm1 is the forms Caption as described in my coment. Change that to whatever your forms caption says exactly.

[croto]

Great!
Thanks a lot