ComboBox (easy!)

[Matt-D]

I want to do this with a ComboBox :
When I start to enter an url (e.g. www.vb-world.net) into the address-box of my browser, the whole address appears after the letters 'www.v' are entered; showing 'www.vb-world.net'. When I go on and write 'www.vbf' it shows 'www.vbforums.com' ....

The content of the Combobox is preaset and can't be changed.
My program has nothing to do with a web-browser, but I thought this example would be nice.
I hope you understand what I mean.
VB 4.0

Matthew

[Dmitri K]

Does this thread require an answer or is it one of them retorical questions lol.

[Matt-D]

Originally posted by Dmitri K
Does this thread require an answer or is it one of them retorical questions lol.

WHY DO YOU ASK THIS?

[Armbruster]

Alot of people go straight to the forums when they get to VBSquare or Visual Basic World, but they don't often realize the vast amount of code and knowledge available at the site.

Here is an excellenet example of what you are looking for:

Type ahead combo box

[James Stanich]

Private Declare Function SendMessage Lib "user32" Alias _
    "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, _
    ByVal wParam As Long, lParam As Any) As Long
 
Const CB_FINDSTRING = &H14C
Const CB_ERR = (-1)
 
'*******************************************************************************
' AUTOFIND (FUNCTION)
'
' DESCRIPTION:
' AUTOCOMPLETE A COMBOBOX (WORKS !!!)
'*******************************************************************************
 
Public Function AUTOFIND(ByRef cboCurrent As ComboBox, _
    ByVal KeyAscii As Integer, Optional ByVal LimitToList As Boolean = False)
    
    Dim lCB As Long
    
    Dim sFindString As String
    
    If KeyAscii = 8 Then
        
        If cboCurrent.SelStart <= 1 Then
            
            cboCurrent = ""
            
            AUTOFIND = 0
            
            Exit Function
            
        End If
        
        If cboCurrent.SelLength = 0 Then
            
            sFindString = UCase(Left(cboCurrent, Len(cboCurrent) - 1))
            
        Else
            
            sFindString = Left$(cboCurrent.Text, cboCurrent.SelStart - 1)
            
        End If
        
    ElseIf KeyAscii < 32 Or KeyAscii > 127 Then
        
        Exit Function
        
    Else
        
        If cboCurrent.SelLength = 0 Then
            
            sFindString = UCase(cboCurrent.Text & Chr$(KeyAscii))
            
        Else
            
            sFindString = Left$(cboCurrent.Text, cboCurrent.SelStart) & Chr$(KeyAscii)
            
        End If
        
    End If
    
    lCB = SendMessage(cboCurrent.hwnd, CB_FINDSTRING, -1, ByVal sFindString)
    
    If lCB <> CB_ERR Then
        
        cboCurrent.ListIndex = lCB
        
        cboCurrent.SelStart = Len(sFindString)
        
        cboCurrent.SelLength = Len(cboCurrent.Text) - cboCurrent.SelStart
        
        AUTOFIND = 0
        
    Else
        
        If LimitToList = True Then
            
            AUTOFIND = 0
            
        Else
            
            AUTOFIND = KeyAscii
            
        End If
        
    End If
    
End Function

[Dmitri K]

WHY DO YOU ASK THIS?

I didn't see any questions in your post, so it seemed to me that you're talking about some example in some other post and instead of replying to that thread you accidently posted and new thread instead.

[Matt-D]

Thanks... but, is there a way to get this running for VB4.0?