10 minute timer

[rjohnst]

Hello

I am in need of some big help to be able to set a timer interval (an event) to occur every 10 minutes. The current timer controls only allow 65000ms. So I have the usualy code for the timer interval set:

tmrtimer.Interval = gettimerdef
tmrtimer.Enabled = True

where gettimerdef is defined by a value from a textbox.

I would like to wrap this somehow so that it only occurs every 10 minutes. Any suggestions will be greatly appreciated.

Rob

[kleinma]

set the timer to 60000 which is 1 minute and use a static variable in the timer event to incriment it until it = 10... something like

Private Sub Timer1_Timer
    Static iCount as Integer
    if iCount = 10 then
        iCount = 0
        'YOUR CODE HERE
    else
        iCount = iCount + 1
    end if
End Sub

[amitabh]

Alternatively, you can use the Timer API :

'in a form
Option Explicit
 
Private Sub Form_Load()
    'Create an API-timer
    SetTimer Me.hwnd, 0, 600000, AddressOf TimerProc
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    'Kill our API-timer
    KillTimer Me.hwnd, 0
End Sub
 
 
 
'in a module
Option Explicit
 
Public Declare Function SetTimer Lib "user32" _
(ByVal hwnd As Long, ByVal nIDEvent As Long, _
ByVal uElapse As Long, ByVal lpTimerFunc As Long) As Long
 
Public Declare Function KillTimer Lib "user32" _
(ByVal hwnd As Long, ByVal nIDEvent As Long) As Long
 
Public Sub TimerProc(ByVal hwnd As Long, ByVal nIDEvent As Long, ByVal uElapse As Long, ByVal lpTimerFunc As Long)
    MsgBox "hello world"
End Sub

[manavo11]

Try experimenting with this.

[joltremari]

Private Sub Form_Load() 'Or whatever event will begin the timing
Text1.Text = Now()
End Sub
 
Private Sub Timer1_Timer()
Timer1.Interval = 1000
TenMinutes = DateDiff("n", Text1, Now())
 
    If TenMinutes = 10 Then
        'Do Something
        'Then reset Text1 to the new Now()
    Else
        'Don't Do Something
    End If
 
End Sub