Loop thru Listbox not getting all records

[Suidae]

I trying to loop through a listbox and retrieve e-mail addresses. I get the addresses just fine what I’m having a problem with is. If there are ten addresses I’m only pulling 9 addresses and if there is only one address it does not do anything.

What am I doing wrong?

Dim n As Integer
        Dim x As Integer
        
'On Error GoTo err:
 
        n = 0
        x = lstSelected.ListCount - 1
    
    Do Until n = x
        lstSelected.ListIndex = n
        adNM = InStr(1, lstSelected.Text, " - ")
        adID = Right$(lstSelected.Text, Len(lstSelected.Text) - adNM - 1)
        Addstr = adID
        MsgBox adID
        'Call SendBroadcast
        n = n + 1
   Loop

[BruceG]

Your condition should be "Do Until n > x", not "n = x"

[Valkan]

when n reach .listcount - 1 when you get to the n = n + 1 it will exit the do block without taking the item at this index.
changing

do until n=x

for

do until n>x

should fix that

[swatty]

you should loop till n > x

or don't substract 1 from the listcount and test on n = x

change it to whatever you think is better.

[Valkan]

Guess i wasn't fast enough for that one

[swatty]

you could rewrite it with a for next, reads better

For n = 0 To lstSelected.ListCount -1
        lstSelected.ListIndex = n
        adNM = InStr(1, lstSelected.Text, " - ")
        adID = Right$(lstSelected.Text, Len(lstSelected.Text) - adNM - 1)
        Addstr = adID
        MsgBox adID
        'Call SendBroadcast
 
   Next

[Suidae]

Thank you all..

[Wokawidget]

has everyone turned into burnt pancakes today???!

Sub woof()
Dim lngIndex    As Long
Dim strText     As String
Dim lngPos      As Long
    For lngIndex = 0 To lstSelected.ListCount - 1
        strText = lstSelected.List(lngIndex)
        lngPos = InStr(1, strText, " - ")
        adID = Right$(strText, Len(strText) - lngPos - 1)
        Addstr = adID
        MsgBox adID
        'Call SendBroadcast
   Next lngIndex
End Sub

The basics of ALL programming...*SIGH*

Woka