[RESOLVED] sorting arrays

[ajames]

I have an array called iarray(), whihc contains the members iarray(0) to array(4). is there a way of sorting out the higher (in terms of the array) array to the lower?

i.e. The arrays are randomly placed in the following order:
iarray(3)
iarray(2)
iarray(4)
iarray(1)
iarray(0)

I would like the code to sort it so it goes from iarray(4) to iarray(0),and then put the indexes (EDIT: indicies) into a new array called order()

[randem]

A better explaination is in order. Do you mean in number sequence? (4)(3)... or the contents of the array?

[ajames]

in reverse sequence (number of the array)

[randem]

For i = Ubound(isarray) to LBound(isarray) Step -1
   Order(j) = isarray(i)
   j = j + 1
Next

[ajames]

how can I ensure that the random values in iarray() have been sorted into descending order? I've tried putting a msgbox in the code (just before j=j+1) but a message just pops up saying "0".

[Static]

Here is code that sorts arrays: havent tried it with numbers but it should work..

Make a copy of the random array.. sort the copy..
then compare Sorted to original.. creating an array with the index order?
sounds like it might work... but, there is probably a better way lol
sort code:

'Author: CVMichael
'Thread: [url]http://www.vbforums.com/showthread.php?t=231925[/url]
 
Private Sub QuickSort(C() As String, ByVal First As Long, ByVal Last As Long)
    Dim Low As Long, High As Long
    Dim MidValue As String
    
    Low = First
    High = Last
    MidValue = C((First + Last) \ 2)
    
    Do
    While C(Low) < MidValue
    Low = Low + 1
    Wend
    
    While C(High) > MidValue
    High = High - 1
    Wend
    
    If Low <= High Then
        Swap C(Low), C(High)
        Low = Low + 1
        High = High - 1
    End If
Loop While Low <= High
 
If First < High Then QuickSort C, First, High
If Low < Last Then QuickSort C, Low, Last
End Sub
 
Private Sub Swap(ByRef A As String, ByRef B As String)
    Dim T As String
    
    T = A
    A = B
    B = T
End Sub

[ajames]

I didnt understand that. I couldnt figure out where any of the variables went, and I couldnt ensure that any of it worked. Thanks anyway. Could someone try to work on randem's code so it will msgbox the contents of the "order" array?

[CVMichael]

I didnt understand that. I couldnt figure out where any of the variables went, and I couldnt ensure that any of it worked.

The original thread for that code is here:
VB - Quick Sort algorithm (very fast sorting algorithm)
You will understand it better if you look at the thread.

You have to call the QuickSort like this:
QuickSort MyArray, LBound(MyArray), UBound(MyArray)

But the QuickSort function is made for strings, so to make it work for numbers, just replace the "As String" to "As Integer" everywhere in the code.

[Static]

CVMichael: Cool.. I had forgotten where I got that code its GREAT!
(Added Comment in my codebank snippet stating u are the author)

[ajames]

CVMichael: Does that code sort the contents of the array of the indexes of the arrays?

[CVMichael]

CVMichael: Does that code sort the contents of the array of the indexes of the arrays?

Well, it sorts the contents of the array.

But... you can't really sort the index of the array, not with a regular array anyways...
An index is always sequention (in order), if you re-order the index, you loose the whole purpose of an index...

But I think I understand what you need.
You probably want to do something like an array of pointers (equivalent in C/C++)
To do that in VB you need an extra array to store the position of the item in the other array, Is that what you want ?

I think I can modify the QuickSort function to do that, but first I want to know if what I previously said is right ?

[CVMichael]

Actually, re-reading your first post, I see that that's what you want...

I modified the code, is it right ?

Option Explicit
 
Private Type tQuickSort
    Index As Long
    Value As Integer
End Type
 
Private Sub Form_Load()
    Dim MyArray(10) As Integer, ArrOrder() As Long, K As Long
    
    MyArray(0) = 23
    MyArray(1) = 345
    MyArray(2) = 2312
    MyArray(3) = 2
    MyArray(4) = 25
    MyArray(5) = 66
    MyArray(6) = 77
    MyArray(7) = 99
    MyArray(8) = 55
    MyArray(9) = 345
    MyArray(10) = 232
    
    QuickSort MyArray, ArrOrder
    
    Debug.Print " Index", " Order", " Value"
    For K = LBound(MyArray) To UBound(MyArray)
        Debug.Print K, ArrOrder(K), MyArray(ArrOrder(K))
    Next K
End Sub
 
Private Sub QuickSort(iArray() As Integer, Order() As Long)
    Dim K As Long
    Dim tArray() As tQuickSort
    
    ReDim tArray(LBound(iArray) To UBound(iArray))
    
    For K = LBound(iArray) To UBound(iArray)
        tArray(K).Index = K
        tArray(K).Value = iArray(K)
    Next K
    
    QuickSortRecurse tArray, LBound(iArray), UBound(iArray)
    
    ReDim Order(LBound(iArray) To UBound(iArray))
    
    For K = LBound(tArray) To UBound(tArray)
        Order(K) = tArray(K).Index
    Next K
End Sub
 
Private Sub QuickSortRecurse(C() As tQuickSort, ByVal First As Long, ByVal Last As Long)
    '
    '  Made by Michael Ciurescu (CVMichael from vbforums.com)
    '  Original thread: [url]http://www.vbforums.com/showthread.php?t=231925[/url]
    '
    Dim Low As Long, High As Long
    Dim MidValue As tQuickSort
    
    Low = First
    High = Last
    MidValue = C((First + Last) \ 2)
    
    Do
        While C(Low).Value < MidValue.Value
            Low = Low + 1
        Wend
        
        While C(High).Value > MidValue.Value
            High = High - 1
        Wend
        
        If Low <= High Then
            If Low <> High Then Swap C(Low), C(High)
            Low = Low + 1
            High = High - 1
        End If
    Loop While Low <= High
    
    If First < High Then QuickSortRecurse C, First, High
    If Low < Last Then QuickSortRecurse C, Low, Last
End Sub
 
Private Sub Swap(ByRef A As tQuickSort, ByRef B As tQuickSort)
    Dim T As tQuickSort
    
    T = A
    A = B
    B = T
End Sub

[randem]

Isn't this a bit over-complicated???? What was wrong with post #4????

[CVMichael]

I don't understand how that works.... where is the sorting part ?

Can you give an example with that code ?

[dglienna]

The value of the array doesn't matter. #4 just sorts the order of the array.

[randem]

in reverse sequence (number of the array)

Well, it was not ask for it to be sorted by contents just by the index numbers in reverse...

[CVMichael]

I'm still confuzed...

Maybe if I see working code (example), I'll understand.

[randem]

It is a working example. Re-read the first post carefully...

[CVMichael]

I would like the code to sort it so it goes from iarray(4) to iarray(0),and then put the indexes (EDIT: indicies) into a new array called order()

I don't know... I re-read it and re-read it... and I still get to the same conclusion...

He wants to sort the array, and put a indexes in a new array.

If it's the way you did it, then It does not make sence to put the index in a new array, why can't you just read the array in reverse order like this:

For I = UBound(iarray) to LBound(iarray) Step -1
     Debug.Print iarray(I)
Next I

I'll wait for ajames respose to have a more clear explanation (hopefully)

Edit
I just realized that I did not make my code sort in reverse order, but that can be easily fixed if you just read the sorted array in reverse order like in the code above.

[randem]

well, Sorting from iarray(4) to iarray(0) should be self explanitory. It's just a reorder in reverse (as defined).

[mebhas]

then why dont u try my example of sorting? http://www.vbforums.com/showthread.php?t=373225

[randem]

Why should I???

[mebhas]

sorry, my post was directed towards ajames.

[ajames]

ok, i seem to have made a difference to my code. Which was the one to sort out the contents of the arrays again?

EDIT: This is how far I have got:

the array 'order(4)' recieves a random number from 0 to 4 each time a button is pressed

it then makes 'iarray(4)' show the image corresponding to its random number (0 = 10, 2 is queen, 4 = ace etc.)

I want to be able to press a button, and get the array 'order' to replace the values so the highest number is in 'order(4)' and the lowest in 'order(0)'.
eg:

Contents of array 'order()':
order(0)=3
order(1)=1
order(2)=4
order(3)=0
order(4)=2

I would then like the code to reorganize it so:

order(0)=4
order(1)=3
order(2)=2
order(3)=1
order(4)=0

eg2) contents of order()
order(0)=4
order(1)=4
order(2)=4
order(3)=1
order(4)=4

sorted out:

order(0)=4
order(1)=4
order(2)=4
order(3)=4
order(4)=1

This should hopefully make sense

[randem]

Now, that is TOTALLY different that what you originally asked.

So, just sort the contents of the array then step through the sorted array and move each element to a new array.

Is the contents of the array a string, number etc???

[randem]

If they are all strings, you can just place all your info into a listbox (with the sorted property set to True), then Step through the ListBox and place the data elements back into the array.

[ajames]

Now, that is TOTALLYSo, just sort the contents of the array then step through the sorted array and move each element to a new array.

Is the contents of the array a string, number etc???

the top bit is what i'm having trouble doing. How do I sort them?

The contents of the array are numbers

(i do realise that this is completly different to what i originally asked, but i figured out a new way of doing it)

[randem]

Either use the code that was supplied by other members to sort the elements or place the elements into a listbox and have them sorted automatically (you would need to convert the numbers to strings first for the listbox).

[CVMichael]

Here:

Option Explicit
 
Private Sub Form_Load()
    Dim Order(0 To 4) As Integer, K As Long
    
    Order(0) = 3
    Order(1) = 1
    Order(2) = 4
    Order(3) = 0
    Order(4) = 2
    
    QuickSort Order, LBound(Order), UBound(Order) ' Sort ascending
    ReverseArray Order ' reorder, so it will be descending
    
    ' print result
    For K = LBound(Order) To UBound(Order)
        Debug.Print "Order(" & K & ") = " & Order(K)
    Next K
End Sub
 
Private Sub ReverseArray(A() As Integer)
    Dim K As Long, Elements As Long
    Dim LB As Long, UB As Long
    
    LB = LBound(A)
    UB = UBound(A)
    
    Elements = UB - LB
    For K = 0 To Elements \ 2
        Swap A(LB + K), A(UB - K)
    Next K
End Sub
 
Private Sub QuickSort(C() As Integer, ByVal First As Long, ByVal Last As Long)
    '
    '  Made by Michael Ciurescu (CVMichael from vbforums.com)
    '  Original thread: [url]http://www.vbforums.com/showthread.php?t=231925[/url]
    '
    Dim Low As Long, High As Long
    Dim MidValue As Integer
    
    Low = First
    High = Last
    MidValue = C((First + Last) \ 2)
    
    Do
        While C(Low) < MidValue
            Low = Low + 1
        Wend
        
        While C(High) > MidValue
            High = High - 1
        Wend
        
        If Low <= High Then
            Swap C(Low), C(High)
            Low = Low + 1
            High = High - 1
        End If
    Loop While Low <= High
    
    If First < High Then QuickSort C, First, High
    If Low < Last Then QuickSort C, Low, Last
End Sub
 
Private Sub Swap(ByRef A As Integer, ByRef B As Integer)
    Dim T As Integer
    
    T = A
    A = B
    B = T
End Sub

[ajames]

How do I get the values of the array into the listbox? And I presume I'm correct by modifying the code to "dim order(4) as string"? (randem)

[randem]

use List1.AddItem sStr (You have to place a listbox on your form first). And you convert the number to a string, you do not have to define it as a string.

ex.

List1.AddItem Format(Order(n),"00000")

[ajames]

Good, thats working, but how would I remove the items in the listbox before the next additem? I have tried "list1.clear" but that doesnt work: it only shows one value after that, even if there's more than one value being added

[randem]

What???,

Don't you want to add all the items to the listbox in order to get them sorted????

Post some code...

[CVMichael]

Why don't you use my code ? you don't have to convert to String !

[ajames]

'after pressing a button (with extra code above)
For i = 0 To 4
List1.Clear
List1.AddItem Format(order(i), "")
Next

Thats the code i'm using.
The thing is, is this code getting all 5 parts of the array 'order()'?
Order() , as I have stated, has a random number in each part of it, so there are 5 random numbers in it.

If I put a msgbox below saying 'list1.listcount' it only has recorded 1 variable

[dglienna]

Because you are clearing it 4 times. try this:

'after pressing a button (with extra code above)
List1.Clear
For i = 0 To 4
  List1.AddItem Format(order(i), "")
Next

[ajames]

i have a slight problem with that. I have 5 'hold' checkboxes, so I would need a way to only clear the things that have not been held, and not do anything about the others

Is there a '.clear' option which you can specify which entry you want to delete?

[randem]

ajames,

Your format statement will give you inacurate sorts if your numbers are longer than 1 character.

Things that have not been held???? If you do not put the items in the listbox would that be better?