How to remove null from fixed length string

[jdy0803]

There is a fixed length string which has 3 null char.
I want to concatenate other string to this string but failed because 3 nulls.
How can I do this?

Here is sample code.

Dim str1 As String * 10
Dim str2 As String

str1 = "ABCDEFG" & Chr(0) & Chr(0) & Chr(0)
str2 = str1 + "HIJ"

MsgBox str2 'str2 is ""ABCDEFG" not "ABCDEFGHIJ"

[Vincent Hadison]

May be you can use this code:

Dim str1 as string
Dim str2 as string
str1 = "ABCDEFG"
str2 = str1 + "HIJ"

[jdy0803]

May be you can use this code:

Dim str1 as string
Dim str2 as string
str1 = "ABCDEFG"
str2 = str1 + "HIJ"

Actually str1 is acquired from some C DLL function which requires 10 fixed length string.
I just made sample code to explaine my issue.
So I can't declare str1 As String

[dilettante]

How about:

Option Explicit

Private Declare Function lstrlen Lib "kernel32" Alias "lstrlenW" ( _
    ByVal lpString As Long) As Long

Private Sub Command1_Click()
    Dim str1 As String * 10
    Dim str2 As String
    Dim NullPos As Long

    str1 = "ABCDEFG" & String$(3, 0)

    'Method 1:
    str2 = Replace$(str1, vbNullChar, "") & "HIJ"
    MsgBox CStr(Len(str2)) & vbNewLine _
         & "[" & str2 & "]", , _
           "Method 1"

    'Method 2:
    NullPos = InStr(str1, vbNullChar)
    If NullPos > 0 Then
        str2 = Left$(str1, NullPos - 1) & "HIJ"
    Else
        str2 = str1 & "HIJ"
    End If
    MsgBox CStr(Len(str2)) & vbNewLine _
         & "[" & str2 & "]", , _
           "Method 2"

    'Method 3:
    str2 = Left$(str1, lstrlen(StrPtr(str1))) & "HIJ"
    MsgBox CStr(Len(str2)) & vbNewLine _
         & "[" & str2 & "]", , _
           "Method 3"
End Sub

The last method using an API call works by relying on the hidden "out of band" NUL that is stored after every String's contents. These are stored as part of a BSTR (OLE String, i.e. VB String) just to make them easier to pass to an API call as a "C string pointer" (lpsz).

[techgnome]

HIJ doesn't get appended because the string is a fixed length and it is already full... there's 3 nulls because the string itself only has 7 characters in it. I'm trying to decide which of the three methods dilettante posted I like best and is the most flexible going forward... probably method 2, although 3 is the least amount of code... I mention this because I doubt you're getting "ABCDEFG" from anything and that "HIJ" is just as arbitrary and contrived as the data sample, and you're going to want something flexible to handle "A" as well as "ABCDE" and "ABCDEFH"


-tg

[Doogle]

This appears to work

Dim strA As String * 10
Dim strB As String
strA = "ABCDEFG" & Chr(0) & Chr(0) & Chr(0)
strB = Replace(strA & "HIJ", Chr(0), vbNullString)
Debug.Print strB

EDIT: On reflection this looks like Dilettante's Method 1

[Bonnie West]

Actually str1 is acquired from some C DLL function which requires 10 fixed length string.
I just made sample code to explaine my issue.
So I can't declare str1 As String

I believe what you just need is a string buffer. In that case, a dynamic string would be good enough. Typically, such a string is filled first with a sufficient number of characters (such as spaces or nulls) before it is passed to the external function. Can you show the C function's signature and your VB6 declaration?