Detect Listview Vertical Scrollbar [Resolved]

[RobDog888]

I just want to determine if the listview has the vertical scrollbar or
not. As I populate a lvw (report display) I want to shorten the
width of the last columnheader if the lvw has enough items in it
to invoke a vertical scrollbar to be displayed. I have searched and
only found was of turning them on or off, but not detecting when
they are added.

Thanks in advance for any help.

[RobDog888]

Ok, I have found this from M$, but I need it converted to VB.

typedef struct tagSCROLLBARINFO {
    DWORD cbSize;
    RECT rcScrollBar;
    int dxyLineButton;
    int xyThumbTop;
    int xyThumbBottom;
    int reserved;
    DWORD rgstate[CCHILDREN_SCROLLBAR+1];
} SCROLLBARINFO, *PSCROLLBARINFO, *LPSCROLLBARINFO;

VB API

Private Declare Function GetScrollBarInfo Lib "user32.dll" (ByVal hwnd As Long, _
ByVal idObject As Long, ByRef psbi As PSCROLLBARINFO) As Long

Or maybe subclass the lvw and trap for the WM_VSCROLL message. Or test somehow for the SBS_VERT scrollbar style???

[DiGiTaIErRoR]

Dunno bout those API's, but I found these:

Public Type SCROLLINFO
cbSize As Long
fMask As Long
nMin As Long
nMax As Long
nPage As Long
nPos As Long
nTrackPos As Long
End Type

Public Declare Function GetScrollInfo Lib "user32" Alias "GetScrollInfo" (ByVal hWnd As Long, ByVal n As Long, lpScrollInfo As SCROLLINFO) As Long

[RobDog888]

This is what I have been working on so far. Just trying to tell if
the scrollbar is present or not. Not working though.

Option Explicit
 
Private Type SCROLLINFO
    cbSize As Long
    fMask As Long
    nMin As Long
    nMax As Long
    nPage As Long
    nPos As Long
    nTrackPos As Long
End Type
 
'SCROLLBAR STYLE
Private Const SBS_VERT As Long = &H1&
 
'SCROLLBAR MESSAGE
Private Const WM_VSCROLL As Long = &H115
 
'SCROLLBAR CONST
Private Const SB_VERT As Long = 1
 
'Private Declare Function GetScrollBarInfo Lib "user32.dll" (ByVal hwnd As Long, ByVal idObject As Long, ByRef psbi As PSCROLLBARINFO) As Long
 
Private Declare Function GetScrollInfo Lib "user32.dll" (ByVal hWnd As Long, ByVal n As Long, ByRef lpScrollInfo As SCROLLINFO) As Long
 
Private Sub cmdAdd_Click()
    ListView1.ListItems.Add , , "Test"
End Sub
 
Private Sub cmdCheck_Click()
    
    Dim si As SCROLLINFO
    Dim lRetVal As Long
    
    si.cbSize = Len(si)
    si.fMask = SB_VERT
    lRetVal = GetScrollInfo(ListView1.hWnd, ByVal SB_VERT, si)
    If si.fMask = SB_VERT Then
        MsgBox lRetVal & "-True"
    Else
        MsgBox lRetVal & "-False"
    End If
End Sub
 
Private Sub cmdRemove_Click()
    ListView1.ListItems.Remove ListView1.ListItems.Count
End Sub
 
Private Sub Form_Load()
    ListView1.ColumnHeaders.Add , , "Test"
End Sub

Can you see where I may be going wrong?

Thanks.

[RobDog888]

I finally got it! After researching at M$ I found that you can get
the number of listitems that can be displayed in the lvw client
area without a vertical scrollbar (.nPage of the SCROLLINFO
structure). Then compare with the number of listitems and if more
than .nPage then scrollbar must be visible.

Complete example.

'NEED 3 COMMANDBUTTONS AND 1 LISTVIEW
Option Explicit
 
Private Type SCROLLINFO
    cbSize As Long
    fMask As Long
    nMin As Long
    nMax As Long
    nPage As Long
    nPos As Long
    nTrackPos As Long
End Type
 
'SCROLLBAR STYLE
'Private Const SBS_HORZ As Long = &H0&
'Private Const SBS_VERT As Long = &H1&
 
'SCROLLBAR MESSAGE
'Private Const WM_HSCROLL As Long = &H114
'Private Const WM_VSCROLL As Long = &H115
 
'SCROLLBAR CONSTS
Private Const SB_HORZ As Long = 0
Private Const SB_VERT As Long = 1
Private Const SB_CTL As Long = 2
Private Const SB_BOTH As Long = 3
 
Private Const SIF_PAGE As Long = &H2
Private Const SIF_POS As Long = &H4
Private Const SIF_RANGE As Long = &H1
Private Const SIF_TRACKPOS As Long = &H10 'FOR DETECTING WHEN USER CLICKS AND DRAGS THUMB CTL
Private Const SIF_ALL As Long = (SIF_RANGE Or SIF_PAGE Or SIF_POS Or SIF_TRACKPOS)
 
Private Declare Function GetScrollInfo Lib "user32.dll" (ByVal hWnd As Long, ByVal n As Long, _
ByRef lpScrollInfo As SCROLLINFO) As Long
 
Private Sub cmdAdd_Click()
    ListView1.ListItems.Add , , "Test " & ListView1.ListItems.Count + 1
End Sub
 
Private Sub cmdCheck_Click()
    
    Dim si As SCROLLINFO
    Dim lRetVal As Long
    
    si.cbSize = Len(si)
    si.fMask = SIF_PAGE 
    lRetVal = GetScrollInfo(ListView1.hWnd, ByVal SB_VERT, si)
    If ListView1.ListItems.Count > si.nPage Then
        MsgBox "Vertical ScrollBar Visible = True"
    Else
        MsgBox "Vertical ScrollBar Visible = False"
    End If
    
End Sub
 
Private Sub cmdRemove_Click()
    If ListView1.ListItems.Count = 0 Then Exit Sub
    ListView1.ListItems.Remove ListView1.ListItems.Count
End Sub
 
Private Sub Form_Load()
    ListView1.ColumnHeaders.Add , , "Vertical ScrollBar Test"
End Sub

[The Bad One]

This code works fine, but there's a small problem I'm having... Sometimes si.nPage = 1 when there's no vertical scrollbar. This doesn't happen when I break and debug.