Make ButtonFace lighter [RESOLVED]

[MidgetsBro]

Hey everyone. I am trying to make vbButtonFace a little lighter. I don't mean to change system colors or anything, but I want to take the constant vbButtonFace, then add or subtract some from it to make it darker or lighter and place it in my own variable. I've tried this:

Dim myColor As Long
myColor = Val(vbButtonFace)+1000
myButton.BackColor = myColor

But it gives me an invalid property value. I want to do this with vbButtonFace instead of a constant color because sometimes people have different colors on their systems other than the default grey, and I want my buttons to stand out a little from the background. This way if they have 3D Objects in their system settings set to a dark blue, then my buttons will be a little lighter blue, and if they have a yellow, then the buttons will be a darker yellow, etc...

Thanks for any help.

[IROY55]

Of course it will - you need to provide HEX number (&something&) or RGB value to change colors.

[Mc Brain]

Try sth. like:

Option Explicit
 
Private Declare Function GetSysColor Lib "user32" (ByVal nIndex As Long) As Long
Private Const COLOR_BTNFACE = 15
 
Private Sub Command1_Click()
    Dim ButtonFace As Long
    Dim Red As Byte
    Dim Blue As Byte
    Dim Green As Byte
    
    ButtonFace = GetSysColor(COLOR_BTNFACE)
    Red = ButtonFace And vbRed
    Green = (ButtonFace And vbGreen) / (2 ^ 8)
    Blue = (ButtonFace And vbBlue) / (2 ^ 16)
    
    ButtonFace = RGB(Red + 50, Green + 50, Blue + 50)
    
    Command1.BackColor = ButtonFace
End Sub

[MidgetsBro]

Originally posted by IROY55
Of course it will - you need to provide HEX number (&something&) or RGB value to change colors.

Tried that too, and it didn't work... I forgot to post that.

myColor = Hex(vbButtonFace) + Hex(1000)
CommandButton.BackColor = myColor 'type mismatch

[MidgetsBro]

Thanks McBrain. That worked.

[Mc Brain]

Be careful with the bounds!!

[MidgetsBro]

Originally posted by Mc Brain
Be careful with the bounds!!

Already got that one fixed.

[Mc Brain]

I mean... if the Red component is 237 you won't be able to add 20, for example to enlighten it.

[MidgetsBro]

Originally posted by Mc Brain
I mean... if the Red component is 237 you won't be able to add 20, for example to enlighten it.

Yes I know.

Public Sub LightenButtons(frm As Form)
Dim ButtonFace As Long
Dim Red As Byte
Dim Blue As Byte
Dim Green As Byte
 
ButtonFace = GetSysColor(COLOR_BTNFACE)
Red = ButtonFace And vbRed
Green = (ButtonFace And vbGreen) / (2 ^ 8)
Blue = (ButtonFace And vbBlue) / (2 ^ 16)
If Red > 240 Then
  Red = 255
Else
  Red = Red + 15
End If
If Green > 240 Then
  Green = 255
Else
  Green = Green + 15
End If
If Blue > 240 Then
  Blue = 255
Else
  Blue = Blue + 15
End If
ButtonFace = RGB(Red, Green, Blue)
 
Dim ctl As Control
For Each ctl In frm
  If TypeOf ctl Is CommandButton Then
    ctl.BackColor = ButtonFace
  End If
Next
End Sub

[Mc Brain]

OK... it seems you've already got the idea and added all the IFs statements that I were too lazy to add.

[MidgetsBro]

Yup. hehe. I wish I didn't have to use all those ifs, but it looks like the only way for right now. I'll think about making it better code later, but for now it works, and that's all that matters.

Thanks again.

[Mc Brain]

Originally posted by MidgetsBro
Yup. hehe. I wish I didn't have to use all those ifs, but it looks like the only way for right now. I'll think about making it better code later, but for now it works, and that's all that matters.

Thanks again.

You're welcome.

[Mc Brain]

You can try:

Public Sub LightenButtons(frm As Form)
    Dim ButtonFace As Long
    Dim Red As Byte
    Dim Blue As Byte
    Dim Green As Byte
    
    ButtonFace = GetSysColor(COLOR_BTNFACE)
    Red = ButtonFace And vbRed
    Green = (ButtonFace And vbGreen) / (2 ^ 8)
    Blue = (ButtonFace And vbBlue) / (2 ^ 16)
    
    Red = IIf(Red > 240, 255, Red + 15)
    Green = IIf(Green > 240, 255, Green + 15)
    Blue = IIf(Blue > 240, 255, Blue + 15)
 
    ButtonFace = RGB(Red, Green, Blue)
    
    Dim ctl As Control
    For Each ctl In frm
      If TypeOf ctl Is CommandButton Then
        ctl.BackColor = ButtonFace
      End If
    Next
End Sub

[Mc Brain]

Or just this way:

Public Sub LightenButtons(frm As Form, Shift As Integer)
    Dim ButtonFace As Long
    Dim Red As Integer
    Dim Blue As Integer
    Dim Green As Integer
    
    ButtonFace = GetSysColor(COLOR_BTNFACE)
    Red = (ButtonFace And vbRed) + Shift
    Green = ((ButtonFace And vbGreen) / (2 ^ 8)) + Shift
    Blue = ((ButtonFace And vbBlue) / (2 ^ 16)) + Shift
 
    ButtonFace = RGB(Red, Green, Blue)
    
    Dim ctl As Control
    For Each ctl In frm
      If TypeOf ctl Is CommandButton Then
        ctl.BackColor = ButtonFace
      End If
    Next
End Sub

Apparently, if the number is bigger than 255, the RGB would use 255 instead. So, there's no need to check if it's bigger than 255. However, you have to declare the variables as Integer, instead of Byte.