Custom Pull-Down Menu in Excel

[TheBionicOrange]

I'm sure I read here somewhere recently that you can't replace the default pull-down menus in Excel, but rather "overlay" your custom menus, in affect doing the same thing in the eyes of the user.

Is this true ?

I want to either replace or "overlay" pull-down menus in Excel, but am not really very up to speed in this area.

Can anyone offer any help ?

Thanks

[RobDog888]

You can find the control and set its visibility property to false and then add
your own custom one in the same place in the toolbar, etc. Use the .Find
method of the commandbars collection for the desired toolbar.

[TheBionicOrange]

OK that makes about 60% sense to me so far .... but I'll keep snouting about and see what I can do.

Thanks again Rob

[RobDog888]

I wrote a small example for you. What it does is hide the standard save
menu item. Then it creates a new "Save Me" menu item in its place. I added
an event for it too that just shows a msgbox.

Option Explicit
 
Public WithEvents oCBBCustom As Office.CommandBarButton
 
Private Sub oCBBCustom_Click(ByVal Ctrl As Office.CommandBarButton, CancelDefault As Boolean)
    MsgBox "Save Me!"
End Sub
 
Private Sub Workbook_Open()
    Dim oCB As Office.CommandBar
    Dim oCBBFile As Office.CommandBarPopup
    Dim oCBBSave As Office.CommandBarButton
    Set oCB = Application.CommandBars("Worksheet Menu Bar")
    Set oCBBFile = oCB.Controls("&File")
    Set oCBBSave = oCBBFile.Controls("&Save")
    oCBBSave.Visible = False
    Set oCBBCustom = oCBBFile.Controls.Add(msoControlButton, 1, , 5, True)
    With oCBBCustom
        .Caption = "Save Me"
        .BeginGroup = False
        .Enabled = True
        .Visible = True
    End With
    'oCB.Reset 'To reset the menu.
End Sub

HTH

[TheBionicOrange]

Thanks a lot Rob ... much appreciated