You read it with your eyes.

Actually, you can read files from the Start Menu directory, like the other said.
This is usually C:\Windows\Start Menu.
But sometimes it is not, for example, on localized versions of windows, the directory name is "Start Menu" in another language.

Here's a fail-proof way to get the correct Start Menu directory:
Code:
Option Explicit

Private Declare Function SHGetSpecialFolderLocation Lib "Shell32" (ByVal hWndOwner As Long, ByVal nFolder As Long, ppIDList As Long) As Long
Private Declare Function SHGetPathFromIDList Lib "Shell32" Alias "SHGetPathFromIDListA" (ByVal pIDList As Long, ByVal pszPath As String) As Long

Private Const CSIDL_STARTMENU = &HB
Private Const MAX_PATH = 260
Private Const NOERROR = 0

Function GetStartMenuPath() As String
    Dim pIDList As Long, lPos As Long
    
    If SHGetSpecialFolderLocation(0, CSIDL_STARTMENU, pIDList) = NOERROR Then
        GetStartMenuPath = String(MAX_PATH, vbNullChar)
        If SHGetPathFromIDList(pIDList, GetStartMenuPath) Then
            lPos = InStr(GetStartMenuPath, vbNullChar)
            If lPos > 0 Then GetStartMenuPath = Left(GetStartMenuPath, lPos - 1)
            If Not Right(GetStartMenuPath, 1) = "\" Then GetStartMenuPath = GetStartMenuPath & "\"
        End If
    End If
End Function