custom.custom

[Skitchen8]

Been far too long since I've worked with VB (Although I've never done this) and I've heard of how to do this before, but I don't remember. I want to have a variable named item with several different variables underneath it (If I remember correctly this has something to do with enumerations) so I can have like item.number = 3 and item.description = 4

not really needed per say, just makes my coding look cleaner, for my own sake.

Any help on how to do that??

[Chrome]

do you mean an enum?

Private Enum TEST
    Jack = 1
    Bob
    Sally
    James
    etc
End Enum

or perhaps a collection

[Skitchen8]

That's exactly what I was looking for, thank you


edit: any way to make this into an array??

So I could have test(0).sally?? or not??

[BuggyProgrammer]

Originally posted by Skitchen8
That's exactly what I was looking for, thank you


edit: any way to make this into an array??

So I could have test(0).sally?? or not??

Huh? How would you want it to work if it was in an array?

[brucevde]

You don't want an Enum you want a user defined type. Enum's are basically constants.

Public Type Item
  Number as Integer 
  Description as String 
End Type
 
'declare a variable using your user defined type
Dim udtItem as Item
'obviously for an array use
Dim udtItems(10) as Item
 
udtItems(0).Number = 1
udtItems(0).Description = 1

[Wokawidget]

I prefer collections and a class as they give you more options and make your code much easier to maintain:
In a class module called clsUser:

Option Explicit
 
Private mstrUsername As String
Private mstrPassword As String
 
Public Property Let Username(ByVal Value As String)
   mstrUsername = Value
End property
 
Public Property Get Username() As String
   Username = mstrUsername
End Property
 
Public Property Let Password(ByVal Value As String)
   mstrPassword = Value
End property
 
Public Property Get Password() As String
   Password = mstrPassword
End Property

Then in your form you would do:

Option Explicit
 
Private mcolItems As Collection
 
Private Sub Form_Load()
   Set mcolItems = New Collection
   AddUsers
End Sub
 
Private Sub AddUsers()
Dim objUser As clsUser
   Set objUser = New clsUser
   objUser.Username = "Woof"
   objUser.Password = "Badger"
   mcolItems.Add objUser
   Set objUser = Nothing
 
   Set objUser = New clsUser
   objUser.Username = "SmallFish"
   objUser.Password = "Sausage"
   mcolItems.Add objUser
   Set objUser = Nothing
End Sub
 
Private Sub Command1_Click()
Dim objUser As clsUser
   Set objUser = mcolItems.Item(1)
   MsgBox objUser.Username
   Set objUser = Nothing
End Sub

Hope that helps.

Woof

[Skitchen8]

Originally posted by brucevde
You don't want an Enum you want a user defined type. Enum's are basically constants.

Public Type Item
  Number as Integer 
  Description as String 
End Type
 
'declare a variable using your user defined type
Dim udtItem as Item
'obviously for an array use
Dim udtItems(10) as Item
 
udtItems(0).Number = 1
udtItems(0).Description = 1

That appears to be exactly what I want, thank you to all who posted.

-Eric