How to pass all files and sub directories?

[vbcodec]

Hi guys
I'm trying to use VBAccelerator zip to compress all content of directory and all files inside,

how to use dir command to get all files in child directories?

thanks

[dglienna]

Post your code. I think I read that you can look at the files before you zip them. What do you need it for? Are you zipping up a folder?

[vbcodec]

exactly, i'm zipping a folder and I dont have any code yet since I dont have all files

[Hack]

I use this to load all of the files in a certain directory into a listbox. You may be able to modify it to get the files, and do your zip thing. Hope this helps.

Private Sub Command1_Click()
Dim LoadFiles As String
List1.Clear
LoadFiles = Dir("c:\program files\qcap\*.*")
Do While LoadFiles > ""
   List1.AddItem LoadFiles
   LoadFiles = Dir
Loop
End Sub

[anotherVBnewbie]

If you want to recursively search directories I think you'll need to use some APIs instead of Dir. Here's some code which does that.

'Create a form with a command button (command1), a list box (list1)
'and four text boxes (text1, text2, text3 and text4).
'Type in the first textbox a startingpath like c:\
'and in the second textbox you put a pattern like *.* or *.txt
 
Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function GetFileAttributes Lib "kernel32" Alias "GetFileAttributesA" (ByVal lpFileName As String) As Long
Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long
 
Const MAX_PATH = 260
Const MAXDWORD = &HFFFF
Const INVALID_HANDLE_VALUE = -1
Const FILE_ATTRIBUTE_ARCHIVE = &H20
Const FILE_ATTRIBUTE_DIRECTORY = &H10
Const FILE_ATTRIBUTE_HIDDEN = &H2
Const FILE_ATTRIBUTE_NORMAL = &H80
Const FILE_ATTRIBUTE_READONLY = &H1
Const FILE_ATTRIBUTE_SYSTEM = &H4
Const FILE_ATTRIBUTE_TEMPORARY = &H100
 
Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type
 
Private Type WIN32_FIND_DATA
    dwFileAttributes As Long
    ftCreationTime As FILETIME
    ftLastAccessTime As FILETIME
    ftLastWriteTime As FILETIME
    nFileSizeHigh As Long
    nFileSizeLow As Long
    dwReserved0 As Long
    dwReserved1 As Long
    cFileName As String * MAX_PATH
    cAlternate As String * 14
End Type
Function StripNulls(OriginalStr As String) As String
    If (InStr(OriginalStr, Chr(0)) > 0) Then
        OriginalStr = Left(OriginalStr, InStr(OriginalStr, Chr(0)) - 1)
    End If
    StripNulls = OriginalStr
End Function
 
Function FindFilesAPI(path As String, SearchStr As String, FileCount As Integer, DirCount As Integer)
    'KPD-Team 1999
    'E-Mail: [email][email protected][/email]
    'URL: [url]http://www.allapi.net/[/url]
 
    Dim FileName As String ' Walking filename variable...
    Dim DirName As String ' SubDirectory Name
    Dim dirNames() As String ' Buffer for directory name entries
    Dim nDir As Integer ' Number of directories in this path
    Dim i As Integer ' For-loop counter...
    Dim hSearch As Long ' Search Handle
    Dim WFD As WIN32_FIND_DATA
    Dim Cont As Integer
    If Right(path, 1) <> "\" Then path = path & "\"
    ' Search for subdirectories.
    nDir = 0
    ReDim dirNames(nDir)
    Cont = True
    hSearch = FindFirstFile(path & "*", WFD)
    If hSearch <> INVALID_HANDLE_VALUE Then
        Do While Cont
        DirName = StripNulls(WFD.cFileName)
        ' Ignore the current and encompassing directories.
        If (DirName <> ".") And (DirName <> "..") Then
            ' Check for directory with bitwise comparison.
            If GetFileAttributes(path & DirName) And FILE_ATTRIBUTE_DIRECTORY Then
                dirNames(nDir) = DirName
                DirCount = DirCount + 1
                nDir = nDir + 1
                ReDim Preserve dirNames(nDir)
            End If
        End If
        Cont = FindNextFile(hSearch, WFD) 'Get next subdirectory.
        Loop
        Cont = FindClose(hSearch)
    End If
    ' Walk through this directory and sum file sizes.
    hSearch = FindFirstFile(path & SearchStr, WFD)
    Cont = True
    If hSearch <> INVALID_HANDLE_VALUE Then
        While Cont
            FileName = StripNulls(WFD.cFileName)
            If (FileName <> ".") And (FileName <> "..") Then
                FindFilesAPI = FindFilesAPI + (WFD.nFileSizeHigh * MAXDWORD) + WFD.nFileSizeLow
                FileCount = FileCount + 1
                List1.AddItem path & FileName
            End If
            Cont = FindNextFile(hSearch, WFD) ' Get next file
        Wend
        Cont = FindClose(hSearch)
    End If
    ' If there are sub-directories...
    If nDir > 0 Then
        ' Recursively walk into them...
        For i = 0 To nDir - 1
            FindFilesAPI = FindFilesAPI + FindFilesAPI(path & dirNames(i) & "\", SearchStr, FileCount, DirCount)
        Next i
    End If
End Function
Sub Command1_Click()
    Dim SearchPath As String, FindStr As String
    Dim FileSize As Long
    Dim NumFiles As Integer, NumDirs As Integer
    Screen.MousePointer = vbHourglass
    List1.Clear
    SearchPath = Text1.Text
    FindStr = Text2.Text
    FileSize = FindFilesAPI(SearchPath, FindStr, NumFiles, NumDirs)
    Text3.Text = NumFiles & " Files found in " & NumDirs + 1 & " Directories"
    Text4.Text = "Size of files found under " & SearchPath & " = " & Format(FileSize, "#,###,###,##0") & " Bytes"
    Screen.MousePointer = vbDefault
End Sub

[Sir Loin]

You can ALSO use the FileSystemObject.

Private Sub Command1_Click()
Dim FSO As New Scripting.FileSystemObject, FileDir As Folder, Files As File
 
Set FileDir = FSO.GetFolder("C:\WINDOWS")
 
For Each Files In FileDir.Files
    List1.AddItem Files.Name
Next Files
 
Set FileDir = Nothing
Set Files = Nothing
Set FSO = Nothing
 
End Sub

-Sir Loin

[vbcodec]

Sir Loin
I can't find the reference to FSO, whats the exact name?

anotherVBnewbie
this is exactly what I want but how to put it inside an array , I want to make my application run as a service and there may not be any controls


thanks

[dglienna]

Add a reference to Microsoft Scripting Runtime

[vbcodec]

well , your code only passes *.* files in windows folder and not its subdirectories... but anotherVBnewbie's code that does the job is actually passing it to a listbox

[anotherVBnewbie]

It shouldn't be that hard to convert the code I posted to do what you want it to do...but since it's an example it is using listboxes and text boxes to display what all goes on..just dump the command click (replace that with whatever you want to call the actual function with) and all references to listboxes, etc, and replace the "List1.AddItem path & FileName" with a couple of lines like

arrayName(Ubound(arrayName)) = path & FileName
ReDim Preserve arrayName(Ubound(arrayName) + 1)

[vbcodec]

I tried to do that, but since this function is calling itself inside, it gives me this error: "This Array is fixed or temporarily locked"

what can I do about that?

[anotherVBnewbie]

You can either declare the array in the declares portion of the form or make it a public array by declaring it in a module. Also, if this code is going to run more than once per program cycle, you should redim the array prior to each time the code is executed to prevent adding new data to the old data.