Set Textbox Inside Listview SubItem [Resolved]

[RobDog888]

I need to "Float" a textbox over a listview subitem to make the
appearance of editing a subitem. I have the detection code for
which subitem was clicked and row, but everything I found was
using the x, y coordinates of the mouse click which does not
accurately position the textbox within the sub item.

How can I set a textbox coordinates to match the subitems
rectangular coordinates? Maybe something like getting the RECT
of the subitem somehow?

Thanks.

[RobDog888]

I found this constant so I think this is the correct path to take.

Public Const LVM_FIRST As Long = &H1000
Public Const LVM_GETSUBITEMRECT As Long = (LVM_FIRST + 56)

Anyone know how to get the coordinates? Probably SendMessage?

[Bruce Fox]

Hi RobDog,

I seem to recall similar posts awhile back, this may have been one.




Bruce.

[RobDog888]

Its a little tacky, though. I am still searching. I thought I came
across something using subclassing a long time ago. Hope I can
find it.

[RobDog888]

I think I'm on the right track now, but I'm having trouble using
this function I found here

Its the ListView_GetSubItemRect function. What is the value I
should be passing for "code As Long"?

[Dmitri K]

RobDog,
what I did is I created a flat textbox and just moved it to a given cell (curselrow and curselcolumn) and made the width/height of the textbox to the width of the columnheader. Although it's a cheap way, it works perfect. The only trick is, make sure the column is visible before displaying the textbox. I'll take a look at the code from the url you provided, maybe, if it's good enough, i'll replace my current functions with it.

[RobDog888]

I found a demo project at the site referenced by the thread. It
looks promissing, but when your editing (showing the textbox)
and the user scrolls the listview, the textbox does not move
accordingly. Getting closer though. Logic is similar to what I was
using to start and yours too.

[Dmitri K]

OK i got this rect thing to work. Add a listview, commandbutton, label and a textbox (no need to rename them or modify them):

Option Explicit
 
Const LVM_GETITEMRECT = (&H1000 + 14)
Private Type RECT
  Left As Long
  Top As Long
  Right As Long
  Bottom As Long
End Type
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
 
Private Sub Command1_Click()
  Dim rec As RECT
  
  SendMessage ListView1.hWnd, LVM_GETITEMRECT, Val(Text1.Text) - 1, rec
    
  MsgBox "bottom: " & rec.Bottom & vbCrLf & _
         "left: " & rec.Left & vbCrLf & _
         "right: " & rec.Right & vbCrLf & _
         "top: " & rec.Top
 
End Sub
 
Private Sub Form_Load()
 
  Dim iitem As ListItem
  Dim x As Integer
  
  ListView1.View = lvwReport
  ListView1.ColumnHeaders.Add , , "col1"
  ListView1.ColumnHeaders.Add , , "col2"
  Label1.Caption = "row:"
  Text1.Text = "1"
  
  For x = 1 To 10
    Set iitem = ListView1.ListItems.Add(, , "test" & x)
      iitem.SubItems(1) = "testsub" & x
  Next x
  
End Sub

looks promissing, although my results returned pretty much the same values using columnwidth array. The only problem is the textbox refuses to stay the height i make it using row's height. I dont know why it always make itself 360 in height even if i make it 255 (default row height) or what not.

[RobDog888]

How come it always returns the left as 0 when I changed the
message to LVM_GETSUBITEMRECT?

[RobDog888]

You need to use the LVIR_LABEL constant to inform the
sendmessage function that it is in report mode and get the label
rect. Also, you need to populate the rect in the sendmessage api
with the top and left properties only. Top = subitem index and left
= LVIR_LABEL value.

So I almost have it resolved except for the height and the left
offset. It seems that it always puts the textbox a little to the right
of the beginning of the subitem and the height does not
completely fit. Perhaps because of the font size cant be chopped
off.

Ps. also use the setparent api to make the textbox a child of the
listview so when it scrolls the textbox follows.

[Dmitri K]

Ok, well here's my code for this kind of stuff. By the way, the left and top are in offset beause of the border of the lsitview. For some reason with flat appearance it's still as with 3d appearance but the code below works for either.

just add a listview and a textbox

Option Explicit
 
Private BMargin As Long
 
Private Sub Form_Load()
  Dim aCol() As Variant, aColW() As Variant
  Dim iItem As ListItem
  Dim x As Integer
  
 
  ListView1.View = lvwReport
  ListView1.FullRowSelect = True
  ListView1.GridLines = True
  ListView1.LabelEdit = lvwManual
  Text1.Appearance = 0
  
  aCol = Array("coltest1", "coltest2", "coltest3", "coltest4")
  aColW = Array(1300, 1300, 600, 2000)
 
  For x = LBound(aCol) To UBound(aCol)
    ListView1.ColumnHeaders.Add x + 1, , aCol(x)
  Next x
  
  For x = 1 To 10
    Set iItem = ListView1.ListItems.Add(, , "test" & x)
      iItem.SubItems(1) = "testsub" & x
      iItem.SubItems(2) = "testsub" & x
      iItem.SubItems(3) = "testsub" & x
  Next x
  
  Erase aCol, aColW
  
  If ListView1.Appearance = ccFlat Then
    BMargin = 0
  Else
    BMargin = ListView1.GetFirstVisible.Left
  End If
  
End Sub
 
Private Sub ListView1_MouseMove(Button As Integer, Shift As Integer, x As Single, y As Single)
 
  Dim cnt As Integer
  Dim CurCol As Integer
  
  With ListView1
  
    .SelectedItem = .HitTest(x, y)
    
    If Not .SelectedItem Is Nothing Then
      For cnt = 1 To .ColumnHeaders.Count
        If .ColumnHeaders.item(cnt).Left < x Then CurCol = cnt
      Next cnt
         
      Text1.Move .ColumnHeaders.item(CurCol).Left + .Left + BMargin, .Top + .SelectedItem.Top + BMargin, .ColumnHeaders.item(CurCol).Width + BMargin, .SelectedItem.Height
    End If
  End With
 
End Sub

see if it works better. If it doesn't than let me know, maybe I can use your method.

Oh by the way, this code does not take into consideration if column is invisible (partially). The only way I know how to fix that is make listview the width of the (example) currentcol.left + currentcol.width.

Just edited this post:
hmm, this LVM_SCROLL scrolls horizontally. I'll see if i can make this work.

[RobDog888]

I like the demo, but not the hover effect. Kind of annoying.

I think I found a simpler method to handel the user scrolling the
listview when the textbox is being displayed. I disable them. This
will be enabled when the textbox is hidden by way of esc or
enter keys.

By the way, you need to subclass the listview because if the user
clicks somewhere outside of your app, the lost focus event will
not fire and you will not be able to determine when to hide the
textbox. You can trap for the WM_KILLFOCUS and WM_DESTROY
messages. When you come accross them you hide the textbox
setting the subitem's text back to original value.

Public Declare Function EnableScrollBar Lib "user32.dll" (ByVal hwnd As Long, ByVal wSBflags As Long, _
ByVal wArrows As Long) As Long
 
'SCROLLBAR CONSTS
Public Const SB_HORZ As Long = 0
Public Const SB_VERT As Long = 1
Public Const SB_CTL As Long = 2
Public Const SB_BOTH As Long = 3
 
Public Const ESB_DISABLE_BOTH = &H3
Public Const ESB_DISABLE_DOWN = &H2
Public Const ESB_DISABLE_LEFT = &H1
Public Const ESB_DISABLE_RIGHT = &H2
Public Const ESB_DISABLE_UP = &H1
Public Const ESB_ENABLE_BOTH = &H0
 
'Example of usage
Call EnableScrollBar(ListView1.hwnd, SB_BOTH, ESB_DISABLE_BOTH)

I think this may be good since I cant see why the user should
be scrolling when they are supposed to be editing.

What do you think?

[RobDog888]

More info...

If you use the common controls v. 5.0 for your listview you can
use the SetParent api to link the textbox to the subitem. Then if
the user scrolls the textbox will follow the subitem perfectly. I
dont know why it doesn't work on 6.0 though? Otherwise you
can just use the MapWindowPoints API to set the textbox to the
subitem RECT.

[RobDog888]

Here is a demo of what I was thinking. I just don't like using
the listview in common controls 5.0 for this. No full row select.

[RobDog888]

I just went with the listview in common controls 6.0 and disabled
the scrollbars. In 5.0 the setparent api works for scrolling but if
you scroll beyond the viewable area then it gets messed up. So it
looks like I will have to settle for disabling the scrollbars.

Thanks to all.

[mvrp350]

Hi RObDog888,

I've been playing around with your editable listview.
I'm not able to convert it for working with an array of listviews.
Are you able to upgrade the code, so it will work with arrays?

Thanks in advance