2 quickies

[AFR]

2 quick questions guys..

1)
whats the diff between a Public Sub & a Private Sub?

2)
For anything in VB to work it must be referenced to the right file right?
I have a project that was sent to me, it contains a form and a module, when I click on References, under Tools, in VB6, I see "MISSING" before the file names a few times. The boxes are checked though.
I'm assuming it means that the file it's referencing to is missing.
When I highloght the "MISSING" line, I see a path at the bottom of the box ending with the file name, they're all "*.OCX" files (Active X Control)
So is that why I get "can't find project or library" Error when i run the program?

thanks a bunch!

[Tec-Nico]

1) A Public Sub can be reached from any other form of your project while Private Sub can only be reached in the form you wrote that procedure.

[Tec-Nico]

Could you add the program so I can see what is happening?

[AFR]

SURE!

here you go, this is the code assotiated with the "form"
never used forms before! thanks for your help!

Private mTimerID As Long
 
Public Sub TimerOn()
    mTimerID = SetTimer(0, 0, 5 * 1000, AddressOf TimerCallback)
    If mTimerID = 0 Then
        MsgBox "Unable to create the timer", vbCritical + vbOKOnly, "Error"
    End If
End Sub
Public Sub TimerOff()
    mTimerID = KillTimer(0, mTimerID)
    If mTimerID = 0 Then
        MsgBox "Unable to stop the timer", vbCritical + vbOKOnly, "Error"
    End If
End Sub
 
Public Sub OnTimer()
    Dim code As Long
    code = mEyeOneCtrl.IsConnected
    If code = eNoError Then
        mStateLabel = "connected"
        mStateLabel.BackColor = vbGreen
    Else
        mStateLabel = "not connected"
        mStateLabel.BackColor = vbRed
    End If
 
End Sub
Private Sub SetStatusBarText(ByVal axCode As Long)
    mErrorTextLabel.Caption = mEyeOneCtrl.GetDeviceInfo("LastError")
End Sub
 
Private Sub LoadResults()
    mResultBox.Clear
    Select Case (mResultViewSelector.Object)
        Case "Spectrum"
            LoadSpectrum
        Case "TriStimulus"
            LoadTriStimulus
        Case "Densities"
            LoadDensities
   End Select
End Sub
 
 
Private Sub LoadSpectrum()
    Dim alSpectrum(0 To 35) As Single
    Dim alIndex As Long
 
    alIndex = 0
    While mEyeOneCtrl.GetSpectrum(alSpectrum, alIndex) <> eNoDataAvailable
        Dim alLine As String
        alLine = "Spectrum[" & Format(alIndex, "000") & "]: "    'cant find project or library here, highlights,"Format"
 
        Dim i As Long
        For i = LBound(alSpectrum) To UBound(alSpectrum)
            alLine = alLine & "  |  " & Format(alSpectrum(i), "###0.000")
        Next i
 
        mResultBox.AddItem (alLine)
        alIndex = alIndex + 1
    Wend
End Sub
 
Private Sub LoadTriStimulus()
    Dim alTriStimulus(0 To 2) As Single
    Dim alIndex As Long
            
    alIndex = 0
    While mEyeOneCtrl.GetTriStimulus(alTriStimulus, alIndex) <> eNoDataAvailable
        Dim alLine As String
        alLine = "TriStimulus[" & Format(alIndex, "000") & "]: "
        
        Dim i As Long
        For i = LBound(alTriStimulus) To UBound(alTriStimulus)
            alLine = alLine & "  |  " & Format(alTriStimulus(i), "###0.000")
        Next i
                
        mResultBox.AddItem (alLine)
        alIndex = alIndex + 1
    Wend
End Sub
 
Private Sub LoadDensities()
    Dim alDensities(0 To 3) As Single
    Dim alIndex As Long
    Dim alAutoDensityIndex As Long
    
    alIndex = 0
    While mEyeOneCtrl.GetDensities(alDensities, alAutoDensityIndex, alIndex) <> eNoDataAvailable
        Dim alLine As String
        alLine = "Densities[" & Format(alIndex, "000") & "]: "
        
        Dim i As Long
        For i = LBound(alDensities) To UBound(alDensities)
            Dim tmp As String
            tmp = Format(alDensities(i), "###0.000")
            If i = alAutoDensityIndex Then
                tmp = "<" & tmp & ">"
            End If
            alLine = alLine & "  |  " & tmp
        Next i
                
        mResultBox.AddItem (alLine)
        alIndex = alIndex + 1
    Wend
End Sub
 
Private Sub mCalibrateButton_Click()
    SetStatusBarText mEyeOneCtrl.Calibrate
End Sub
 
Private Sub mMeasureButton_Click()
    If mEyeOneCtrl.TriggerMeasurement <> 0 Then
         mErrorTextLabel.Caption = mEyeOneCtrl.GetDeviceInfo("LastError")
         MsgBox "mesurement failed"
         Exit Sub
    End If
    
    LoadResults
    
End Sub
 
Private Sub mMeasurementModeSelector_Change()
    SetStatusBarText mEyeOneCtrl.SetOption("MeasurementMode", mMeasurementModeSelector.Object)
    LoadResults
End Sub
 
Private Sub mResultViewSelector_Change()
    LoadResults
End Sub
 
Private Sub UserForm_Initialize()
    TimerOn
    
    mMeasurementModeSelector.AddItem ("SingleReflectance")
    mMeasurementModeSelector.AddItem ("ScanningReflectance")
    mMeasurementModeSelector.AddItem ("SingleEmission")
    mMeasurementModeSelector.ListIndex = 0
    
    mResultViewSelector.AddItem ("Spectrum")
    mResultViewSelector.AddItem ("TriStimulus")
    mResultViewSelector.AddItem ("Densities")
    mResultViewSelector.ListIndex = 0
    
    Dim alSubstrate(0 To 35) As Single
    Dim i As Long
    For i = LBound(alSubstrate) To UBound(alSubstrate)
        alSubstrate(i) = 1
    Next i
    Dim code As Long
    code = mEyeOneCtrl.SetSubstrate(alSubstrate)
    
    OnTimer
End Sub
 
Private Sub UserForm_Terminate()
    TimerOff
End Sub

[Tec-Nico]

Ahhh.. I see you are missing a Reference... The same would happen to me when I forgot to add a reference to the MSScript control.

What I ignore is which of all the references is missing... I don't know where format would fit.

Anyway, what I meant was that you should zip and upload the project so we could check it, test it, move some things and then find an answer...

[AFR]

a million thanks Tec-Nico

i included the XLS file (with all the code)

and the DLL that youll need to reference to is about 500,000 bytes when zipped, so it wouldnt let me post it,
not sure if you can do much without referencing to the DLL file


thanks again!