Interface dll in ocx

[Bregalad]

Hi

I have an interface that I have put in a separate dll.
I implement this interface in a user control ocx.

In my main program, i have the dll and ocx referenced,
and I load the user control depending on which form is showing.

I use this code to do it:

Private Sub Form_Load()
   Dim oCtl As Object
   Dim ctlMain As FormControls.ctlBuy
   Dim clsMain As FormClasses.clsForm
 
   Set oCtl = Controls.Add("FormControls.ctlBuy","ctlCur")
   Set ctlMain = oCtl
   ' I set the control's properties and show it here...
   Set clsMain = ctlMain
End Sub

This works fine until the statement 'Set clsMain = ctlMain'.
This gives a type mismatch error.

The dll is compiled with binary compability, and was compiled
before I started making my user control. I have checked that
it is the same dll that is referenced both from the main app and
from the ocx project.

What am I doing wrong here?

[ChiefRB]

ctlMain and clsMain must implement the same interface. Do they?

[Bregalad]

The FormClasses.dll contains just one class module,
which is clsForm. clsForm is implemented in FormControls.ctlBuy.

I then try to define an object of type clsForm, and set this to
be an instance of FormControls.ctlBuy.

It worked fine as long as i had all the class modules, user
controls, and forms in the same project, but when i split the
project into 3 parts, 1 ocx, 1 dll, 1 exe, i got the type mismatch
error message.

So clsMain is the interface class, and ctlMain implements that class.

[ChiefRB]

Have you tried taking out the intermediary - you don't need both oCtl and ctlMain.

Set ctlMain = Controls.Add("FormControls.ctlBuy","ctlCur")
   ' I set the control's properties and show it here...
   Set clsMain = ctlMain

If this still gives a type mismatch error, then there's something wrong with your interfaces or controls.

Just a tip - give things more obvious names. The coding convention for interface classes is to prefix with "I" - FormClass.IForm for example. Classes which implement this interface are prefixed with "C" to stand for Concrete. Objects are prefixed with obj or nothing at all... so (Just IMHO of course):

Dim objCtl As Object
   Dim objBuy As FormControls.CBuy
   Dim objForm As FormClasses.IForm

[Bregalad]

OK.. I did a simple test project, and got the same problem.
Here is what I have:

FormClasses.IForm:

Option Explicit
 
Public Property Let ControlCaption(ByVal sCaption As String)
 
End Property
 
Public Property Get ControlCaption() As String
 
End Property

FormControls.ctlLabel:

Option Explicit
 
Implements FormClasses.IForm
 
Private Property Get IForm_ControlCaption() As String
   IForm_ControlCaption = Label1.Caption
End Property
 
Private Property Let IForm_ControlCaption(ByVal RHS As String)
   Label1.Caption = RHS
End Property

prjTest:

Option Explicit
 
Private Sub cmdTest_Click()
   Dim ctl As FormControls.ctlLabel
   Dim cls As FormClasses.IForm
   Set ctl = Me.Controls.Add("FormControls.ctlLabel", "lblNew")
   ctl.Top = cmdTest.Top + cmdTest.Height
   ctl.Left = cmdTest.Left
   ctl.Visible = True
   Set cls = ctl
   cls.ControlCaption = "Hello"
   Set cls = Nothing
   Set ctl = Nothing
End Sub

I still get the Type Mismatch error in the line "Set cls = ctl"
I noticed that VB changes the sCaption parameter to RHS,
but changing it back to sCaption in the usercontrol doesn't
make any difference.

[ChiefRB]

In that case I can't see anything wrong. It all looks fine... perhaps it's something to do with the Controls.Add method... try using a control array instead, and using the Load statement to create a new instance.

[Bregalad]

I just changed the line

Set cls = ctl

to

Set cls = ctl.Object

This seemed to do the trick,
although I have no idea why it should.

Thanks for your help ChiefRB