Writing on checks

[tonyrueb]

I am making a program that will print on checks. I have it so it will ask for the amount in a $12.50 format, and all the other info. But as I’m sure all of you know you also have to write it out like “Twelve dollars and 50/100*************” seems simple but I don’t know how to go about this.

[tonyrueb]

i found the answer my self

'************ Code Start **********
    'This code was originally written by Joe Foster.
    'It is not to be altered or distributed,
    'except as part of an application.
    'You are free to use it in any application,
    'provided the copyright notice is left unchanged.
    '
    'Code Courtesy of
    'Joe Foster
    '
    ' Convert a currency value into an (American) English string
    Function Writeout(ByVal N As Double) As String
        Const Thousand = 1000@
        Const Million = Thousand * Thousand
        Const Billion = Thousand * Million
        Const Trillion = Thousand * Billion
 
        If (N = 0@) Then Writeout = "zero" : Exit Function
 
        Dim Buf As String : If (N < 0@) Then Buf = "negative " Else Buf = ""
        Dim Frac As Double : Frac = Math.Abs(N - Fix(N))
        If (N < 0@ Or Frac <> 0@) Then N = Math.Abs(Fix(N))
        Dim AtLeastOne As Integer : AtLeastOne = N >= 1
 
        If (N >= Trillion) Then
 
            Buf = Buf & EnglishDigitGroup(Int(N / Trillion)) & " trillion"
            N = N - Int(N / Trillion) * Trillion ' Mod overflows
            If (N >= 1@) Then Buf = Buf & " "
        End If
 
        If (N >= Billion) Then
 
            Buf = Buf & EnglishDigitGroup(Int(N / Billion)) & " Billion"
            N = N - Int(N / Billion) * Billion ' Mod still overflows
            If (N >= 1@) Then Buf = Buf & " "
        End If
 
        If (N >= Million) Then
 
            Buf = Buf & EnglishDigitGroup(N \ Million) & " Million"
            N = N Mod Million
            If (N >= 1@) Then Buf = Buf & " "
        End If
 
        If (N >= Thousand) Then
 
            Buf = Buf & EnglishDigitGroup(N \ Thousand) & " Thousand"
            N = N Mod Thousand
            If (N >= 1@) Then Buf = Buf & " "
        End If
 
        If (N >= 1@) Then
 
            Buf = Buf & EnglishDigitGroup(N)
        End If
 
        If (Frac = 0@) Then
            Buf = Buf & " Exactly"
        ElseIf (Int(Frac * 100@) = Frac * 100@) Then
            If AtLeastOne Then Buf = Buf & " and "
            Buf = Buf & Format$(Frac * 100@, "00") & "/100"
        Else
            If AtLeastOne Then Buf = Buf & " and "
            Buf = Buf & Format$(Frac * 100@, "00") & "/100"
        End If
 
        Writeout = Buf
    End Function
 
    ' Support function to be used only by English()
    Private Function EnglishDigitGroup(ByVal N As Integer) As String
        Const Hundred = " Hundred"
        Const One = "One"
        Const Two = "Two"
        Const Three = "Three"
        Const Four = "Four"
        Const Five = "Five"
        Const Six = "Six"
        Const Seven = "Seven"
        Const Eight = "Eight"
        Const Nine = "Nine"
        Dim Buf As String : Buf = ""
        Dim Flag As Integer : Flag = False
 
        'Do hundreds
        Select Case (N \ 100)
            Case 0 : Buf = "" : Flag = False
            Case 1 : Buf = One & Hundred : Flag = True
            Case 2 : Buf = Two & Hundred : Flag = True
            Case 3 : Buf = Three & Hundred : Flag = True
            Case 4 : Buf = Four & Hundred : Flag = True
            Case 5 : Buf = Five & Hundred : Flag = True
            Case 6 : Buf = Six & Hundred : Flag = True
            Case 7 : Buf = Seven & Hundred : Flag = True
            Case 8 : Buf = Eight & Hundred : Flag = True
            Case 9 : Buf = Nine & Hundred : Flag = True
        End Select
 
        If (Flag <> False) Then N = N Mod 100
        If (N > 0) Then
            If (Flag <> False) Then Buf = Buf & " "
        Else
            EnglishDigitGroup = Buf
            Exit Function
        End If
 
        'Do tens (except teens)
        Select Case (N \ 10)
            Case 0, 1 : Flag = False
            Case 2 : Buf = Buf & "Twenty" : Flag = True
            Case 3 : Buf = Buf & "Thirty" : Flag = True
            Case 4 : Buf = Buf & "Forty" : Flag = True
            Case 5 : Buf = Buf & "Fifty" : Flag = True
            Case 6 : Buf = Buf & "Sixty" : Flag = True
            Case 7 : Buf = Buf & "Seventy" : Flag = True
            Case 8 : Buf = Buf & "Eighty" : Flag = True
            Case 9 : Buf = Buf & "Ninety" : Flag = True
        End Select
 
        If (Flag <> False) Then N = N Mod 10
        If (N > 0) Then
            If (Flag <> False) Then Buf = Buf & "-"
        Else
            EnglishDigitGroup = Buf
            Exit Function
        End If
 
        'Do ones and teens
        Select Case (N)
            Case 0 ' do nothing
            Case 1 : Buf = Buf & One
            Case 2 : Buf = Buf & Two
            Case 3 : Buf = Buf & Three
            Case 4 : Buf = Buf & Four
            Case 5 : Buf = Buf & Five
            Case 6 : Buf = Buf & Six
            Case 7 : Buf = Buf & Seven
            Case 8 : Buf = Buf & Eight
            Case 9 : Buf = Buf & Nine
            Case 10 : Buf = Buf & "Ten"
            Case 11 : Buf = Buf & "Eleven"
            Case 12 : Buf = Buf & "Twelve"
            Case 13 : Buf = Buf & "Thirteen"
            Case 14 : Buf = Buf & "Fourteen"
            Case 15 : Buf = Buf & "Fifteen"
            Case 16 : Buf = Buf & "Sixteen"
            Case 17 : Buf = Buf & "Seventeen"
            Case 18 : Buf = Buf & "Eighteen"
            Case 19 : Buf = Buf & "Nineteen"
        End Select
 
        EnglishDigitGroup = Buf
    End Function
    '************ Code End **********

[szlamany]

I am making a program that will print on checks. I have it so it will ask for the amount in a $12.50 format, and all the other info. But as I’m sure all of you know you also have to write it out like “Twelve dollars and 50/100*************” seems simple but I don’t know how to go about this.

You might choose to do it this way, but it is in no way required - at least not in the US.

We produce payroll, health claim processing and other financial packages and write out out checks as:

EXACTLY 12 DOLLARS AND 00 CENTS

and then to the right of that we put ********12.00

This is the accepted business practice in commercial applications (and some of our customers produce 100,000 checks or more a year!).

Writing it out as words is more for a personal checking account (handwritten).