Scrolling background, exAmpLe included

[scr0p]

I included my example, I want to scroll that graphic in the picbox, forever, I tried to make it like a pattern on the sides so it can scroll evenLy without anyone noticing but I don't care about the graphic, I just did it as a test, I want to know how to make it scroll across, and keep repeating.

[scr0p]

-_- bUMP -_0`

[scr0p]

I just need to know when the picturebox fully passed the left side of the form. then I can just move it to the right and repeat it. I have the equation for this at home somewhere but I am in school now. I need to check the "right" side of the picture box to see if it turns to -1 (passed form.left) But the code isn't coming to me~

[Aaron Young]

Try something like this:

Option Explicit
 
Private oPic As IPictureDisp
Private Const SCROLLSPEED As Long = 1
 
Private Sub Form_Load()
  ' Use Pixels
  ScaleMode = vbPixels
  ' Store the Form Picture to be scrolled
  Set oPic = Picture
  ' Animation Speed
  Timer1.Interval = 10
  Timer1.Enabled = True
End Sub
 
Private Sub Timer1_Timer()
  Static lLeft As Long
  Dim lWidth As Long, lHeight As Long
  Dim lScrollSpeed As Long
  
  lWidth = ScaleX(oPic.Width, vbHimetric, vbPixels)
  lHeight = ScaleY(oPic.Height, vbHimetric, vbPixels)
  
  ' Move Image to Left
  lLeft = lLeft - SCROLLSPEED
  ' If The Image is completely off screen, reset to Zero
  If lLeft <= -lWidth Then lLeft = 0
  
  ' Draw the Image at it's Offset, then append a copy to the end
  ' giving room to wrap the image as it's scrolled.
  PaintPicture oPic, lLeft, 0, lWidth, lHeight, 0, 0, lWidth, lHeight
  PaintPicture oPic, lLeft + lWidth, 0, lWidth, lHeight, 0, 0, lWidth, lHeight
End Sub

You should be able to easily adapt this to scroll inside a picturebox instead of the form.