[RESOLVED] MsgBox focus question

[TysonLPrice]

I have a project that the user works two windows at once split so they are visible on the same screen.. Form1 is the main VBP project and works in junction with an OCX that controls a third party viewer. When the user clicks save on Form1 it has the focus. Then it calls the OCX which displays a msgbox which is under form1. The reverse happens when the user makes selections on the viewer. It has focus and when control passes back to form1 and displays a message it is under the viewer. How can I make the message box stay in front of both forms? I tried me.setfocus in the OCX and it doesn’t seem to support it. Someone pointed me at an API that is called SetWindowPos but it doesn’t seem to work. “Using MsgBox "test", vbMsgBoxSetForeground” seems to set it in front but I need to check for a yes no response.

Any suggestions?

[RobDog888]

Is your form1 set as the topmost form perhaps? Otherwise a msgbox should display above its parent form.

[Merri]

It depends on message box instance. Here is a Unicode aware API version of the standard messagebox:

Option Explicit

Private Declare Function MessageBoxIndirectW Lib "user32" (lpMsgBoxParams As MsgBoxParams) As Long

Private Const MB_USERICON = &H80&

Private Type MsgBoxParams
    cbSize As Long
    hWndOwner As Long
    hInstance As Long
    lpszText As Long
    lpszCaption As Long
    dwStyle As Long
    lpszIcon As Long
    dwContextHelpId As Long
    lpfnMsgBoxCallback As Long
    dwLanguageId As Long
End Type

' note: I didn't bother to go ahead and start hacking with HelpFile and Context
Public Function MsgBox(ByVal Prompt As String, Optional Buttons As VbMsgBoxStyle = vbOKOnly, Optional ByVal Title As String, Optional ResourceIcon As String, Optional hWndOwner As Long) As VbMsgBoxResult
    Dim udtMsgBox As MsgBoxParams
    ' if no owner is specified, try to use the active form
    If hWndOwner = 0 Then If Not Screen.ActiveForm Is Nothing Then hWndOwner = Screen.ActiveForm.hWnd
    With udtMsgBox
        .cbSize = Len(udtMsgBox)
        ' important to set owner to get behavior similar to the native MsgBox
        .hWndOwner = hWndOwner
        .hInstance = App.hInstance
        ' set the message
        .lpszText = StrPtr(Prompt)
        ' if no title is given, use the application title like the native MsgBox
        If LenB(Title) = 0 Then Title = App.Title
        .lpszCaption = StrPtr(Title)
        ' thought this would be a nice feature addition
        If LenB(ResourceIcon) = 0& Then
            .dwStyle = Buttons
        Else
            .dwStyle = (Buttons Or MB_USERICON) And Not (&H70&)
            .lpszIcon = StrPtr(ResourceIcon)
        End If
    End With
    ' show the message box
    MsgBox = MessageBoxIndirectW(udtMsgBox)
End Function

The things of interest for you are hInstance and hWndOwner. As long as you set the the same owner and instance in each call, you get the same kind of behavior.

[TysonLPrice]

Is your form1 set as the topmost form perhaps? Otherwise a msgbox should display above its parent form.

I probably should have been clearer. Form1 is the project. The first of the two forms the user is working with is a dll. The dll calls the ocx. Those two are what's sharing the screen and hiding each others message boxes.

So...the main screen is up, the user calls the dll display and the form1 goes to the tool bar. Clicking on the dll calls the ocx display which is now side by side with the dll display Working between the two is where they are blocking each others messages.

[TysonLPrice]

This seems to work fine:

MsgBox "text", vbInformation + vbMsgBoxSetForeground, "text"

[Hack]

This seems to work fine:

MsgBox "text", vbInformation + vbMsgBoxSetForeground, "text"

But, that doesn't seem to satisfy this requirement.

I need to check for a yes no response.

Don't you need to add a vbYesNo in there?

[TysonLPrice]

But, that doesn't seem to satisfy this requirement.Don't you need to add a vbYesNo in there?

Yes...What I posted was from the form load of a simple project to test and to show what works for keeping the msgbox on top in case someone searches in the future. This is what I actually used:

Select Case MsgBox("Do you want to index the remaining pages after the split?" & vbCrLf & _
                           "Clicking 'No' will delete the remaining pages", vbYesNoCancel + vbMsgBoxSetForeground, "Confirm Keep Pages.")
        Case vbYes
            bKeepRemainingPages = True
        Case vbNo
            bKeepRemainingPages = False
        Case vbCancel
            Exit Function
        End Select