Running app as Admin.

[Danial]

Hi,
I have some tools which runs in the bacground and carry out administrative task.

I am running my utility in all XP machines and Limited user environment. Now my utility needs to modify/add/delete certain registry keys/values. Since the application is running from the Limited user account my utility is prevented from modifying the registry. I dont want to give the users the abilit to modify registry manually only my utility.

Is there any way to Impersonate or run an utility with Admin priviliages?

Thanks.

[RobDog888]

This example will solve your problem.

Private Const LOGON_WITH_PROFILE = &H1&
Private Const LOGON_NETCREDENTIALS_ONLY = &H2&
Private Const CREATE_DEFAULT_ERROR_MODE = &H4000000
Private Const CREATE_NEW_CONSOLE = &H10&
Private Const CREATE_NEW_PROCESS_GROUP = &H200&
Private Const CREATE_SEPARATE_WOW_VDM = &H800&
Private Const CREATE_SUSPENDED = &H4&
Private Const CREATE_UNICODE_ENVIRONMENT = &H400&
Private Const ABOVE_NORMAL_PRIORITY_CLASS = &H8000&
Private Const BELOW_NORMAL_PRIORITY_CLASS = &H4000&
Private Const HIGH_PRIORITY_CLASS = &H80&
Private Const IDLE_PRIORITY_CLASS = &H40&
Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const REALTIME_PRIORITY_CLASS = &H100&
 
Private Type PROCESS_INFORMATION
    hProcess As Long
    hThread As Long
    dwProcessId As Long
    dwThreadId As Long
End Type
 
Private Type STARTUPINFO
    cb As Long
    lpReserved As Long
    lpDesktop As Long
    lpTitle As Long
    dwX As Long
    dwY As Long
    dwXSize As Long
    dwYSize As Long
    dwXCountChars As Long
    dwYCountChars As Long
    dwFillAttribute As Long
    dwFlags As Long
    wShowWindow As Integer
    cbReserved2 As Integer
    lpReserved2 As Byte
    hStdInput As Long
    hStdOutput As Long
    hStdError As Long
End Type
 
Private Declare Function CreateProcessWithLogon Lib "Advapi32" Alias "CreateProcessWithLogonW" _
(ByVal lpUsername As Long, ByVal lpDomain As Long, ByVal lpPassword As Long, ByVal dwLogonFlags As Long, _
ByVal lpApplicationName As Long, ByVal lpCommandLine As Long, ByVal dwCreationFlags As Long, ByVal lpEnvironment As Long, _
ByVal lpCurrentDirectory As Long, lpStartupInfo As STARTUPINFO, lpProcessInfo As PROCESS_INFORMATION) As Long
 
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
 
Private Sub Form_Load()
    Dim lpUsername As String, lpDomain As String, lpPassword As String, lpApplicationName As String
    Dim lpCommandLine As String, lpCurrentDirectory As String
    Dim StartInfo As STARTUPINFO, ProcessInfo As PROCESS_INFORMATION
    lpUsername = "OtherUser"
    lpDomain = ""
    lpPassword = "other_user_password"
    lpApplicationName = "C:\WINNT\NOTEPAD.EXE"
    lpCommandLine = vbNullString 'use the same as lpApplicationName
    lpCurrentDirectory = vbNullString 'use standard directory
    StartInfo.cb = LenB(StartInfo) 'initialize structure
    StartInfo.dwFlags = 0&
    CreateProcessWithLogon StrPtr(lpUsername), StrPtr(lpDomain), StrPtr(lpPassword), LOGON_WITH_PROFILE, _
    StrPtr(lpApplicationName), StrPtr(lpCommandLine), CREATE_DEFAULT_ERROR_MODE Or CREATE_NEW_CONSOLE Or _
    CREATE_NEW_PROCESS_GROUP, ByVal 0&, StrPtr(lpCurrentDirectory), StartInfo, ProcessInfo
    CloseHandle ProcessInfo.hThread 'close the handle to the main thread, since we don't use it
    CloseHandle ProcessInfo.hProcess 'close the handle to the process, since we don't use it
    'note that closing the handles of the main thread and the process do not terminate the process
    'unload this application
    Unload Me
End Sub

[Danial]

Thanks Rob for your quicky reply. I will try it out and let you.

Cheers.

Danial

[RobDog888]

No prob. I was just re-formatting the post so it wouldn't be so wide.

[Danial]

Rob,
Just skimmed through your code, it seems like I would need to provide admin password. I could make the admin provide their password when the run this first time and store the encrypted password.

I am a bit concenered about the security issues regarding storing Admin password even though I will encrypt it.

Is this the only way or there are other methods which i can use to modify registry value from a limited user account?

[RobDog888]

There is a CreateProcessAsUser API, but I dont have an example.
I assume you would still need a username and password. What
about hardcoding it? I know its not usually a good idea but then it
wont be exposed except to your programmers.

[Danial]

Originally posted by RobDog888
There is a CreateProcessAsUser API, but I dont have an example.
I assume you would still need a username and password. What
about hardcoding it? I know its not usually a good idea but then it
wont be exposed except to your programmers.

Looked up the Reference for CreateProcessAsUser API, you would need to create token for which you would need to authenticate using password.

I guess it makes sense other wise any process can run as admin and cause havoc. Just want to make sure its not possible.

Haradcoding is not an option since I wont know the Admin password in advance. I guess I will have to ask the Admin password during installation and some how store it safely(I have got few ideas already).

Thanks again.

[RobDog888]

No prob. Probably encrypting in the registry would be good,
but if you cant get into the registry to read the credientials then
the point it mute.

[Dave Sell]

He should be able to READ from the registry, just not WRITE to it.