need some help on this one

[freddie_26]

hey there

need some help on a program that i'm trying to create. i've been working on this for over three weeks now. here is what i want to do.

create a program that offer some word to word translation from english to the language chosen by the user. It could be any language. the user is supposed to type the word in english and the word is supposed to be translated in the other language.
Also i want to do it using sentences.

Any help would be appreciated greatly. Just need some idea about how to create the program.

thank you very much.

[Pirate]

I've done something similar as a bilingual dictionary . No much coding requird if it works as dictionary .I'll tell you what I did :

I've created database with only one table and two fields .Let suppose you have two fields named : English and French .Structure of your table should looks something like this :

---------------------------
English : French :
---------------------------
Hi : Hi
nice : gentil
Pirate : Pirate
boy : garçon
translate : traduisez

Now , what are you ganna do ?
Build your proj with one textbox at least used to type a word in English to be translated into French (either vice versa or both )

Then , your program looks for this word in english field actually,for instance, if any matches found then show the record combined with it in french . Show the word besides the word in english .If you have done it this way , this results in bilingual dictionary . You need to hire tens of typist either ways lol

Cheers

[rudvs2]

the following class is an example I banged together for you

It supposes that you have a database named dictionary.mdb

the class is very rough but should give you the basic idea

the db is defined by the following schema

<?xml version="1.0" encoding="utf-8" ?>
<xs:schema id="dictionary" targetNamespace="http://tempuri.org/dictionary.xsd" elementFormDefault="qualified" xmlns="http://tempuri.org/dictionary.xsd" xmlns:mstns="http://tempuri.org/dictionary.xsd" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:msdata="urn:schemas-microsoft-com:xml-msdata">
    <xs:element name="Dictionary">
        <xs:complexType>
            <xs:sequence>
                <xs:element name="DictKey" type="xs:long" />
                <xs:element name="EngWord" type="xs:string" />
                <xs:element name="Definition" type="xs:string" />
                <xs:element name="FrenchWord" type="xs:string" />
            </xs:sequence>
        </xs:complexType>
        <xs:key name="DictionaryKey" msdata:PrimaryKey="true">
            <xs:selector xpath="." />
            <xs:field xpath="mstns:DictKey" />
        </xs:key>
    </xs:element>
</xs:schema>

the class code is

Friend Class translateCls
 
    Private Const CONSTRING1 As String = "Provider=Microsoft.Jet.OLEDB.4.0;Password="""";User ID=Admin;Data Source="
 
    Private Const CONSTRING2 As String = ";Mode=Share Deny None;Extended Properties="""";Jet OLEDB:System database="""";" & _
            "Jet OLEDB:Registry Path="""";Jet OLEDB:Database Password="""";Jet OLEDB:Engine Type=" & _
            "5;Jet OLEDB:Database Locking Mode=1;Jet OLEDB:Global Partial Bulk Ops=2;Jet OLED" & _
            "B:Global Bulk Transactions=1;Jet OLEDB:New Database Password="""";Jet OLEDB:Create" & _
            " System Database=False;Jet OLEDB:Encrypt Database=False;Jet OLEDB:Don't Copy Loc" & _
            "ale on Compact=False;Jet OLEDB:Compact Without Replica Repair=False;Jet OLEDB:SF" & _
            "P=False"
 
    Protected Enum indexPosition
        FirstWord = 0
        MidString = 1
        LastWord = 2
    End Enum
 
    Dim m_StringToTranslate As String = Nothing
    Dim m_TranslatedString As String = Nothing
 
    Friend Property StringToTranslate() As String
        Get
            Return m_StringToTranslate
        End Get
        Set(ByVal Value As String)
            m_StringToTranslate = Value
        End Set
    End Property
 
    Friend Property TranslatedString() As String
        Get
            Return m_TranslatedString
        End Get
        Set(ByVal Value As String)
            m_TranslatedString = Value
        End Set
    End Property
 
    Protected Friend Shared Function Translate(ByVal originalString As String) As String
        Return Translator(originalString)
    End Function
 
    Protected Friend Sub Translate()
        m_TranslatedString = Translator(m_StringToTranslate)
    End Sub
 
    Protected Shared Function Translator(Optional ByVal originalString As String = "") As String
        Dim stringArray() As String = originalString.Split(" ")
        Dim intLoop As Integer
        Dim NewString As String = originalString
        Dim indexPos As indexPosition = indexPosition.FirstWord
        For intLoop = 0 To stringArray.Length - 1
            If intLoop > 0 And intLoop < stringArray.Length - 1 Then
                indexPos = indexPosition.MidString
            ElseIf intLoop = stringArray.Length - 1 Then
                indexPos = indexPosition.LastWord
            End If
            NewString = Replace(NewString, stringArray(intLoop), GetReplaceMentWord(stringArray(intLoop), indexPos))
        Next intLoop
        Return NewString
    End Function
 
    Protected Shared Function Replace(ByVal str As String, ByVal strSearchWord As String, ByVal strReplaceWord As String) As String
        Dim regex As New System.Text.RegularExpressions.Regex("(?i:(" & strSearchWord & "\s)|(\s" & strSearchWord & ")|(" & strSearchWord & "\.)|(" & strSearchWord & ",))")
        str = (regex.Replace(str, strReplaceWord))
        Return str
    End Function
 
 
    Protected Shared Function GetReplaceMentWord(ByVal strWord As String, ByVal position As indexPosition) As String
        Dim dbConn As New OleDb.OleDbConnection(CONSTRING1 & getExeLocation() & "dictionary.mdb" & CONSTRING2)
        Dim strSql As String = "SELECT FrenchWord FROM dictionary WHERE EngWord = '" & strWord & "'"
        Dim dbAdapter As New OleDb.OleDbDataAdapter(strSql, dbConn)
        Dim ods As New DataSet()
 
        dbConn.Open()
        dbAdapter.Fill(ods)
        dbConn.Close()
 
        Dim strNewWord As String = ""
 
        If (Not ods.Tables(0).Rows.Count = 0) Then
            strNewWord = ods.Tables(0).Rows(0).Item("FrenchWord")
        Else
            strNewWord = "?"
        End If
 
        Select Case position
            Case indexPosition.FirstWord
                strNewWord = strNewWord & " "
            Case indexPosition.MidString
                strNewWord = " " & strNewWord
            Case indexPosition.LastWord
                strNewWord = " " & strNewWord
        End Select
        Return strNewWord
    End Function
 
    Protected Shared Function getExeLocation() As String
        Dim strLoc As String = System.Reflection.Assembly.GetExecutingAssembly.Location
        strLoc = strLoc.Remove((strLoc.LastIndexOf("\") + 1), (strLoc.Length - (strLoc.LastIndexOf("\") + 1)))
        Return strLoc
    End Function
 
 
End Class