[RESOLVED] DataGrid - Checkbox Selection Problem

[fdunford]

I have the following datagrid but the checkboxes are not behaving normally. I expect each checkbox to accept 1 click to change state and another click to change it back but this is not happening.

When I check on one of the boxes, it will select the entire row, and if I check it again, it will then change the state. Then the next click will select the row again, and the following click will change the state back.

How can I stop the grid from selecting the entire row, and just change the state of the checkbox for each click?

Public dtSession As New DataTable("SessionTable")
    Public dsSession As DataSet = New DataSet("SessionData")
    Public sSessionId As String = "Session ID"
    Public sSessionDesc As String = "Session Descripton"
    Public sSessionCB1 As String = "CB1"
    Public sSessionCB2 As String = "CB2"
    Public sSessionCB3 As String = "CB3"
    Public sSessionCB4 As String = "CB4"
 
 
    Public Sub sessionDataGrid_Load()
 
        Dim myRow As DataRow
        Dim x As Integer
        Dim dgts As New DataGridTableStyle
        Dim dgcs1 As New DataGridTextBoxColumn
        Dim dgcs2 As New DataGridTextBoxColumn
        Dim dgcs3 As New DataGridBoolColumn
        Dim dgcs4 As New DataGridBoolColumn
        Dim dgcs5 As New DataGridBoolColumn
        Dim dgcs6 As New DataGridBoolColumn
        Dim cb1, cb2, cb3, cb4 As DataColumn
 
               Try
            sessionDataGrid.CaptionText = "Sessions Currently in Data Base"
            dtSession.Clear()
            dtSession.Columns.Add(New DataColumn(sSessionId, GetType(String)))
            dtSession.Columns.Add(New DataColumn(sSessionDesc, GetType(String)))
 
            cb1 = New DataColumn(sSessionCB1, GetType(Boolean))
            cb1.ReadOnly = False
            cb1.DefaultValue = False
            dtSession.Columns.Add(cb1)
 
            cb2 = New DataColumn(sSessionCB2, GetType(Boolean))
            cb2.ReadOnly = False
            cb2.DefaultValue = False
            dtSession.Columns.Add(cb2)
 
            cb3 = New DataColumn(sSessionCB3, GetType(Boolean))
            cb3.ReadOnly = False
            cb3.DefaultValue = False
            dtSession.Columns.Add(cb3)
 
            cb4 = New DataColumn(sSessionCB4, GetType(Boolean))
            cb4.ReadOnly = False
            cb4.DefaultValue = False
            dtSession.Columns.Add(cb4)
 
            dgcs1.MappingName = sSessionId
            dgcs1.ReadOnly = True
            dgcs1.HeaderText = sSessionId
            dgts.GridColumnStyles.Add(dgcs1)
 
            dgcs2.MappingName = sSessionDesc
            dgcs2.ReadOnly = True
            dgcs2.Width = sessionDataGrid.Size.Width / 3
            dgcs2.HeaderText = sSessionDesc
            dgts.GridColumnStyles.Add(dgcs2)
 
            dgcs3.MappingName = sSessionCB1
            dgcs3.ReadOnly = False
            dgcs3.AllowNull = False 'Makes the checkbox 2 state
            dgcs3.HeaderText = sSessionCB2
            dgts.GridColumnStyles.Add(dgcs3)
 
            dgcs4.MappingName = sSessionCB2
            dgcs4.ReadOnly = False
            dgcs4.AllowNull = False 'Makes the checkbox 2 state
            dgcs4.HeaderText = sSessionCB2
            dgts.GridColumnStyles.Add(dgcs4)
 
            dgcs5.MappingName = sSessionCB3
            dgcs5.ReadOnly = False
            dgcs5.AllowNull = False 'Makes the checkbox 2 state
            dgcs5.HeaderText = sSessionCB3
            dgts.GridColumnStyles.Add(dgcs5)
 
            dgcs6.MappingName = sSessionCB4
            dgcs6.ReadOnly = False
            dgcs6.AllowNull = False 'Makes the checkbox 2 state
            dgcs6.HeaderText = sSessionCB4
            dgts.GridColumnStyles.Add(dgcs6)
 
            dgts.MappingName = "SessionTable"
            sessionDataGrid.TableStyles.Add(dgts)
 
            For x = 0 To gSessions.Length - 2
                myRow = dtSession.NewRow()
                myRow(sSessionId) = Hex(gSessions(x).Id)
                myRow(sSessionDesc) = gSessions(x).Desc
                myRow(sSessionCB1) = True 'TODO:Get actual value later
                myRow(sSessionCB2) = True 'TODO:Get actual value later
                myRow(sSessionCB3) = True 'TODO:Get actual value later
                myRow(sSessionCB4) = False 'TODO:Get actual value later
                dtSession.Rows.Add(myRow)
            Next
 
            dsSession.Tables.Add(dtSession)
            sessionDataGrid.DataSource = dtSession
 
        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
 
    End Sub

[JanZuk]

Try this.

Private Sub DataGrid1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles DataGrid1.Click
        Dim myColumn As Integer = 0
        Dim pt As Point = DataGrid1.PointToClient(Control.MousePosition)
        Dim hti As DataGrid.HitTestInfo = DataGrid1.HitTest(pt)
        Dim bmb As BindingManagerBase = BindingContext(DataGrid1.DataSource,DataGrid1.DataMember)
 
        If hti.Row < bmb.Count AndAlso hti.Type = DataGrid.HitTestType.Cell AndAlso hti.Column = myColumn Then
            DataGrid1(hti.Row, myColumn) = Not CBool(DataGrid1(hti.Row, myColumn))
                    
       End If
End Sub

This is something I use with the checkbox in the first column.

[fdunford]

Thanks jz. With the column tweak below it worked.

Public Sub sessionDataGrid_SingleClick(ByVal sender As Object, ByVal e As System.EventArgs) Handles sessionDataGrid.Click
        Dim dgs As DataGridCell = sessionDataGrid.CurrentCell
        Dim row As Integer = dgs.RowNumber
        Dim col As Integer = dgs.ColumnNumber
        Dim pt As Point = sessionDataGrid.PointToClient(Control.MousePosition)
        Dim hti As DataGrid.HitTestInfo = sessionDataGrid.HitTest(pt)
        Dim bmb As BindingManagerBase = BindingContext(sessionDataGrid.DataSource, sessionDataGrid.DataMember)
        Static Dim last As Integer = 0
 
        'clear last row selected
        sessionDataGrid.UnSelect(last)
        sessionDataGrid.Select(row)
        last = row
 
        'control checkbox
        If hti.Row < bmb.Count AndAlso hti.Type = DataGrid.HitTestType.Cell AndAlso hti.Column = col Then
            sessionDataGrid(hti.Row, col) = Not CBool(sessionDataGrid(hti.Row, col))
        End If
    End Sub

[JanZuk]

Cool.

Just be careful that the col that is being clicked and updated is a checkboxcolumn and not something else where you're trying to flip the bool.