Creating a form at runtime without adding it in IDE

[Tadej]

I have a class like this

Private WithEvents frm As Form
 
Private Sub Class_Initialize()
    Set frm =  new Form
End Sub

I would like to create a new form when the class initializes.
And I don't want to add a form at design time.
The 'new Form' stuff doesnt seem to work.

Any ideas?

Regards, Tadej

[007shahid]

You can add controls without adding them to the form. See http://www.vbforums.com/showthread.php?threadid=174267
But I don't know if you can do the same with a form. I guess you will have to add a form during design time and load a new one during runtime. If you don't know how...
In a new Standard EXE Project, add a Command Button to Form1
Paste the following in the code section

Option Explicit
Dim frm As Form1
 
Private Sub Command1_Click()
Set frm = New Form1
frm.Show
End Sub

[Tadej]

I don't want to design the form.
I want to create it from scratch.

I also tried the next logical thing
Forms.Add

... but nope, it doesnt work either.


I am asking myself if it is even possible

Thanks anyway for trying.

[007shahid]

VB.Global.Forms is a read only object showing 'All loaded forms in an application'.
VB.Global.Licenses 'Manipulates a collection of control licenses for use with Controls.Add'.
So you could not get it that way. Before I had tried that too.

Try adding a blank form to the project. You can modify the form properties. Then you can add the controls using the above method.

[moinkhan]

To create a form dynamically you'll have to create an array of an already created form(say a blueprint)..

Public frmArr() As myFrm   'Declare it in a module
Public frmCount As Long   'This too
 
Private Sub Class_Initialize()
 frmCount = frmCount + 1
 ReDim Preserve frmArr(frmCount)
 Load frmArr(frmCount) = New myFrm
 frmArr(frmCount).Show
End Sub

You can handle events in myFrm(check indices)

[007shahid]

He doesn't want to design a form.

I don't want to design the form.
I want to create it from scratch.

[moinkhan]

What would it mean? Creating from scratch? Does he want to add controls dynamically??
He cannot add any form except the way i mentioned...once the form is added he can always use Form.Controls and Form.Lisences Collection to add any controls to the form..

[kleinma]

vb does not have the ability to create forms from scratch...

but if you REALLY REALLY want to then

Option Explicit
 
Type WNDCLASS
    style As Long
    lpfnwndproc As Long
    cbClsextra As Long
    cbWndExtra2 As Long
    hInstance As Long
    hIcon As Long
    hCursor As Long
    hbrBackground As Long
    lpszMenuName As String
    lpszClassName As String
End Type
Type POINTAPI
    x As Long
    y As Long
End Type
Type Msg
    hWnd As Long
    message As Long
    wParam As Long
    lParam As Long
    time As Long
    pt As POINTAPI
End Type
 
Declare Function RegisterClass Lib "user32" Alias "RegisterClassA" (Class As WNDCLASS) As Long
Declare Function UnregisterClass Lib "user32" Alias "UnregisterClassA" (ByVal lpClassName As String, ByVal hInstance As Long) As Long
Declare Function CreateWindowEx Lib "user32" Alias "CreateWindowExA" (ByVal dwExStyle As Long, ByVal lpClassName As String, ByVal lpWindowName As String, ByVal dwStyle As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hWndParent As Long, ByVal hMenu As Long, ByVal hInstance As Long, lpParam As Any) As Long
Declare Function DefWindowProc Lib "user32" Alias "DefWindowProcA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Declare Sub PostQuitMessage Lib "user32" (ByVal nExitCode As Long)
Declare Function GetMessage Lib "user32" Alias "GetMessageA" (lpMsg As Msg, ByVal hWnd As Long, ByVal wMsgFilterMin As Long, ByVal wMsgFilterMax As Long) As Long
Declare Function TranslateMessage Lib "user32" (lpMsg As Msg) As Long
Declare Function DispatchMessage Lib "user32" Alias "DispatchMessageA" (lpMsg As Msg) As Long
Declare Function ShowWindow Lib "user32" (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long
Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Declare Function LoadCursor Lib "user32" Alias "LoadCursorA" (ByVal hInstance As Long, ByVal lpCursorName As Any) As Long
 
 
Public Const COLOR_WINDOW = 5
Public Const BM_CLICK = 245
Public Const CS_VREDRAW = &H1
Public Const CS_HREDRAW = &H2
Public Const CS_KEYCVTWINDOW = &H4
Public Const WS_OVERLAPPED = &H0&
Public Const WS_POPUP = &H80000000
Public Const WS_CHILD = &H40000000
Public Const WS_MINIMIZE = &H20000000
Public Const WS_VISIBLE = &H10000000
Public Const WS_DISABLED = &H8000000
Public Const WS_CLIPSIBLINGS = &H4000000
Public Const WS_CLIPCHILDREN = &H2000000
Public Const WS_MAXIMIZE = &H1000000
Public Const WS_CAPTION = &HC00000 ' WS_BORDER Or WS_DLGFRAME
Public Const WS_BORDER = &H800000
Public Const WS_DLGFRAME = &H400000
Public Const WS_VSCROLL = &H200000
Public Const WS_HSCROLL = &H100000
Public Const WS_SYSMENU = &H80000
Public Const WS_THICKFRAME = &H40000
Public Const WS_GROUP = &H20000
Public Const WS_TABSTOP = &H10000
Public Const WS_MINIMIZEBOX = &H20000
Public Const WS_MAXIMIZEBOX = &H10000
Public Const WS_TILED = WS_OVERLAPPED
Public Const WS_ICONIC = WS_MINIMIZE
Public Const WS_SIZEBOX = WS_THICKFRAME
Public Const WS_OVERLAPPEDWINDOW = (WS_OVERLAPPED Or WS_CAPTION Or WS_SYSMENU Or WS_THICKFRAME Or WS_MINIMIZEBOX Or WS_MAXIMIZEBOX)
Public Const WS_TILEDWINDOW = WS_OVERLAPPEDWINDOW
Public Const WS_POPUPWINDOW = (WS_POPUP Or WS_BORDER Or WS_SYSMENU)
Public Const WS_CHILDWINDOW = (WS_CHILD)
Public Const WS_EX_CLIENTEDGE = 512
Public Const WM_DESTROY = &H2
Public Const WM_MOVE = &H3
Public Const WM_SIZE = &H5
Public Const SW_HIDE = 0
Public Const SW_SHOWNORMAL = 1
Public Const SW_NORMAL = 1
Public Const SW_SHOW = 5
Public Const SW_MINIMIZE = 6
Public Const IDC_ARROW = 32512&
Public Const GWL_WNDPROC = -4
 
Public lngHwndButton As Long
Public lngHwndLabel2 As Long
Public lngHwndLabel1 As Long
Public lngHwndTextbox As Long
Public hWndForm As Long
 
Public Sub Main()
    Dim lngStyle As Long
 
    'Register Class
    Call RegisterClassProc
    'Create a FORM
    lngStyle = WS_OVERLAPPED Or WS_SYSMENU Or WS_CLIPCHILDREN Or WS_CLIPSIBLINGS
    hWndForm = CreateWindowEx(0, "MyCoolClass", "Dynamic Form using CreateEx API from Serge", lngStyle, 0, 0, 400, 300, 0, 0, App.hInstance, ByVal 0&)
    'Create controls on the form
    lngHwndLabel1 = CreateWindowEx(0, "Static", "New Label1", WS_CHILD, 50, 25, 100, 25, hWndForm, 0, App.hInstance, ByVal 0&)
    lngHwndLabel2 = CreateWindowEx(0, "Static", "New Label2", WS_CHILD, 50, 55, 100, 25, hWndForm, 0, App.hInstance, ByVal 0&)
    lngHwndButton = CreateWindowEx(0, "Button", "New Button", WS_CHILD, 50, 90, 100, 25, hWndForm, 0, App.hInstance, ByVal 0&)
    lngHwndTextbox = CreateWindowEx(WS_EX_CLIENTEDGE, "edit", "Sample Text", WS_CHILD, 50, 125, 100, 25, hWndForm, 0, App.hInstance, ByVal 0&)
    If hWndForm <> 0 Then ShowWindow hWndForm, SW_SHOWNORMAL
    'Show controls on the new form
    ShowWindow lngHwndTextbox, SW_SHOWNORMAL
    ShowWindow lngHwndButton, SW_SHOWNORMAL
    ShowWindow lngHwndLabel1, SW_SHOWNORMAL
    ShowWindow lngHwndLabel2, SW_SHOWNORMAL
    MessageProc
    
End Sub
Private Sub MessageProc()
    Dim ms As Msg
    
    Do While GetMessage(ms, 0, 0, 0)
        TranslateMessage ms
        DispatchMessage ms
    Loop
End Sub
 
Function ProcessWndProc(ByVal lWndProc As Long) As Long
    ProcessWndProc = lWndProc
End Function
 
Public Sub RegisterClassProc()
    Dim ws As WNDCLASS
    
    'Prepare Class to be registered
    ws.style = CS_HREDRAW + CS_VREDRAW
    ws.lpfnwndproc = ProcessWndProc(AddressOf WindowProc)
    ws.cbClsextra = 0
    ws.cbWndExtra2 = 0
    ws.hInstance = App.hInstance
    ws.hIcon = 0
    ws.hCursor = LoadCursor(0, IDC_ARROW)
    ws.hbrBackground = COLOR_WINDOW
    ws.lpszMenuName = 0
    ws.lpszClassName = "MyCoolClass"
    'Register Class
    RegisterClass ws
End Sub
 
Private Function WindowProc(ByVal hWnd As Long, ByVal message As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Select Case message
        Case WM_DESTROY
            PostQuitMessage (0)
            UnregisterClass "MyCoolClass", App.hInstance
    End Select
    WindowProc = DefWindowProc(hWnd, message, wParam, lParam)
End Function

code originally posted by Serge..

[007shahid]

He could just use VC++ instead of doing the above code. But I still feel he should just add a blank form and add controls using Licenses.Add(). Infact it was moin khan who showed me how to add controls like that in the above link

[Tadej]

Thanks everyone for your input.
I think I'll use VC++ for making my class and VB to make only the UI.