[RESOLVED] How do I get an image from a DC into a stdPicture object?

[moeur]

I have a memory DC that has an image in it and I'm trying to put that image into a stdPicture object. Here is an example that illustrates.

Dim mypic As StdPicture
Picture1.AutoRedraw = True
Picture2.AutoRedraw = True
 
'load the picture into the stdPicture object
Set mypic = LoadPicture("whatever.gif")
'display the image in a picturebox.  So far so good
Picture1.PaintPicture mypic, 0, 0
 
'create a memory device context
Dim DC As Long
DC = CreateCompatibleDC(Picture1.hDc)
'put the bitmap image from our stdPicture object into the DC
Call SelectObject(DC, mypic.Handle)
 
'Now it is ruined, picture2 won't display it properly
'no matter what I've tried
Set Picture2.Picture = mypic
Picture2.Refresh
 
'tried this too
'Picture2.PaintPicture mypic, 0, 0

Anyone have any ideas?

[moeur]

I may have found an API function that will help
OleCreatePictureIndirect
http://msdn.microsoft.com/library/de...b1b8d760c4.asp

I'll check it out

[moeur]

Well, I think I have an answer.
It's a bit more complex than I would like, but since I don't understand these things too much I haven't been able to simplify it.
This code is from AllAPI .NET

Function CreateBitmapPicture(ByVal hBmp As Long, ByVal hPal As Long) As Picture
    Dim R As Long, Pic As PicBmp, IPic As IPicture, IID_IDispatch As GUID
 
    'Fill GUID info
    With IID_IDispatch
        .Data1 = &H20400
        .Data4(0) = &HC0
        .Data4(7) = &H46
    End With
 
    'Fill picture info
    With Pic
        .Size = Len(Pic) ' Length of structure
        .Type = vbPicTypeBitmap ' Type of Picture (bitmap)
        .hBmp = hBmp ' Handle to bitmap
        .hPal = hPal ' Handle to palette (may be null)
    End With
 
    'Create the picture
    R = OleCreatePictureIndirect(Pic, IID_IDispatch, 1, IPic)
 
    'Return the new picture
    Set CreateBitmapPicture = IPic
End Function
 
Function hDCToPicture(ByVal hDCSrc As Long, ByVal LeftSrc As Long, ByVal TopSrc As Long, ByVal WidthSrc As Long, ByVal HeightSrc As Long) As Picture
    Dim hDCMemory As Long, hBmp As Long, hBmpPrev As Long, R As Long
    Dim hPal As Long, hPalPrev As Long, RasterCapsScrn As Long, HasPaletteScrn As Long
    Dim PaletteSizeScrn As Long, LogPal As LOGPALETTE
 
    'Create a compatible device context
    hDCMemory = CreateCompatibleDC(hDCSrc)
    'Create a compatible bitmap
    hBmp = CreateCompatibleBitmap(hDCSrc, WidthSrc, HeightSrc)
    'Select the compatible bitmap into our compatible device context
    hBmpPrev = SelectObject(hDCMemory, hBmp)
 
    'Raster capabilities?
    RasterCapsScrn = GetDeviceCaps(hDCSrc, RASTERCAPS) ' Raster
    'Does our picture use a palette?
    HasPaletteScrn = RasterCapsScrn And RC_PALETTE ' Palette
    'What's the size of that palette?
    PaletteSizeScrn = GetDeviceCaps(hDCSrc, SIZEPALETTE) ' Size of
 
    If HasPaletteScrn And (PaletteSizeScrn = 256) Then
        'Set the palette version
        LogPal.palVersion = &H300
        'Number of palette entries
        LogPal.palNumEntries = 256
        'Retrieve the system palette entries
        R = GetSystemPaletteEntries(hDCSrc, 0, 256, LogPal.palPalEntry(0))
        'Create the palette
        hPal = CreatePalette(LogPal)
        'Select the palette
        hPalPrev = SelectPalette(hDCMemory, hPal, 0)
        'Realize the palette
        R = RealizePalette(hDCMemory)
    End If
 
    'Copy the source image to our compatible device context
    R = BitBlt(hDCMemory, 0, 0, WidthSrc, HeightSrc, hDCSrc, LeftSrc, TopSrc, vbSrcCopy)
 
    'Restore the old bitmap
    hBmp = SelectObject(hDCMemory, hBmpPrev)
 
    If HasPaletteScrn And (PaletteSizeScrn = 256) Then
        'Select the palette
        hPal = SelectPalette(hDCMemory, hPalPrev, 0)
    End If
 
    'Delete our memory DC
    R = DeleteDC(hDCMemory)
 
    Set hDCToPicture = CreateBitmapPicture(hBmp, hPal)
End Function