Closing/opening cdrom drive

[uniquegodwin]

Hello...
This is an API on closing and opening cdrom drive.
I tried searching for this online and found many for vb6.But,there was none for vb.net.but,finally,I figured it out.I got little bit of help from my friend Oliver too...

'This is an API called mcisendstring,a readymade function from the winmm.dll available in windows.
 Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" _
(ByVal lpszCommand As String, ByVal lpszReturnString As String, _
ByVal cchReturnLength As Long, ByVal hwndCallback As Long) As Long
 
    Private Sub opencd()
        mciSendString("set CDAudio door open", 0, 0, 0) 'here,were sending the command for opening.Its case sensitive and should be EXACT..and same way for closing too. :)
    End Sub
 
    Private Sub closecd()
        mciSendString("set CDAudio door closed", 0, 0, 0)
    End Sub

Hope this helps someone

Edit...Thanks to jo0ls for the cdrom lock function too ...Here it is...

[shush]

Hi ,
It' s good & I was search so long for some thing like , so thanks

[uniquegodwin]

Hi Shush..
Im so happy that this helped you

[Andy]

Is it possible to disable the door to the drive? On my laptop, if it's barely touched, the door opens.

[MrPolite]

I dont know how but I know it is possible
you can "lock" the drive. thats what happens when you're burning a CD also....
I'm not sure if you can use windows apis to do this, you might need a third party dll?

[uniquegodwin]

Hello Mr.Polite and Andy...
Here...You have it for locking cdrom drive
http://www.vbforums.com/showthread.p...ighlight=cdrom

[MrPolite]

nice find

[jo0ls]

Here is how to Load/Unload/Lock/Unlock a drive by its handle (which you can get from the drive letter). It uses deviceIOControl to send commands to the drive, much like the examples in the other thread. I found the command info in the vb6 "Flamed Lib" on pscode.com.

[uniquegodwin]

Thank You for posting it here jo0ls..
ll put it on the 1st post :-)

[jo0ls]

In the first post in the thread,

Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" _
(ByVal lpszCommand As String, ByVal lpszReturnString As String, _
ByVal cchReturnLength As Long, ByVal hwndCallback As Long) As Long

is wrong, it's using vb6 types, and the sample doesn't allow you to specify the drive:

Imports System.Runtime.InteropServices
Imports System.Text
 
Public Class CDTray
 
    Private Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" _
    (<MarshalAs(UnmanagedType.LPStr)> ByVal command As String, _
    ByVal returnString As StringBuilder, _
    ByVal cchReturnLength As Int32, _
    ByVal hwndCallback As IntPtr) As Int32
 
    ''' <summary>
    ''' Open the specified cdrom drives tray
    ''' </summary>
    ''' <param name="drive">In the form "X:\"</param>
    ''' <remarks></remarks>
    Public Shared Sub OpenCDTray(ByVal drive As String)
        Dim command As String
        ' Here we open a particular drive, and create an alias to it - cddrive:
        command = String.Format("open {0} type cdaudio alias cddrive", drive)
        Dim result As Int32 = mciSendString(command, Nothing, 0, Nothing)
        If result > 0 Then
            Throw New ApplicationException("When opening device, MCISendString returned: " & result)
        End If
        command = "set cddrive door open"
        result = mciSendString(command, Nothing, 0, Nothing)
        If result > 0 Then
            Throw New ApplicationException("When ejecting device tray, MCISendString returned: " & result)
        End If
        command = "close cddrive"
        result = mciSendString(command, Nothing, 0, Nothing)
        If result > 0 Then
            Throw New ApplicationException("When closing device, MCISendString returned: " & result)
        End If
 
    End Sub
 
    ' Close the tray. 
    ' Doesn't work for my drive, but deviceIOControl does.
    Public Shared Sub CloseCDTray(ByVal drive As String)
        Dim command As String
        command = String.Format("open {0} type cdaudio alias cddrive", drive)
        Dim result As Int32 = mciSendString(command, Nothing, 0, Nothing)
        If result > 0 Then
            Throw New ApplicationException("When opening device, MCISendString returned: " & result)
        End If
        command = "set cddrive door closed"
        result = mciSendString(command, Nothing, 0, Nothing)
        If result > 0 Then
            Throw New ApplicationException("When closing device tray, MCISendString returned: " & result)
        End If
        command = "close cddrive"
        result = mciSendString(command, Nothing, 0, Nothing)
        If result > 0 Then
            Throw New ApplicationException("When closing device, MCISendString returned: " & result)
        End If
    End Sub
 
End Class

[uniquegodwin]

Very nice! Thank you

[paraidy]

This is a Great Post, Thx