A link to an image

**mendhak** · Dec 12th, 2002, 04:29 AM

If I give ubb image tag, like {IMG]something.com/image3324.asp[/IMG]

Now in the ASP page's coding, I choose from several images in an array list and do a Response.Redirect to that image.

My question is, will that image show up, or will it be a red X?

If you haven't understood the question, I can rephrase:

How did Spetnik do that random image thing in his signature?

**axion_sa** · Dec 12th, 2002, 05:06 AM

In a file rndImageTest.asp:

Code:

<HTML>
<HEAD>
	<TITLE>Untitled</TITLE>
</HEAD>
<BODY>

<table id = 'testImage'>
	<tr>
		<td>
			<%	Response.Write "<img src=rndImage.asp>"  %>
		</td>
	</tr>
</table>

</BODY>
</HTML>

In a file rndImage.asp:

VB Code:

<%
    Dim arrImages
    Dim arrData
    Dim objStream
    
    ' Load the images
    arrImages = Array("images\firewks1.jpg", "images\firewks2.jpg", "images\firewks3.jpg")
    Randomize
    intRnd = Int(((UBound(arrImages) + 1) * Rnd))
    
    Set objStream = Server.CreateObject("ADODB.Stream")
    With objStream
        .Type = 1 ' adTypeBinary
        .Open
        .LoadFromFile Server.MapPath(arrImages(intRnd))
    End With
    With Response
        .ContentType = "image/jpeg" 
        .BinaryWrite objStream.Read
    End With
 
                Set objStream = Nothing
%>

**mendhak** · Dec 12th, 2002, 07:18 AM

Thanks!

**axion_sa** · Dec 12th, 2002, 07:41 AM

My pleasure

Any chance for a cash payment?

**mendhak** · Dec 12th, 2002, 10:06 AM

Originally posted by axion_sa
My pleasure

Any chance for a cash payment?

How about a big fat joint?

**axion_sa** · Dec 12th, 2002, 10:10 AM

Lol - thanks, but no thanks

**WALDO** · Dec 14th, 2002, 12:07 PM

Hey, I'll take one.

Thread: A link to an image

Thread Tools

Display

A link to an image

Posting Permissions