Listboxes

[lavarock09]

I have 11 list boxes,

I need it so that if I select the top item on the first list box it selects the first option on the other 10, and it does the same so that if I pick the 356th item on the list box, it pick the 356th item on all the other list boxes

[umilmi81]

It becomes much simpler if you are using an array of listbox controls.

Here is the meat of the select

Private Sub List1_Click(Index As Integer)
    Dim NewIdx As Integer
    Dim i As Integer
    NewIdx = List1(Index).ListIndex
    For i = 0 To List1.Count - 1
        List1(i).Selected(NewIdx) = True
    Next i
End Sub

Here is the form

[brucevde]

Assuming you have a control array and assuming the number of items in each listbox are the same.

Private Sub List1_Click(Index As Integer)
    Dim lngIdx As Long
    If Index = 0 Then
       For lngIdx = List1.LBound + 1 To List1.UBound
           List1(lngIdx).ListIndex = List1(0).ListIndex
       Next
    End If
End Sub

[Bruce Fox]

The Control Array as mentioned above is the way to go. However if you
haven't used on, then this may be a place to start:

Private Sub List1_Click()
    Call Update_All_ListBoxs(List1, List1.ListIndex)
End Sub
 
Private Sub List2_Click()
    Call Update_All_ListBoxs(List2, List2.ListIndex)
End Sub
 
Private Sub List3_Click()
    Call Update_All_ListBoxs(List3, List3.ListIndex)
End Sub
 
Private Sub Update_All_ListBoxs(ByRef lstBox As ListBox, ByVal intIdx As Integer)
Dim ctl As Control
 
    For Each ctl In Me.Controls
        If TypeOf ctl Is ListBox And ctl <> lstBox Then ctl.ListIndex = intIdx
    Next
End Sub

Edit: The draw back with this method, is the Sub gets fired each time a ListBox is updated (simulated Click) by the actual Sub.

[Surveillance]

The index method seems the way to go, the only addendum I have to it is make sure that you put it on a keypress event also (actually, if memory serves you only need it on a keypress event, but I'm often wrong) That way if your user gets ants in their pants and decides to scroll the box with up/down arrows, it will scroll all of them. The only problem I've encountered with this is that if someone decides to grab the scroll bar and move one box, the other boxes don't move. I like to see my highlighted line run straight, and while it will still highlight all the correct items, sometimes the line won't be straight if the scroll bars have been repositioned.

Don't listen to me.

P.S. The one by Bruce only allows the first list box to control the others, remove the If index = 0 / end if if you want all the boxes to control one another.