folder exist ???

[davyquyo]

can someone tell me how i can see if a folder exist or not

is use this to find a file

if len(dir$("login.dat")) > 0 then

i could not find the right script to o the same for a folder
i try't this

if len(mkdir$("login")) > 0 then


but an error shows up then

what's is the right way to do this

[baja_yu]

I have searched for this alot and I find these to be the best:

Function funFolderExists(ByVal lsFilename As String) As Boolean
        On Error Resume Next
        
        Dim fso As New Scripting.FileSystemObject
        
        funFolderExists = fso.FolderExists(lsFilename)
        Set fso = Nothing
    End Function
    
    Function funFileExists(ByVal lsFilename As String) As Boolean
        On Error Resume Next
        
        Dim fso As New Scripting.FileSystemObject
        
        funFileExists = fso.FileExists(lsFilename)
        Set fso = Nothing
    End Function

you have to turn on Microsoft Scripting Runtime in the refferences.

[RhinoBull]

'check for a folder existance
If Dir(App.Path & "\Data", vbDirectory) = "" Then
    MkDir App.Path & "\Data"
Else
    'check for a file existance
    If Not Dir(App.Path & "\Data\myfile.dat", vbNormal) = "" Then
        'open file 
    Else
        MsgBox "Cannot locate " & App.Path & "\Data\myfile.dat"
    End If
End If

[davyquyo]

i think the one from redbull is the bestpassing thing to my script
i try not to use fso
don't ask me why
probaply because i can use fso in html on local machine and i will mix up the scripts
hehe

[RobDog888]

Sorry, I know this thread is resolved but a more reliable way without
dependancies to check for a file...

Option Explicit
 
Private Const OF_EXIST = &H4000
Private Const OFS_MAXPATHNAME = 128
 
Private Type OFSTRUCT
    cBytes As Byte
    fFixedDisk As Byte
    nErrCode As Integer
    Reserved1 As Integer
    Reserved2 As Integer
    szPathName(OFS_MAXPATHNAME) As Byte
End Type
 
Private Declare Function OpenFile Lib "kernel32" (ByVal lpFileName As String, lpReOpenBuff As OFSTRUCT, ByVal wStyle As Long) As Long
 
Public Function FileExists(ByVal sFile As String) As Long
 
    Dim lRetVal As Long
    Dim OfSt As OFSTRUCT
    
    lRetVal = OpenFile(sFile, OfSt, OF_EXIST)
    If lRetVal = 1 Then
        FileExists = 1
    Else
        FileExists = 0
    End If
    
End Function
 
'Usage:
Private Sub Command1_Click()
    If FileExists("C:\DeleteMe\Test.txt") = 1 Then
        Msgbox "File Exists!"
    Else
        MsgBox "File Not Found!"
    End If
End Sub

[davyquyo]

it's realy very nice but here you going to use dll
i also try not to use much dll files because i want to try avoid dll trouble
i don't wan't to be responsible
that a computer from a great company crashes

thanks for the help

[baja_yu]

The reason I ended up using FSO (I can remember I think I started a thread on this) is that the method that Rhino gave (which I used at first) does not work with hidden folders. I tested 4 different methods and the one with FSO is the best, and all you have to include is the scrrun.dll which is only about 140kb

[RobDog888]

kernel32 is a basic Windows O.S. dll. If the user doesn't have it
then they are not running Windows NT 3.1 or later or Windows
95 or later.