[RESOLVED] Fastest way to parse text for fields

[softwareguy74]

What would be the fasted method of get a string list of all values within [] in a string of text? For example:

Hi [client_name], are you are doing today? My name is [my_name].

The list of strings would be:

client_name
my_name

Just to be clear, I do not know beforehand what the values are between the brackets, it can be anything and any number of them.

[softwareguy74]

Found the following solution using RegEx. It works quite well:

    Private Function GetFields(ByVal text As String) As List(Of String)
        Dim list As New List(Of String)
        Try
            Dim collection As MatchCollection = Regex.Matches(text, "\[([^]]*)\]")
            For Each value As Match In collection
                list.Add(value.Groups(1).Value)
            Next
        Catch ex As Exception
            MessageBox.Show(ex.Message)
        End Try
        Return list
    End Function

[.paul.]

try this. it uses regex to find any text between [], + puts them in a list(of string):

Imports System.Text.RegularExpressions
 
Public Class Form1
 
    Dim strList As List(Of String)
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim strText As String = "Hi [client_name], are you are doing today? My name is [my_name]."
        Dim matches() As String = Array.ConvertAll(New Regex("(?<=\[)(\w|\s)+(?=\])").Matches(strText).Cast(Of Match).ToArray, Function(m) m.Value)
        strList = New List(Of String)(matches)
    End Sub
End Class

[softwareguy74]

Your code is definitely cleaner. I will be using that instead. Thanks!

[softwareguy74]

One other improvement I need to make is to only add unique values. For example, if [client_name] appears more than once in the source, I just want it added once to the list. Is this easily accomplished?

[.paul.]

yes. no problem. you can use LINQ to select unique names from the matches array:

Imports System.Text.RegularExpressions
 
Public Class Form1
 
    Dim strList As List(Of String)
 
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim strText As String = "Hi [client_name], are you are doing today? My name is [my_name].Hi [client_name], are you are doing today? My name is [my_name]."
        Dim matches() As String = Array.ConvertAll(New Regex("(?<=\[)(\w|\s)+(?=\])").Matches(strText).Cast(Of Match).ToArray, Function(m) m.Value)
        strList = New List(Of String)((From match In matches Select match Distinct).ToArray)
        Stop
    End Sub
End Class

[softwareguy74]

Perfect! Thanks!