Attachment syntax with outlook mail object

[iany]

I was wondering if anybody, could tell me the correct syntax to attatch a csv file to an outlook mail object. Do i just have to specify the file path for the outlookmsg.attatchment property?

[Hack]

Private Sub SendMessage(DisplayMsg As Boolean, Receiver As String, Optional AttachmentPath)
    
    Dim objOutlook As Outlook.Application
    Dim objOutlookMsg As Outlook.MailItem
    Dim objOutlookRecip As Outlook.Recipient
    Dim objOutlookAttach As Outlook.Attachment
    Dim CallDescription As String
 
' Create the Outlook session.
    Set objOutlook = CreateObject("Outlook.Application")
 
' Create the message.
    Set objOutlookMsg = objOutlook.CreateItem(olMailItem)
 
    With objOutlookMsg
' Add the To recipient(s) to the message.
        Set objOutlookRecip = .Recipients.Add(Receiver)
        objOutlookRecip.Type = olTo
 
' Add the CC recipient(s) to the message.
        Set objOutlookRecip = .Recipients.Add("an other person")
        objOutlookRecip.Type = olCC
 
' Set the Subject, Body, and Importance of the message.
        .Subject = "Replace this String With your subject Or variable"
        .Body = "replace this String With your subject Or variable"
        .Body = .Body & vbCrLf & "In this manner you can create a body larger than 256 characters"
 
'.Importance = olImportanceHigh  'High importance
 
' Add attachments to the message.
        If Not IsMissing(AttachmentPath) Then
            Set objOutlookAttach = .Attachments.Add("c:\yourpath\yourfile.csv")
        End If
 
' Resolve each Recipient's name.
        For Each objOutlookRecip In .Recipients
            objOutlookRecip.Resolve
        Next
 
' Should we display the message before sending?
        If DisplayMsg Then
            .Display
        Else
            .Send
        End If
 
    End With
 
    Set objOutlook = Nothing
End Sub

Make sure your project has a reference to the Microsoft Object Library.

[iany]

thanking you HACK