Listbox Search!?

[anthony_pacitto3]

ok, how do i make it so that i have a listbox and a textbox and my listbox is filled with names (Anthony, Alex, Brad, Anthony, Anthony) and when i type a name in the textbox, it will only show that name in the listbox and will remove the rest of the other names. ex: If i type Anthony in the textbox then in the listbox all that will show is Anthony
Anthony
Anthony
and Brad and Alex will not show. Does anyone know how to do this its a search method its in some software programs....please help! Thank you.

[aikidokid]

Try doing a search for "Autocomplete"

I found one of my old threads that worked here

This will get you started.

[Hack]

Try doing a search for "Autocomplete"

I found one of my old threads that worked here

This will get you started.

Your link is for a ListView. The OP is asking about a ListBox, for which I would use something like

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, _
ByVal wMsg As Long, ByVal wParam As Long, lparam As Any) As Long 
 
Private Const LB_FINDSTRING = &H18F   
Private Const LB_FINDSTRINGEXACT = &H1A2
 
Private Sub txtSearch_Change()
List1.ListIndex = SendMessage(List1.hwnd, LB_FINDSTRING, -1,  ByVal CStr(Text1.Text)) 
End Sub

[RobDog888]

To make it autocomplete you will want to use the Change event of the textbox perhaps instead of a command button.

[Hack]

Good point.

Changed.

[aikidokid]

Your link is for a ListView.

yeah the original question was about a Listview, but post 13 from zyander was for a Listbox

[Hack]

Post 13?????

There are only 6, now 7, posts in this thread.

[aikidokid]

Post 13?????

There are only 6, now 7, posts in this thread.

No - the thirteenth post in the link I gave.

Here is autocomplete for listbox.

Option Explicit
'API call to listbox
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
    ByVal hwnd As Long, _
    ByVal wMsg As Long, _
    ByVal wParam As Long, _
    ByRef lParam As Any _
) As Long
Const LB_FINDSTRING = &H18F
Dim DelKey As Boolean
Dim bNoClick As Boolean

Private Sub List1_Click()
'to prevent executing the click event
 If bNoClick Then Exit Sub
    Text1.Text = List1.Text
End Sub

Private Sub List1_GotFocus()
    SendKeys "{DOWN}"
End Sub

Private Sub List1_KeyDown(KeyCode As Integer, Shift As Integer)
    List1_Click
End Sub

Private Sub Text1_Change()
'autocomplete feature
Dim strt As Long, nIndex As Long
Dim nLen As Long, sText As String
Const LB_GETTEXTLEN As Long = &H18A
Const LB_GETTEXT As Long = &H189
Static blnBusy As Boolean

If blnBusy Then
   Exit Sub
End If
     
     bNoClick = True
     blnBusy = True
    
    'Retrieve the item's listindex
    List1.ListIndex = SendMessage(List1.hwnd, LB_FINDSTRING, -1, ByVal CStr(Text1.Text))
    
    If Not DelKey Then


    If List1.ListIndex <> -1 Then
        strt = Len(Text1.Text)
        Text1.Text = List1.List(List1.ListIndex)
        Text1.SelStart = strt
        Text1.SelLength = Len(Text1.Text) - strt
    Else
    
    End If
    End If
       DelKey = False
       blnBusy = False
       bNoClick = False

End Sub

Private Sub Text1_Click()
    'select all the text
    Text1.SelStart = 0
    Text1.SelLength = Len(Text1)
End Sub

Private Sub text1_KeyDown(KeyCode As Integer, Shift As Integer)
    'for delete and backspace
    If KeyCode = vbKeyDelete Or KeyCode = 8 Then
    
    DelKey = True
    Exit Sub

    ElseIf KeyCode = vbKeyDown Then
        List1.SetFocus
    End If
End Sub

That is assuming, the listbox has already items on it. Try it out and see what fits your program best.

[RobDog888]

A listbox and a combobox use almost the same exact code for this. Just use the different constant declarations. Different values but named similar CB_ or LB_

Private Const LB_FINDSTRING As Long = &H18F
Private Const LB_FINDSTRINGEXACT As Long = &H1A2

Private Const CB_FINDSTRING As Long = &H14C
Private Const CB_FINDSTRINGEXACT As Long = &H158

[Hack]

How did a combo box make it into the question?

[RobDog888]

Because I posted it.

Just pointing out a useless fact.