Passing strings between different apps **RESOLVED**

**amitabh** · Oct 29th, 2002, 09:04 AM

How do I send a string as a message between two apps using SendMessage or PostMessage?
This is the code I have, but it doesn't work, since I think I will have to use WM_COPYDATA with SendMessage, as suggested by MerrionComputin.
'In the first project

VB Code:

'in a form with a command button
Private Sub Form_Load()
    Me.Caption = "Test Target Window"
    Command1.Caption = "Test_Target_Button"
    'subclass the command button
    lngPrevWndProc = SetWindowLong(Command1.hWnd, GWL_WNDPROC, AddressOf WindowProc)
End Sub
 
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    'set it back to normal before exiting
    SetWindowLong Command1.hWnd, GWL_WNDPROC, lngPrevWndProc
End Sub
 
'=====================
'in a module
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
 
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
 
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
'\\ Pointer validation in StringFromPointer
Private Declare Function IsBadStringPtrByLong Lib "kernel32" Alias "IsBadStringPtrA" (ByVal lpsz As Long, ByVal ucchMax As Long) As Long
 
 
Public Const GWL_WNDPROC = (-4)
 
Public lngPrevWndProc As Long
Public Const WM_USER = &H400
Public Const MY_MSG = WM_USER + 100
 
Public Function WindowProc(ByVal hWnd As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Select Case uMsg
        Case MY_MSG
            MsgBox StringFromPointer(lParam, 12)
            'what to do here
            'lParam returns a pointer, how do I get the string
        Case Else
            WindowProc = CallWindowProc(lngPrevWndProc, hWnd, uMsg, wParam, lParam)
    End Select
End Function
 
Public Function StringFromPointer(lpString As Long, lMaxLength As Long) As String
 
  Dim sRet As String
  Dim lret As Long
 
  If lpString = 0 Then
    StringFromPointer = ""
    Exit Function
  End If
 
  If IsBadStringPtrByLong(lpString, lMaxLength) Then
    '\\ An error has occured - do not attempt to use this pointer
      StringFromPointer = ""
    Exit Function
  End If
 
  '\\ Pre-initialise the return string...
  sRet = Space$(lMaxLength)
  CopyMemory ByVal sRet, ByVal lpString, ByVal Len(sRet)
  If Err.LastDllError = 0 Then
    If InStr(sRet, Chr$(0)) > 0 Then sRet = Left$(sRet, InStr(sRet, Chr$(0)) - 1)
  End If
 
 
  StringFromPointer = sRet
 
End Function

In the second project:

VB Code:

'in a form with a command button
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" _
(ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As String) As Long
 
Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hwnd As Long, _
ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
 
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" _
(ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
 
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, ByVal lpWindowName As String) As Long
 
Private Const WM_USER = &H400
Private Const MY_MSG = WM_USER + 100
 
Private Sub Command1_Click()
Dim lngFrmHwnd As Long
Dim lngBtnHwnd As Long
    lngFrmHwnd = FindWindow(vbNullString, "Test Target Window")
    lngBtnHwnd = FindWindowEx(lngFrmHwnd, 0&, vbNullString, "Test_Target_Button")
    SendMessage lngBtnHwnd, MY_MSG, 0&, "hello world"
    
End Sub

I am also attaching the code.

Thanks
Amitabh Kant

**MerrionComputin** · Oct 29th, 2002, 09:30 AM

#1. Sending the string:

VB Code:

Option Explicit
 
Private Type COPYDATASTRUCT
    dwData As Long
    cbData As Long
    lpData As Long
End Type
Private Const WM_COPYDATA = &H4A
Private Const MCL_COPYSTRING = &HE
 
Private Declare Function SendString Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As COPYDATASTRUCT) As Long
 
 
Public Function SendStringCrossTask(ByVal TargetWnd As Long, ByVal smessage As String)
 
Dim cpThis As COPYDATASTRUCT
 
Dim sAnsiString As String
 
sAnsiString = StrConv(smessage, vbFromUnicode)
 
With cpThis
    .dwData = MCL_COPYSTRING
    .cbData = LenB(sAnsiString)
    .lpData = StrPtr(sAnsiString)
End With
 
If SendString(TargetWnd, WM_COPYDATA, Me.hwnd, cpThis) Then
    '\\ target window accepted and processed the data
Else
    '\\ target window did not accept the data
End If
 
End Function

::EDITTED FOR ANSI / UNICODE CHANGES ::

**amitabh** · Oct 29th, 2002, 09:31 AM

To think of it, I can use WM_SETTEXT messsage and then look for the same in the Window proc. But still, I would rather like to have a self-defined message to be sent, with the string as a parameter if its possible.

**amitabh** · Oct 29th, 2002, 09:32 AM

A big thanks.
Didn't see that you had already replied to the thread. I will just test it out in my app.

**MerrionComputin** · Oct 29th, 2002, 09:38 AM

#2 - recieving the string
Subclass the recieving window and put the following as a replacement for it's windowproc:

VB Code:

Option Explicit
 
Private Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Type COPYDATASTRUCT
    dwData As Long
    cbData As Long
    lpData As Long
End Type
Private Const WM_COPYDATA = &H4A
Private Const MCL_COPYSTRING = &HE
 
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Private Declare Sub CopyMemoryCopyDataStruct Lib "kernel32" Alias "RtlMoveMemory" (Destination As COPYDATASTRUCT, ByVal Source As Long, ByVal Length As Long)
 
Private mhOldWndproc As Long
 
Public Function VBWndproc(ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
 
If Msg = WM_COPYDATA Then
    Dim cpThis As COPYDATASTRUCT
    Call CopyMemoryCopyDataStruct(cpThis, lParam, Len(cpThis))
    If cpThis.dwData = MCL_COPYSTRING Then
        Dim smessage As String
        smessage = StringFromPointer(cpThis.lpData, cpThis.cbData)
        Debug.Print smessage
        '\\ tell other window we processed this message
        VBWndproc = 1
    Else
        '\\ pass message on for standard processing
        VBWndproc = CallWindowProc(mhOldWndproc, hWnd, Msg, wParam, lParam)
    End If
Else
    '\\ pass message on for standard processing
    VBWndproc = CallWindowProc(mhOldWndproc, hWnd, Msg, wParam, lParam)
End If
 
End Function
 
Public Function StringFromPointer(lpString As Long, lMaxLength As Long) As String
 
  Dim sRet As String
  Dim lret As Long
 
  If lpString = 0 Then
    StringFromPointer = ""
    Exit Function
  End If
 
  If IsBadStringPtrByLong(lpString, lMaxLength) Then
    '\\ An error has occured - do not attempt to use this pointer
      StringFromPointer = ""
    Exit Function
  End If
 
  '\\ Pre-initialise the return string...
  sRet = Space$(lMaxLength)
  CopyMemory ByVal sRet, ByVal lpString, ByVal Len(sRet)
  If Err.LastDllError = 0 Then
    If InStr(sRet, Chr$(0)) > 0 Then sRet = Left$(sRet, InStr(sRet, Chr$(0)) - 1)
  End If
 
 
  StringFromPointer = sRet
 
End Function

Hope this helps,
Duncan

**amitabh** · Oct 29th, 2002, 09:44 AM

BTW, what to do in the WindowProc of the subcalssed APP. I am currently looking out for WM_COPYDATA, then using the StringFromPointer function given by you earlier. But this is returning failure in the calling app and the data too is not available.

**amitabh** · Oct 29th, 2002, 09:46 AM

I am really sorry. I didn't knew that you were in the process of replying to me.

. Get back to you in minute.

**MerrionComputin** · Oct 29th, 2002, 09:49 AM

Both posts editted to deal with ANSI/Unicode issues...

**amitabh** · Oct 29th, 2002, 10:16 AM

Merrion
I have having problems with the code. It is not letting me even subclass the button. I know I must be doing something wrong, but I am not able to pin point it out. Can you take a look at the code, and tell me where am I going wrong. The subclassing line is working properly, but the app terminates when it goes ot the VBWndProc.

VB Code:

'form code
Private Sub Form_Load()
    Me.Caption = "Test Target Window"
    Command1.Caption = "Test_Target_Button"
    'subclass the command button
    'lngPrevWndProc = SetWindowLong(Command1.hWnd, GWL_WNDPROC, AddressOf VBWndproc)
    mhOldWndproc = SetWindowLong(Command1.hWnd, GWL_WNDPROC, AddressOf VBWndproc)
End Sub
 
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
    'set it back to normal before exiting
    SetWindowLong Command1.hWnd, GWL_WNDPROC, mhOldWndproc
End Sub
 
'module code
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
(ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
 
Public Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Private Type COPYDATASTRUCT
    dwData As Long
    cbData As Long
    lpData As Long
End Type
Private Const WM_COPYDATA = &H4A
Private Const MCL_COPYSTRING = &HE
Public Const GWL_WNDPROC = (-4)
 
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Private Declare Sub CopyMemoryCopyDataStruct Lib "kernel32" Alias "RtlMoveMemory" (Destination As COPYDATASTRUCT, ByVal Source As Long, ByVal Length As Long)
 
Public mhOldWndproc As Long
 
Public Function VBWndproc(ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
 
If Msg = WM_COPYDATA Then
    Dim cpThis As COPYDATASTRUCT
    Call CopyMemoryCopyDataStruct(cpThis, lParam, Len(cpThis))
    If cpThis.dwData = MCL_COPYSTRING Then
        Dim smessage As String
        smessage = StringFromPointer(cpThis.lpData, cpThis.cbData)
        Debug.Print smessage
        '\\ tell other window we processed this message
        VBWndproc = 1
    Else
        '\\ pass message on for standard processing
        VBWndproc = CallWindowProc(mhOldWndproc, hWnd, wMsg, wParam, lParam)
    End If
Else
    '\\ pass message on for standard processing
    VBWndproc = CallWindowProc(mhOldWndproc, hWnd, wMsg, wParam, lParam)
End If
 
End Function
 
Public Function StringFromPointer(lpString As Long, lMaxLength As Long) As String
 
  Dim sRet As String
  Dim lret As Long
 
  If lpString = 0 Then
    StringFromPointer = ""
    Exit Function
  End If
 
  If IsBadStringPtrByLong(lpString, lMaxLength) Then
    '\\ An error has occured - do not attempt to use this pointer
      StringFromPointer = ""
    Exit Function
  End If
 
  '\\ Pre-initialise the return string...
  sRet = Space$(lMaxLength)
  CopyMemory ByVal sRet, ByVal lpString, ByVal Len(sRet)
  If Err.LastDllError = 0 Then
    If InStr(sRet, Chr$(0)) > 0 Then sRet = Left$(sRet, InStr(sRet, Chr$(0)) - 1)
  End If
 
 
  StringFromPointer = sRet
 
End Function

**KayJay** · Oct 29th, 2002, 10:44 AM

Originally posted by amitabh
How do I send a string as a message between two apps using SendMessage or PostMessage?

Can this help?

**MerrionComputin** · Oct 29th, 2002, 12:14 PM

My Typo

VB Code:

VBWndproc = CallWindowProc(mhOldWndproc, hWnd, wMsg, wParam, lParam)

Should be

VB Code:

VBWndproc = CallWindowProc(mhOldWndproc, hWnd, Msg, wParam, lParam)

as wMsg is an undefined variable...

**amitabh** · Oct 29th, 2002, 02:17 PM

Merrion
No, it's my mistake. I should have noticed it immediately. A simple missing parameter question

.I must have gone mad these days.

KayJay
It's a nice code. Never gave a thought that Interprocess communications could aslo be used to solve my problems.

Thank you both.

**KayJay** · Oct 30th, 2002, 01:08 AM

UR Welcome

Thread: Passing strings between different apps RESOLVED

Thread Tools

Display