MS Word Error(Resolved)

[longwolf]

I'm taking an ascii data file and converting/moving the data into MS Word tables.
It opens MS Word with the completed documemt.
I've gotten that part working well.

But here's the problem:
It can not make more that one word doc unless you close/restart the program.

If I try to make two documents in a row I get the following msg:

Runtime Error '462'
The remote server machine does not exist or is unavailble.

I get this error at line:
Set myRange = ActiveDocument.Content

I've only tried doing a second document after MS Word has been saved and closed.

Full code:

Private Sub InsertToTemplate3(Columns() As String, ByRef Year As Integer)
'inserts the preformayed columns text into the template then saves it
    Dim sPath As String
    Dim MSWord As Word.Application
    Dim TemplateDOC As Document
    Dim myRange As Word.Range
    Dim lM As Long
    Dim lD As Long
    Dim sFind As String
    
    staBar.Panels(1).Text = "Initalizing MSWord"
    sPath = App.Path & "\Template\TableTemplate12g.dot"
    Set MSWord = New Word.Application
    With MSWord
'        .Visible = True
        'Load the template
        Set TemplateDOC = .Documents.Open(sPath)
        .Selection.WholeStory
        .Selection.Copy
        'create a ne document from the template
        .Documents.Add DocumentType:=wdNewBlankDocument
        .Selection.PasteAndFormat (wdPasteDefault)
        Set myRange = ActiveDocument.Content
        'notify the user
        staBar.Panels(1).Text = "Creating Word Document"
        Screen.MousePointer = vbDefault
        ProgressBarInitalize 365
        
        'Set the Name of Location
        sFind = "Name of Location"
        myRange.Find.Execute FindText:=sFind, _
                             MatchCase:=True, _
                             MatchWholeWord:=True, _
                             ReplaceWith:=m_sLocName, _
                             Replace:=wdReplaceAll
        'Set the Year
        sFind = "Year"
        myRange.Find.Execute FindText:=sFind, _
                             MatchCase:=True, _
                             MatchWholeWord:=True, _
                             ReplaceWith:=CStr(Year), _
                             Replace:=wdReplaceAll
        
        For lM = 1 To 12
            For lD = 1 To 31
                ProgressBarDecrement
                'add the Day Numeral
                sFind = "Dm" & CStr(lM) & "d" & CStr(lD)
                myRange.Find.Execute FindText:=sFind, _
                                     MatchCase:=True, _
                                     MatchWholeWord:=True, _
                                     ReplaceWith:=Columns(lM, 0, lD), _
                                     Replace:=wdReplaceAll
                'add the Day Name
                sFind = "Wm" & CStr(lM) & "d" & CStr(lD)
                myRange.Find.Execute FindText:=sFind, _
                                     MatchCase:=True, _
                                     MatchWholeWord:=True, _
                                     ReplaceWith:=Columns(lM, 1, lD), _
                                     Replace:=wdReplaceAll
                'add the Moon Phase
                sFind = "Sm" & CStr(lM) & "d" & CStr(lD)
                myRange.Find.Execute FindText:=sFind, _
                                     MatchCase:=True, _
                                     MatchWholeWord:=True, _
                                     ReplaceWith:=Columns(lM, 2, lD), _
                                     Replace:=wdReplaceAll
                
                'add the Time column
                sFind = "Tm" & CStr(lM) & "d" & CStr(lD)
                myRange.Find.Execute FindText:=sFind, _
                                     MatchCase:=True, _
                                     MatchWholeWord:=True, _
                                     ReplaceWith:=Columns(lM, 3, lD), _
                                     Replace:=wdReplaceAll
            Next
        Next
        .Visible = True
    End With
    'Clear the progress bar
    ProgressBarClear
    staBar.Panels(1).Text = "Processing Complete"
    staBar.Panels(2).Text = "Use MS Word to save the file."
    'kill the MS Word objects
    TemplateDOC.Close
    Set MSWord = Nothing
    Set TemplateDOC = Nothing
    Set myRange = Nothing
End Sub

[MartinLiss]

Do something like this when you open Word.

Public Sub OpenWord()
 
    Dim hWnd As Long
    Dim nRpt As Integer
    
    On Error GoTo ErrorRoutine
    
StartOver:
    hWnd = FindWindow("OpusApp", vbNullString)
    If hWnd = 0 Then
        Set wdApp = New Word.Application
    Else
        Set wdApp = Word.Application
    End If
 
    Exit Sub
 
ErrorRoutine:
    Select Case Err.Number
        Case -2147023174
            ' The user has manually shut down Word, so we need to
            ' clean up and then restart Word.
            For nRpt = 1 To wdApp.Documents.Count
                wdApp.Documents(nRpt).Close SaveChanges:=wdDoNotSaveChanges
            Next nRpt
            wdApp.Quit
            Set wdApp = Nothing
            Resume StartOver
        Case 462
            Resume Next
        Case Else
            DisplayError "OpenWord"
    End Select
 
End Sub

[longwolf]

Thanks Martin.

I adapted the code to work within my sub because I'm not using global MS Word objects

But I'd like to know what the full msg is that should go with..

Case Else
            DisplayError "OpenWord"
    End Select

I've hit it twice with two different error numbers.

[MartinLiss]

DisplayError is just a sub that I use to format err messages. You could replace that line with

MsgBox Err.Number & " - " Err.Description

[RobDog888]

You should fully qualify your word objects when dimensioning them.

Dim TemplateDOC As Document
 
'Should be
Dim TemplateDOC As Word.Document

Also, when you destroy your word objects you should do it in reverse order of their structure within word.

'kill the MS Word objects
    Set myRange = Nothing
    TemplateDOC.Close
    Set TemplateDOC = Nothing
    Set MSWord = Nothing

[longwolf]

Thanks guys,

I made the changes.

I still get an error when I try to do two files back to back.

But now it get's errors at:

myRange.Find.Execute ......

And gives error:
"Object variable or With block variable not set"

Checking myRange shows that myRange = nothing

[MartinLiss]

I know you say you aren't global MS Word objects, but certainly your myRange.Find.Execute statement must be prepended with a local Word object at least.

[longwolf]

I know you say you aren't global MS Word objects, but certainly your myRange.Find.Execute statement must be prepended with a local Word object at least.

Boy did I just get a good scare!

I took the:

	Set myRange = ActiveDocument.Content

bits from the help file.
The range object allows the use of vbCr while the find object doesn't

After reading Martins last post I changed the code to:

	Set myRange = .ActiveDocument.Content

So that the dot would plug it into the MSWord object.
Then tried doing two doc's in a row. (After closing the 1st one.)

The code seemed to be working and was about half done when I black screened.
The comp rebooted itself and told me I didn't have a MBR!

Turned out to be a lose cable

Now the app is working fine when the first document gets closed before making a new one.
I'll do a test without closing the 1st doc now.

Thanks Martin and Rob, Y'all are great!

[longwolf]

Wellllll, the new test was interesting. (making a 2nd doc while the 1st is still open)
It did make the 2nd document, but I got two odd pop-ups.

The first one said


After using the 'switch to' button I got this one:


It must be referring to the template, it's full of tags like:
Dm1d1
Wm7d3
Sm4d25
The replacement text is almost all numeric.

I also get a msg about 'a lot of data has been added to the clipboard.....' when the document is closed.


It'd be nice to get rid of those.

I wouldn't want the users to think something is wrong.

[MartinLiss]

Have you tried spellchecking and accepting all "misspellings" in the template before you attempt to use it?

[longwolf]

Have you tried spellchecking and accepting all "misspellings" in the template before you attempt to use it?

I just tried it.
It didn't report ANY spelling errors, wierd.

And the only spelling 'error' I see in the output document is the name of the location that gets plugged into the top of each page. (6 in all)

[longwolf]

Ok, I made some changes that seem to have gotten rid of the pop ups

Tell me if these are a mistakes.

lHwnd = FindWindow("OpusApp", vbNullString)
    If lHwnd = 0 Then
        Set MSWord = New Word.Application
    Else
        Set MSWord = Word.Application
'Added the next line so they can't click the wrong 
'instance of word and set it active
        MSWord.Application.Visible = False
    End If

And I added:

Clipboard.Clear

After all the pasing is finished.
Hopefully it will stop the 'clipboard' msg.

[RobDog888]

This is what I write to re-use an instance of Word if its running and if its not I create one.

Option Explicit
 
Private moApp As Word.Application
 
Private Sub Form_Load()
    
    On Error GoTo MyError
    
    Set moApp = GetObject(, "Word.Application")
    If moApp Is Nothing Then
        Set moApp = CreateObject("Word.Application")
    End If
    'Do some of your apps initialization stuff
    '...
    Exit Sub
    
MyError:
    If Err.Number = 429 Then
        Resume Next
    Else
        MsgBox Err.Number & " - " & Err.Description
    End If
End Sub

[longwolf]

What is the difference in using:
Set moApp = GetObject(, "Word.Application") ?

[longwolf]

DAAAAMN.
Just found a new problem.
If the user closes the application while it's making a Word File both the program and Word stay open but hidden.

Should I make a new thread for this?

I added flag (m_bProcessing).
I check the flag in the Form_QueryUnload event
If True I warn the user, give them a chance to change their minds and turn the flag false if they still want to stop.
The 'Insertion' sub checks to see if the flag has changed and calls the '=Nothing' lines at the end of the sub.

But that didn't help!

I guess I could remove their option to kill the app while it's working, but that doesn't seem very Profes

[longwolf]

Just tried a 'work around'

If they want to close the app it just hides itself until the job is done, then closes.
But the app may run for another 5 mins (it's adding about 1500 pieces of info to the file).
And the whole time WINWORD.EXE is pegging the CPU at about 98%.

Then, when it does close, it pops up a box asking if you want to save the changes.

Imagine an app asking to save changes 5 mins after you 'closed' it. AAAAAAAARRRRRRRRRGGGGGGG

[RobDog888]

You need to post some of your code that inserts the data to the document. Maybe we can optimize it somehow.

I guess GetObject and this "Set MSWord = Word.Application" may be the same thing.

[MartinLiss]

Do something like this when you want to save

wdApp.ActiveDocument.SaveAs FileName:="MyDoc.doc", FileFormat:= _
        wdFormatDocument, LockComments:=False, Password:="", AddToRecentFiles:= _
        True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts:= _
        False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
        SaveAsAOCELetter:=False
    wdApp.ActiveWindow.Close
    Application.Quit

[longwolf]

Thanks guys

I'm in the process of setting the Word Object to be global level.
That way I can move a bunch of this code to a module and just kill the obj when the user wants out.

I'll let you know how well it goes.
I'll probably be screaming again

[longwolf]

You need to post some of your code that inserts the data to the document. Maybe we can optimize it somehow.

I guess GetObject and this "Set MSWord = Word.Application" may be the same thing.

The app is formating tide tables for a give loc for a full year.
The reason it's taking so long is because I get an error if I try to insert any text over 256 chars long.

The basic insertion code hasn't changed sence my posting at 04:59 PM
I could have consolidated some of the insertions but those sections need different font sizes.
It was just easier to set the template Tags the correct font size(s) to begin with.
(It would also be nice if I could change the font for the MoonPhase Inserts and use the Moons from the WingDings 2 Font, but that a whole other problem)


BTW,
On that 'GetObject', I believe I saw a post here were that code caused someone a problem.
But I can't remember the details

[dglienna]

Maybe you could use my method of creating the tables in Word, and saving it as a RTF file. Replace the entries with tags (I use [1] [2]) which you can then load as a document in a rtb in your app. Then you could replace [1] with your first item, and loop through the other ones. If you saved the moon phase X in a tag, you could prolly isolate it in between tags [mp1 X ], and then parse it out.

I am assuming the phase would be different for each chart.

The only problem I was having when the chart size changed. You shouldn't have that issue.

Use the WYSIWYG example at the M$ site so that you get actual dimensions for a print preview of your RTB.

[longwolf]

Maybe you could use my method of creating the tables in Word, and saving it as a RTF file. Replace the entries with tags (I use [1] [2]) which you can then load as a document in a rtb in your app. Then you could replace [1] with your first item, and loop through the other ones. If you saved the moon phase X in a tag, you could prolly isolate it in between tags [mp1 X ], and then parse it out.

I am assuming the phase would be different for each chart.

The only problem I was having when the chart size changed. You shouldn't have that issue.

Use the WYSIWYG example at the M$ site so that you get actual dimensions for a print preview of your RTB.

Hi David,

My client was pretty specific about the layout and file type he wants.

But you've got me curious about you method, do you have an example somewhere?

The document is laided out something like a calander with 2 months sided-by-sided per page.
For the Moon phases, the app finds the 4 quarter moon dates for each month and adds an abbreviation to those days.
NM = New mon
FQ = First Quarter
FM = Full Mon
LQ = Last Quarter

I had hoped to replace those abbreviations with moon symbols.
But I'm having an issue with the font.
See this link: Strange Font Problem
http://www.vbforums.com/showthread.p...highlight=font

Even if I get that working, I'd have to figure out how to change the chars and fonts at the same time, I'm guessing it'd use the Selection part of the Word Obj

[dglienna]

Basically, I use .Find to search for a tag, then replace it with my output. This all fits in the cell of the table that I designed. For the headings on the top and bottom, I center and bold them, after I've written the rest of the info. I even copy in a different image into the third table (which has only one square cell that holds a picture).

I'm assuming that you could get the quarters to show up on the document. Then, you could just copy and paste them (I think) from one place to another. You might have to set the font, but you can use .SelFont for that, as you know.

I generate a receipt by replacing 45 fields, and formatting each one of them that includes about 25 prices, and a lot of detail that varies from page to page.

I can't post it, but I'll help you. Start with the WYSIWYG RTB from M$'s site.
It lets you work with a preview that is half the size of the printed page, like Word does.

It took a while to get everything working, and the biggest problem was trying to get an image next to text. I finally gave up and placed it on the bottom of the page (above the footer)

[longwolf]

Hooray!
I think the beast is tamed.
I wouldn't call it house broken, but at least it seems to have stopped snapping at me

David,
I had a problem with the 'CreateObject' method.
If the user closed the 1st doc and tried to make a new one, CreateObject reported the MSWord object as still existing.
I adopted Marty's method and it's working fine.

[longwolf]

One more task and I can (I hope) consider this job a complete success.

I want to replace the inserted Moon Phase 'tags' with the moon symbol fonts from Wingdings 2.
I can't seem to find a Chr$() value to create the First and Last Quarter Moon symbols.

To get those chars from the font I had to :
1. create an rtf file
2. use the Windows Character Map to copy them to the file
3 Load the new file into a RichTextBox.

I tried getting it directly from the richtextbox like this:

sFind = "NM"
    myRange.Find.Execute FindText:=sFind, _
                         MatchCase:=True, _
                         MatchWholeWord:=True, _
                         ReplaceWith:=rtbSmbls.SelRTF, _
                         Replace:=wdReplaceAll

But that pasted all the formating for the symbol, as if you opened an rtf file in Notepad.


So I created a sub to copy any one of the needed symbols to the windows clipboard.
Next I tried getting the symbol from the windows clipboard:

MoonPhaseToClipboard FullMoon
    g_MSWord.Selection.Find.Execute "FM", True, True, , , , True, wdFindContinue
    g_MSWord.Selection.PasteAndFormat wdFormatOriginalFormatting

But that pasted the entire original template into each of the tag positions, not good, lol

Any ideas on how to replace the tags and the fonts from the WINDOWS clipboard at the same time?

[dglienna]

Where X is your symbol, can't you do"

str = .Find "[  X ]"
fq = mid$(str,3,1)

if that doesn't work, just find it, and use str = .SelText to load it into the string.
You might have to change the font when you paste it.

If you post a small rtf, then I will try to mess around with it later tonight or tomorrow. Going out soon.

[longwolf]

Thanks David,
But this is pasting onto a MS Word Document.

It'd be easy If I was making an rtf file.

I'm only using an rtf file to get the moon font symbols.
I can get the correct symbol and copy it to the windows clipboard or find it in the Richtextbox.
The Richtextbox is only used to hold those symbols.

I can also find and select the correct 'tags' in the MS Word doc.

I just can't seem to replace them with the symbols.

[MartinLiss]

One more task and I can (I hope) consider this job a complete success.

I want to replace the inserted Moon Phase 'tags' with the moon symbol fonts from Wingdings 2.
I can't seem to find a Chr$() value to create the First and Last Quarter Moon symbols.

To get those chars from the font I had to :
1. create an rtf file
2. use the Windows Character Map to copy them to the file
3 Load the new file into a RichTextBox.

I tried getting it directly from the richtextbox like this:

sFind = "NM"
    myRange.Find.Execute FindText:=sFind, _
                         MatchCase:=True, _
                         MatchWholeWord:=True, _
                         ReplaceWith:=rtbSmbls.SelRTF, _
                         Replace:=wdReplaceAll

But that pasted all the formating for the symbol, as if you opened an rtf file in Notepad.


So I created a sub to copy any one of the needed symbols to the windows clipboard.
Next I tried getting the symbol from the windows clipboard:

MoonPhaseToClipboard FullMoon
    g_MSWord.Selection.Find.Execute "FM", True, True, , , , True, wdFindContinue
    g_MSWord.Selection.PasteAndFormat wdFormatOriginalFormatting

But that pasted the entire original template into each of the tag positions, not good, lol

Any ideas on how to replace the tags and the fonts from the WINDOWS clipboard at the same time?

I responded in your other thread and what I said was that I can't figure out how to do it using SendKeys but Alt plus 386 on the number pad will produce that character if the font is wingdings 2. The trick is to use the number pad and I've seen references that say you can use something like SendKeys "%{Pad3}{Pad8}{Pad6}" but that gives an error.

[longwolf]

Thanks Marty,

I hadn't thought of SendKeys.

Perhaps I could have Word Highlight the tags then use SendKeys to send the paste command after the char is sent to the clipboard?

But at that point in the program the Word Doc is hidden.

It seems like there should be a way to paste it direcctly useing the MSWord object and methods.

[longwolf]

David,
I had a problem with the 'CreateObject' method.
If the user closed the 1st doc and tried to make a new one, CreateObject reported the MSWord object as still existing.
I adopted Marty's method and it's working fine.

Update to this.
Marty's code had a problem if the user opened thier own Word Document while the program was running.

I made a hybred sub using both of y'alls codes.
It aint pretty, but it works

Public Function WordInitialize() As Boolean
    Dim nRpt As Integer
    
    On Error GoTo ErrorRoutine:
StartOver:
    nRpt = FindWindow("OpusApp", vbNullString)
    If nRpt = 0 Then
        Set g_MSWord = New Word.Application
    Else
        Set g_MSWord = Word.Application
    End If
    WordInitialize = True
    Exit Function
    
ErrorRoutine:
    Select Case Err.Number
        Case -2147023174
            ' The user has manually shut down Word, so we need to
            ' clean up and then restart Word.
            For nRpt = 1 To g_MSWord.Documents.Count
                g_MSWord.Documents(nRpt).Close SaveChanges:=wdDoNotSaveChanges
            Next nRpt
            g_MSWord.Quit
            Set g_MSWord = Nothing
            Resume StartOver
        Case 429
            'ActiveX component can't create object
            Resume Next
        Case 462
            Resume Next
        Case Else
            'Sometimes FindWindow doesn't work, try GetObject
            On Error GoTo StillBad:
            Set g_MSWord = GetObject(, "Word.Application")
            If g_MSWord Is Nothing Then
                Set g_MSWord = CreateObject("Word.Application")
            End If
            g_lMSWordHwnd = FindWindow("OpusApp", vbNullString)
            WordInitialize = True
            Exit Function
StillBad:
            MsgBox Err.Number & " - " & Err.Description & vbCrLf & _
                   "Please make sure there there are no other instances of MS Word running.", vbExclamation, App.Title
    End Select
End Function

[longwolf]

I got it.

For some reason I had to clear the clipboard before pasteing the new char to it.
Then use the PasteSpecial method in a loop.
It only replaces chars one at a time.

'    'change the font symbols
    Clipboard.Clear
    MoonPhaseToClipboard NewMoon
    Do
        g_MSWord.Selection.Find.Execute "NM", True, True, , , , True, wdFindContinue
        If g_MSWord.Selection.Find.Found Then
            g_MSWord.Selection.PasteSpecial , , , , wdPasteRTF
        End If
    Loop While g_MSWord.Selection.Find.Found

Thanks Guys!
You were a big help and also helped keep me thinking.

Now as long as the guy doesn't call me back asking what happened to his MBR............