Shell command to check if program stops running!

[ITboy]

I'm doing a VBA program whereby it reads text files(That is not the problem). Those text files are created by a perl program. At one point, I would need to click a button in my Userform to activate the perl program to execute. Also, to prevent the compiler from reading the next line in my code(y? coz the text files wouldn't be created yet coz they are BIG n SEVERAL of them need to be created), how am I to pause my program to check whether the files are created(NOT IF THE FILES R THERE COZ THE FILES MAY EXISTS BUT NOT ALL THE DATA ARE CREATED.HOPE U UNDERSATND THIS) OR whether the perl program has stopped running.I've got a "plain" Shell func but not with this conditions to loop n check. Any body who knows this pls help .Attached is how my Shell func is like(ive put it in a notepad).Feel free to make changes in it and send me if u know how to work it out.Thanks a 1000 times.

[john_murphy]

Hello Singapore,
Bet its warmer there.

Anyway to the point.

I presume that your perl program opens the text file for write thus locking it.

what you could do is a loop with a sleep in it (trapping the error) and keep retrying until you can open the textfile exclusively for reading!!

On Error Resume Next
Dim finished As Boolean
finished = False

Do While finished = False
Open "c:\john.txt" For Binary Access Read Lock Read As #1
finished = True
Loop
Close #1

[Frans C]

Here is a function that starts a process, and wits until it has finished, or the timeout is passed.

Private Type STARTUPINFO
    cb As Long
    lpReserved As String
    lpDesktop As String
    lpTitle As String
    dwX As Long
    dwY As Long
    dwXSize As Long
    dwYSize As Long
    dwXCountChars As Long
    dwYCountChars As Long
    dwFillAttribute As Long
    dwFlags As Long
    wShowWindow As Integer
    cbReserved2 As Integer
    lpReserved2 As Long
    hStdInput As Long
    hStdOutput As Long
    hStdError As Long
End Type
 
Private Type PROCESS_INFORMATION
    hProcess As Long
    hThread As Long
    dwProcessId As Long
    dwThreadID As Long
End Type
 
Const NORMAL_PRIORITY_CLASS = &H20
Const IDLE_PRIORITY_CLASS = &H40
Const HIGH_PRIORITY_CLASS = &H80
 
Private Declare Function WaitForSingleObject Lib _
    "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds _
    As Long) As Long
 
Private Declare Function CreateProcessA Lib "kernel32" _
    (ByVal lpApplicationName As Long, ByVal lpCommandLine As _
    String, ByVal lpProcessAttributes As Long, ByVal _
    lpThreadAttributes As Long, ByVal bInheritHandles As Long, _
    ByVal dwCreationFlags As Long, ByVal lpEnvironment As Long, _
    ByVal lpCurrentDirectory As Long, lpStartupInfo As _
    STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) _
    As Long
 
Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) _
    As Long
 
Public Sub ShellNWait(CommandLine As String, Optional WaitForMilliseconds As Long = -1&, Optional Priority As Long = NORMAL_PRIORITY_CLASS)
    Dim proc As PROCESS_INFORMATION
    Dim Start As STARTUPINFO
    Dim lRet As Long
On Error Resume Next
 
    'Initialize the STARTUPINFO structure:
    Start.cb = Len(Start)
    
    'Start the shelled application:
    lRet = CreateProcessA(0&, CommandLine, 0&, 0&, 1&, _
    Priority, 0&, 0&, Start, proc)
    
    'Wait for the shelled application to finish:
    'use -1 to specify no "timeout" length.
    lRet = WaitForSingleObject(proc.hProcess, WaitForMilliseconds)
    lRet = CloseHandle(proc.hProcess)
    lRet = CloseHandle(proc.hThread)
End Sub

P.S. I copied the code from a post brenaaro posted, and modified it a little to fix a little bug.
Here is the original thread:
http://www.vbforums.com/showthread.p...hreadid=221401

[ITboy]

Frans C...Did u look into my attached file.I've got a "similar" code there but I dont c any condition there to check my files ....?! Is there?? And for u , John, where should I place the code..according to tat shell functionwhich is attached?? Thanks for both ur replies..Hope to hear from u.

[Frans C]

You could check the files last modified date, using VB's FileDateTime function