NetMeeting CLSID

[Mc Brain]

Does anybody understand this code?

<object ID=NetMeeting CLASSID="CLSID:3E9BAF2D-7A79-11d2-9334-0000F875AE17" width="244" height="158"><PARAM NAME = "MODE" VALUE = "DataOnly"></object>

That seems to add a netmeeting object in an htm page. Is there any way to get the same in a form? If so, how?

[Aaron Young]

The code you've entered is like you said, for HTML, it makes a
reference to the Netmeeting Scripting API ActiveX Object which is
the same object you can get a reference to in a VB form.

However it only gives you "Basic" functionality, i.e. "CallTo", "LeaveConference"

For much more flexability you need to use the COM API interface
but it's not well documentented from a VB standpoint and I'm
fairly sure (not 100%) that it's not directly accessible through VB.

[Mc Brain]

I was wondering if I could get a control in a form, like it can be done in HTM.

[Aaron Young]

There's no control, but you can add a reference to the NetMeeting 1.1 Type Library which gives you access to a NetMeeting Object with Events, see my example in this thread.

If you can't find the reference in the list, locate "conf.exe" in the NetMeeting Folder.

[Mc Brain]

Originally posted by Aaron Young
There's no control, but you can add a reference to the NetMeeting 1.1 Type Library which gives you access to a NetMeeting Object with Events, see my example in this thread.

If you can't find the reference in the list, locate "conf.exe" in the NetMeeting Folder.

I've seen that thread already. I was wondering if I could open it within a form, instead of that way.

[James Stanich]

Mc Brain : Did I spark an interest in Netmeeting?

[Mc Brain]

Not that much... I was asked for it, remember?

[James Stanich]

Originally posted by Mc Brain
Not that much... I was asked for it, remember?

So this thread is for me?

[Aaron Young]

ok, now I see what you're after.
Well, I guess you could add a WebBrowser control and use the HTML script to get it "in" your form.

Or you could use the API to grab the NetMeeting Window and make a Picturebox on your Form the Parent.

[Mc Brain]

Yes... that was the other way I was thinking of.

[Mc Brain]

Originally posted by James Stanich
So this thread is for me?

I don't know.... If you're asking if you're the one who asked it... the answer is no.

[Mc Brain]

On this thread: http://www.vbforums.com/showthread.p...hreadid=114650

Originally posted by Mc Brain
I was asked, if possible, to vinculate Netmeeting with my app. This would be used to have an "On-line help" (with the support of someone who knows on the other side)

[James Stanich]

Originally posted by Aaron Young
ok, now I see what you're after.
Well, I guess you could add a WebBrowser control and use the HTML script to get it "in" your form.

Or you could use the API to grab the NetMeeting Window and make a Picturebox on your Form the Parent.

Aaron : Have you ever implemented anything like this before?

[Aaron Young]

I've never implemented anything with Netmeeting before, never
had to.

NetMeeting Zone seems to be a good resource.

Here's an example of using the GetParent() API to
manipulate the Interface into a Form.

Option Explicit
 
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hwnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
Private Declare Function GetTopWindow Lib "user32" (ByVal hwnd As Long) As Long
Private Declare Function GetNextWindow Lib "user32" Alias "GetWindow" (ByVal hwnd As Long, ByVal wFlag As Long) As Long
Private Declare Function MoveWindow Lib "user32" (ByVal hwnd As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal bRepaint As Long) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function SetParent Lib "user32" (ByVal hWndChild As Long, ByVal hWndNewParent As Long) As Long
 
Private Const GW_HWNDNEXT = 2
Private Const GW_HWNDFIRST = 0
 
Private Const WM_CLOSE = &H10
 
Private mlHwnd As Long
 
Private WithEvents NetMeetingObject As NetMeeting
 
Private Sub Form_Load()
  ' Resize Picturebox to be the
  ' same as the Video Screen
  ScaleMode = vbPixels
  Picture1.Width = 177
  Picture1.Height = 145
  Picture1.ScaleMode = vbPixels
 
  ' Create a new NetMeeting Object
  Set NetMeetingObject = New NetMeeting
  ' Undock a copy of the interface
  NetMeetingObject.UnDock
  ' Wait for the Window to become available
  mlHwnd = WaitForWindowCaption("NetMeeting - Not in a Call")
  ' If the Window was found..
  If mlHwnd Then
    ' Place the Interface within the Picturebox on this Form
    Call SetParent(mlHwnd, Picture1.hwnd)
    ' Reposition the Interface so only the Video Window is Visible
    Call MoveWindow(mlHwnd, -12, -87, Picture1.ScaleWidth, Picture1.ScaleHeight, True)
  Else
    ' Release the Object
    Set NetMeetingObject = Nothing
  End If
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
  ' Make sure to cancel a call if in one.
  If cmdClose.Enabled Then cmdClose_Click
  ' Release the Object
  Set NetMeetingObject = Nothing
  ' If the Window was being Managed, Close it
  If mlHwnd <> 0 Then
    Call SendMessage(mlHwnd, WM_CLOSE, 0, ByVal 0&)
    mlHwnd = 0
  End If
End Sub
 
Private Sub cmdOpen_Click()
  ' Connect to some other Client
  NetMeetingObject.CallTo "0.0.0.0"
End Sub
 
Private Sub cmdClose_Click()
  ' If there's a NetMeeting Object..
  If Not NetMeetingObject Is Nothing Then
    ' If in a Call..
    If NetMeetingObject.IsInConference Then
      ' Close the Call
      NetMeetingObject.LeaveConference
    End If
  End If
End Sub
 
Private Sub NetMeetingObject_ConferenceStarted()
  Debug.Print "Call Initiated"
  cmdOpen.Enabled = False
  cmdClose.Enabled = True
End Sub
 
Private Sub NetMeetingObject_ConferenceEnded()
  Debug.Print "End of Call"
  cmdOpen.Enabled = True
  cmdClose.Enabled = False
End Sub
 
Private Function WaitForWindowCaption(ByVal sCaption As String) As Long
  Dim lhWnd As Long
  Dim sText As String
  Dim tTimer As Single
  
  ' Wait for a Window with the specified
  ' Caption to be loaded.
  ' (could have used Window Enumeration, but
  ' This allows the code to be in a Form's
  ' code module.)
  tTimer = Timer
  Do
    If lhWnd = 0 Then
      lhWnd = GetTopWindow(0)
    Else
      lhWnd = GetNextWindow(lhWnd, GW_HWNDNEXT)
    End If
    sText = Space(260)
    sText = Left(sText, GetWindowText(lhWnd, ByVal sText, 260))
  Loop While StrComp(Left(sText, Len(sCaption)), sCaption, vbTextCompare) <> 0 And ((Timer - tTimer) < 10)
  
  WaitForWindowCaption = IIf(StrComp(Left(sText, Len(sCaption)), sCaption, vbTextCompare) = 0, lhWnd, 0)
End Function

[James Stanich]

Nice code Aaron. I will give it a go early next week. Still wish I could figure out this XP to 2k thing...

[Aphrael]

I'm looking for a way to add the netmeeting functions (i don't need all, but when you get one, you can get the others) in a vb application. So I don't wanna use netmeeting itself, but its dlls or whatever files it has it's functions in.
I found 1 vb application that did this, but again, the ocx code wasn't available. So I know it is possible to do, but I don't know how exactly.

[James Stanich]

Aaron's code:

Option Explicit
 
Private WithEvents NetMeetingObject As NetMeeting
 
Private Sub Command1_Click()
  Set NetMeetingObject = New NetMeeting
  NetMeetingObject.CallTo "192.168.0.136"
End Sub
 
Private Sub Command2_Click()
  If Not NetMeetingObject Is Nothing Then
    If NetMeetingObject.IsInConference Then
      NetMeetingObject.LeaveConference
    End If
  End If
  Set NetMeetingObject = Nothing
End Sub
 
Private Sub NetMeetingObject_ConferenceStarted()
  Debug.Print "Call Initiated"
End Sub
 
Private Sub NetMeetingObject_ConferenceEnded()
  Debug.Print "End of Call"
End Sub

[tengsam]

Aaron, i have problem on your code after convert it from VB to VB.Net. there is some upgrade issue in the vb.net and i am having problem fixing it. can u help me or anyone can help. And i have found tat Window xp already have the netmeeting 3. Only thing is to install it by click the start button then open run. there type conf and press ok. the netmeeting 3 setup will pop up.