Msgbox Icons

[Enveetee]

I've finally had a spare day to write my own VB6 MsgBox function but now I need the standard icons

vbExclamation, vbQuestion, vbCritical and so on

Anyone got them or a link to them

thanks

[VBClassicRocks]

Try this code:

Option Explicit
Private Enum MsgBoxIcons
 mbiCritical = 32513&
 mbiQuestion = 32514&
 mbiExclamation = 32515&
 mbiInformation = 32516&
 mbiWinLogo = 32517&
End Enum
Private Declare Function DrawIcon Lib "user32" (ByVal hDC As Long, ByVal x As Long, ByVal y As Long, ByVal hIcon As Long) As Long
Private Declare Function LoadIcon Lib "user32.dll" Alias "LoadIconA" (ByVal hInstance As Long, ByVal lpIconName As Long) As Long
Private Sub DrawMsgBoxIcon(ByVal hDC As Long, x As Long, y As Long, ByVal mbi As MsgBoxIcons)
 Dim hIcon As Long
 hIcon = LoadIcon(ByVal 0, mbi)
 DrawIcon hDC, x, y, hIcon
End Sub

Private Sub Form_Load()
 Dim i As Long
 Dim x As Long
 AutoRedraw = True
 For i = mbiCritical To mbiWinLogo
  DrawMsgBoxIcon hDC, x, 0, i
  x = x + 32
 Next
End Sub

[Enveetee]

Thanks, can I ask, are these icons part to of some component or sub system and this code is extracting it

If so, can I assume it will be installed on all machines XP -> 8

Cheers

[techgnome]

User32.dll? Oh yeah, you can assume it's there. W/o it, nearly everything in Windows would stop working.

-tg