Common Dialog Folder

[Nove]

Is there a way to use the common dialog control to set a folder (not to open or save to file, just to get a folder's application path), or will I have to just code one on my own?

[RobDog888]

Yes, you can use some APIs to create a BrowseForFolder dialog.

Private Type BrowseInfo
    hWndOwner As Long
    pIDLRoot As Long
    pszDisplayName As Long
    lpszTitle As Long
    ulFlags As Long
    lpfnCallback As Long
    lParam As Long
    iImage As Long
End Type
Const BIF_RETURNONLYFSDIRS = 1
Const MAX_PATH = 260
Private Declare Sub CoTaskMemFree Lib "ole32.dll" (ByVal hMem As Long)
Private Declare Function lstrcat Lib "kernel32" Alias "lstrcatA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function SHBrowseForFolder Lib "shell32" (lpbi As BrowseInfo) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32" (ByVal pidList As Long, ByVal lpBuffer As String) As Long
Private Sub Form_Load()
    'KPD-Team 1998
    'URL: [url]http://www.allapi.net/[/url]
    '[email protected]
    Dim iNull As Integer, lpIDList As Long, lResult As Long
    Dim sPath As String, udtBI As BrowseInfo
 
    With udtBI
        'Set the owner window
        .hWndOwner = Me.hWnd
        'lstrcat appends the two strings and returns the memory address
        .lpszTitle = lstrcat("C:\", "")
        'Return only if the user selected a directory
        .ulFlags = BIF_RETURNONLYFSDIRS
    End With
 
    'Show the 'Browse for folder' dialog
    lpIDList = SHBrowseForFolder(udtBI)
    If lpIDList Then
        sPath = String$(MAX_PATH, 0)
        'Get the path from the IDList
        SHGetPathFromIDList lpIDList, sPath
        'free the block of memory
        CoTaskMemFree lpIDList
        iNull = InStr(sPath, vbNullChar)
        If iNull Then
            sPath = Left$(sPath, iNull - 1)
        End If
    End If
 
    MsgBox sPath
End Sub

[Nove]

Thanks, that works absolutely great!

[RobDog888]

No prob. The site has allot of good examples on using APIs.

[robertLL]

RobDog888,

The API folder browse sample code looks very good for me. But what I am looking for is folder and file browse. that means user can find some specific file through click the "Browse" button. Is there any API can handle that?

Any help will be very appreciated!.

Thanks,

Robert Song

[RobDog888]

Use the show files flag.

Private Const BIF_BROWSEINCLUDEFILES As Long = &H4000

[robertLL]

Thank you so much, Rob. the constant woks perfectly.

Robert

[RobDog888]

No prob.

For all the API definitions, constants, and examples, downlod the
API Viewer and API Guide from all api.net