Encryption / Hashing method which can be used in PHP AND VB for my passwords?

**wpearsall** · Jan 25th, 2003, 04:42 PM

hey ya,

Does any one know a Sub Function / Routine, which i can use for PHP and VB which will both give the exact same result?

Say in php:

PHP Code:


$password = "My Password Here";

$hased_pass = function($password);

and vb:

VB Code:

Dim HasedPass as string
HashedPass = Module1.Function("My Password Here")

..? cuz i need to encrypt my users password / hash em, so as to protect there Data,

But i need to be able to use the same password in my website, and in my Chat Server application....

**<ABX** · Jan 25th, 2003, 05:19 PM

Use MD5

vbMD5 module Is attached

Heres a way to use MD5 in PHP

PHP Code:




<html> 

<head> 

<!--coded by harsha email:[email protected]> 

<title>php and its md5 function</title> 

<?php 

/*if statement  verifies the form input*/  

if($HTTP_POST_VARS) 

{ 

$code= md5($pass);   

/*note that these htmlspecialchars and md5 are the built in functons of php language*/ 

echo "the word you have entered is:\t\t\t".$pass."<br>"; 

echo "the md5ied form of the word is:\t\t\t".$code; 

} 

//end of if statement 

?> 

</head> 

<body> 

<form method="post" action="<?=$PHP_SELF?>"> 

<br> 

<b>enter a word:</b><br><input type="text" name="pass"><br> 

<input type="submit" value="md5"> 

</form> 

</body> 

</html>

-I did not write the PHP or VB Examples

Incase you are not familar with MD5, you can not decrypt it
you must encrypt the password that the user types in and then compare it with the stored password.

**wpearsall** · Jan 26th, 2003, 02:02 AM

they give difference results though?

IE:

Text1 in php gives: 8fd6355c54556be287fecb4166c4a8c1
Text1 in VB gives: 8d993394c892dcaa8683dc4ba4fae21d

[i have searched the forums for ages, even asked a thread b4 about md5, but their diff, etc.]

Is there any way i can get any encryption to give the same result? or will i need to result to having a normal text password in my DB?

[Not that much of a problem, except that it exposes ppl's passwords if ma site gets hacked some way etc..]

How bout a base64_encode? [not "Perfect" but its still some "Protection"?]

is there a way to do this in php/vb that gives the same result?
[This is just a type of "Encoding/Encryption" for php. its used alot for my cookies etc, so it isnt normal text in cookies that ne 1 can read...]

thanks....

**CVMichael** · Jan 26th, 2003, 08:55 PM

And about the MD5, I've checked your MD5 output with one of my MD5 algorithm that I made from this http://www.ietf.org/rfc/rfc1321.txt, and it seems that from the 2 hash strings that you pasted, the VB one is the correct one...
As I know, in PHP, you can include ActiveX DLL's (I think), if that's true, then, you can make a DLL in VB, using the same algorithm that you use in VB (the one you pasted)... Like that you'll have the same result always...

Base64 is te easyest encryption to break because it does not use any password to encode it...

VB Code:

Public Function Base64Encoding(StrToEncode As String) As String
    Static EncodeTable(0 To 63) As Byte
    
    Dim K As Long, OutStr() As Byte, StrIn() As Byte, Lng As Long
    
    If EncodeTable(0) = 0 Then
        For K = 0 To 25
            EncodeTable(K) = Asc("A") + K
        Next K
        
        For K = 0 To 25
            EncodeTable(K + 26) = Asc("a") + K
        Next K
        
        For K = 0 To 9
            EncodeTable(K + 52) = Asc("0") + K
        Next K
        
        EncodeTable(62) = Asc("+")
        EncodeTable(63) = Asc("/")
    End If
    
    If StrToEncode = "" Then Exit Function
    
    StrIn = StrConv(StrToEncode, vbFromUnicode)
    If (Len(StrToEncode) Mod 3) = 0 Then
        ReDim OutStr((Len(StrToEncode) \ 3) * 4 - 1)
    Else
        ReDim OutStr(((Len(StrToEncode) \ 3) + 1) * 4 - 1)
    End If
    
    For K = 0 To Len(StrToEncode) \ 3 - 1
        Lng = StrIn(K * 3 + 2) Or (StrIn(K * 3 + 1) * &H100&) Or (StrIn(K * 3) * &H10000)
        
        OutStr(K * 4 + 0) = EncodeTable((Lng And &HFC0000) \ &H40000)
        OutStr(K * 4 + 1) = EncodeTable((Lng And &H3F000) \ &H1000&)
        OutStr(K * 4 + 2) = EncodeTable((Lng And &HFC0&) \ &H40&)
        OutStr(K * 4 + 3) = EncodeTable(Lng And &H3F&)
    Next K
    
    If (Len(StrToEncode) Mod 3) = 1 Then
        Lng = StrIn(UBound(StrIn)) * &H10000
        
        OutStr(UBound(OutStr) - 3) = EncodeTable((Lng And &HFC0000) \ &H40000)
        OutStr(UBound(OutStr) - 2) = EncodeTable((Lng And &H3F000) \ &H1000&)
        OutStr(UBound(OutStr) - 1) = Asc("=")
        OutStr(UBound(OutStr) - 0) = Asc("=")
    ElseIf (Len(StrToEncode) Mod 3) = 2 Then
        Lng = (StrIn(UBound(StrIn)) * &H100&) Or (StrIn(UBound(StrIn) - 1) * &H10000)
        
        OutStr(UBound(OutStr) - 3) = EncodeTable((Lng And &HFC0000) \ &H40000)
        OutStr(UBound(OutStr) - 2) = EncodeTable((Lng And &H3F000) \ &H1000&)
        OutStr(UBound(OutStr) - 1) = EncodeTable((Lng And &HFC0&) \ &H40&)
        OutStr(UBound(OutStr) - 0) = Asc("=")
    End If
    
    Base64Encoding = StrConv(OutStr, vbUnicode)
End Function
 
Public Function Base64Decoding(StrToDecode As String, Optional CheckInvalidChars As Boolean = True) As String
    Static DecodeTable(0 To 255) As Byte
    
    Dim OutStr() As Byte, StrIn() As Byte
    Dim K As Long, Lng As Long
    
    If DecodeTable(0) = 0 Then
        For K = 0 To 255
            DecodeTable(K) = 255
        Next K
        
        For K = 0 To 25
            DecodeTable(K + 65) = K
        Next K
        
        For K = 26 To 51
            DecodeTable(K + 71) = K
        Next K
        
        For K = 52 To 61
            DecodeTable(K - 4) = K
        Next K
        
        DecodeTable(43) = 62
        DecodeTable(47) = 63
    End If
    
    If StrToDecode = "" Then Exit Function
    
    StrToDecode = Trim(StrToDecode)
    
    If CheckInvalidChars Then
        For K = 0 To 255
            If Not (Chr(K) Like "[A-Za-z0-9+/=]") Then
                StrToDecode = Replace(StrToDecode, Chr(K), "")
            End If
        Next K
    End If
    
    StrIn() = StrConv(StrToDecode, vbFromUnicode)
    ReDim OutStr(0 To ((Len(StrToDecode) \ 4) * 3 - 1))
    
    For K = 0 To Len(StrToDecode) \ 4 - 2
        Lng = DecodeTable(StrIn(K * 4 + 3))
        Lng = Lng Or (DecodeTable(StrIn(K * 4 + 2)) * &H40&)
        Lng = Lng Or (DecodeTable(StrIn(K * 4 + 1)) * &H1000&)
        Lng = Lng Or (DecodeTable(StrIn(K * 4 + 0)) * &H40000)
        
        OutStr(K * 3 + 0) = (Lng And &HFF0000) \ &H10000
        OutStr(K * 3 + 1) = (Lng And &HFF00&) \ &H100&
        OutStr(K * 3 + 2) = Lng And &HFF&
    Next K
    
    Lng = 0
    If DecodeTable(StrIn(K * 4 + 3)) <> 255 Then Lng = DecodeTable(StrIn(K * 4 + 3))
    If DecodeTable(StrIn(K * 4 + 2)) <> 255 Then Lng = Lng Or (DecodeTable(StrIn(K * 4 + 2)) * &H40&)
    If DecodeTable(StrIn(K * 4 + 1)) <> 255 Then Lng = Lng Or (DecodeTable(StrIn(K * 4 + 1)) * &H1000&)
    If DecodeTable(StrIn(K * 4 + 0)) <> 255 Then Lng = Lng Or (DecodeTable(StrIn(K * 4 + 0)) * &H40000)
    
    OutStr(K * 3 + 0) = (Lng And &HFF0000) \ &H10000
    OutStr(K * 3 + 1) = (Lng And &HFF00&) \ &H100&
    OutStr(K * 3 + 2) = Lng And &HFF&
    
    If StrIn(UBound(StrIn) - 1) = 61 Then
        Base64Decoding = Left(StrConv(OutStr, vbUnicode), UBound(OutStr) - 1)
    ElseIf StrIn(UBound(StrIn)) = 61 Then
        Base64Decoding = Left(StrConv(OutStr, vbUnicode), UBound(OutStr) - 0)
    Else
        Base64Decoding = StrConv(OutStr, vbUnicode)
    End If
End Function

**wpearsall** · Jan 27th, 2003, 03:48 AM

OK, I'll try and see about makin the Active X DLL For PHP.

tnx :

**wpearsall** · Jan 27th, 2003, 04:09 AM

lol, dont suppose u no how i load the dll into php when its made?

**CVMichael** · Jan 27th, 2003, 04:11 AM

Nope... no clue... don't even know if it's possible, that was just in theory...

Post a question in PHP forum to ask for this...

**batserra** · Dec 29th, 2005, 03:46 AM

Hi ,i have got a program to encryp files using RC4 ,normaly i use rc4 to encode ,and after i use Base64Encoding ,to save in a binary file ,but the files are very large ,and sometimes ,if the file is long i recive a message ,telling that there isn't enought memory.

Does anybody know any sugestion ,to a best encode?

Thanks

Thread: Encryption / Hashing method which can be used in PHP AND VB for my passwords?

Thread Tools

Display

Encryption / Hashing method which can be used in PHP AND VB for my passwords?

Re: Encryption / Hashing method which can be used in PHP AND VB for my passwords?

Posting Permissions